Snapshot (screenshot semnat) - AntiSS-ul este istorie

[John.mZq]

UN plugin foarte bun :)

[CrySo]

Felicitari . bv

[alecs14]

Reupload SMA va rog, link expirat.

[Ionutz4x17]

puneti alt .sma va rog

[Guess Who ?!]

File does not exist on this server
De ce ? :)
Anyway, am luat .sma-ul din alta parte, dar asa ca chestie ;*

[Ulquiorra]

am vazut ca nu mai merge link.. de download.. si aveam si eu nevoie de plugin..
asa ca mi-am facut unul identic.. doar ca putin mai colorat si mai cum imi place mie..

cvar-uri: ss_move_spec 0/1 daca sa mute jucatorul spectator dupa ss sau nu.

nu bagati in seama [sPuf ?]'s Testing Ground ! ( ala e numele la sv de teste.. )
la voi pe server o sa apara ce aveti pun in cvarul 'hostname'

| Afiseaza codul

#include < amxmodx >
#include < amxmisc >
#include < cstrike >
#include < fun >
#include < CC_ColorChat >


#pragma semicolon 1


#define PLUGIN "New Plugin"
#define VERSION "1.0"

#define SS_ACCESS	ADMIN_SLAY
#define SignTask	112233
#define UnSignTask	332211

enum
{
	
	INFO_NAME,
	INFO_IP,
	INFO_AUTHID
	
};

new const szTag[    ]  =  "*";
new const szSite[    ]  =  "www.indungi.ro/forum";

new g_iUserHP[ 33 ];
new g_iUserAP[ 33 ];

new gCvarMoveSpec;

new SyncHudMessage;
new SyncHudMessage2;
new SyncHudMessage3;

public plugin_init( )
{
	// Idee plugin si primul care l-a publicat: ThE_ChOSeN_OnE
	// Acest cod este scris de mine in totalitate..
	register_plugin( PLUGIN, VERSION, "Askhanar" );
	
	gCvarMoveSpec  =  register_cvar(  "ss_move_spec",  "0"  );
	register_clcmd(  "amx_ss", "ClCmdSS"  );

	SyncHudMessage  =  CreateHudSyncObj(    );
	SyncHudMessage2  =  CreateHudSyncObj(    );
	SyncHudMessage3  =  CreateHudSyncObj(    );
	
}

public client_putinserver(  id  )
{
	g_iUserHP[  id  ]  =  0;
	g_iUserAP[  id  ]  =  0;
}

public client_disconnect(  id   )
{
	g_iUserHP[  id  ]  =  0;
	g_iUserAP[  id  ]  =  0;
	
	if( task_exists(  id + UnSignTask  )  )
	{
		ColorChat(  0, RED, "^x04%s^x03 %s^x01 s-a deconectat in timp ce i s-a facut SS!", szTag, GetInfo(  id,  INFO_NAME  )  );
		remove_task(  id  + UnSignTask  );
	}
}

public ClCmdSS(  id  )
{
	if(  !(  get_user_flags(  id  )  &  SS_ACCESS  )  )
	{
		client_cmd(  id, "echo %s Nu ai acces la aceasta comanda!", szTag  );
		return 1;
	}
	
	new szFirstArg[ 32 ];
	read_argv(  1,  szFirstArg, sizeof ( szFirstArg ) -1  );
	
	if(  equal(  szFirstArg, ""  )  )
	{
		client_cmd(  id, "echo amx_ss < nume > faci o poza semnata!"  );
		return 1;
	}
	
	new iPlayer  =  cmd_target(  id,  szFirstArg,  8  );
	
	if( !iPlayer  )
	{
		client_cmd(  id, "echo %s Jucatorul specificat nu a fost gasit!", szTag  );
		return 1;
	}
	
	if( !is_user_alive(  iPlayer  ) )
	{
		client_cmd(  id, "echo %s Jucatorul %s nu este in viata !", szTag, GetInfo(  iPlayer, INFO_NAME  )  );
		return 1;
	}
	
	if(  task_exists(  iPlayer  +  SignTask)  ||  task_exists(  iPlayer  + UnSignTask  )  )
	{
		client_cmd(  id, "echo %s Jucatorul %s este in curs de 'pozare' !", szTag, GetInfo(  iPlayer, INFO_NAME  )  );
		return 1;
	}
	
	if(  cs_get_user_team(  id  )  !=  CS_TEAM_SPECTATOR  )
	{
		client_cmd(  id, "echo %s Trebuie sa fii Spectator ca sa poti face o poza!", szTag  );
		return 1;
	}
	
	ColorChat(  0,  RED,  "^x04%s^x03 %s^x01 i-a facut o poza semnata lui^x04 %s^x01 !",  szTag,  GetInfo(  id,  INFO_NAME  ),  GetInfo(  iPlayer,  INFO_NAME  )  );
	
	g_iUserHP[ iPlayer ]  =  get_user_health(  iPlayer  );
	g_iUserAP[ iPlayer ]  =  get_user_armor(  iPlayer  );
	
	set_user_godmode(  iPlayer,  1  );
	set_user_health(  iPlayer,  255  );
	set_user_armor(  iPlayer,  255  );
	
	ColorChat(  iPlayer, RED, "^x04%s^x01 Nume:^x03 %s^x04 |^x01 Nume Admin:^x03 %s", szTag, GetInfo(  iPlayer,  INFO_NAME  ), GetInfo(  id, INFO_NAME  )  );
	ColorChat(  iPlayer, RED, "^x04%s^x01 IP:^x03 %s^x04 |^x01 IP Admin:^x03 %s", szTag, GetInfo(  iPlayer, INFO_IP  ),  GetInfo(  id,  INFO_IP  )  );
	ColorChat(  iPlayer, RED, "^x04%s^x01 SteamId:^x03 %s^x04 |^x01 SteamId Admin:^x03 %s", szTag, GetInfo(  iPlayer,  INFO_AUTHID  ),  GetInfo(  id,  INFO_AUTHID  )  );
	ColorChat(  iPlayer, RED, "^x04%s^x01 Data/Ora:^x03 %s^x04 |^x01 Site ^x03%s", szTag, _get_time(    ),  szSite  );
	client_print(  iPlayer,  print_center,  "Screenshot facut.."  );
	
	
	client_print(  iPlayer,  print_console,  " %s Nume: %s | Nume Admin: %s", szTag, GetInfo(  iPlayer,  INFO_NAME  ), GetInfo(  id, INFO_NAME  )  );
	client_print(  iPlayer,  print_console,  " %s IP: %s | IP Admin: %s", szTag, GetInfo(  iPlayer, INFO_IP  ),  GetInfo(  id,  INFO_IP  )  );
	client_print(  iPlayer,  print_console,  " %s SteamId: %s | SteamId Admin: %s", szTag, GetInfo(  iPlayer,  INFO_AUTHID  ),  GetInfo(  id,  INFO_AUTHID  )  );
	client_print(  iPlayer,  print_console,  " %s Data/Ora: %s | Site %s", szTag, _get_time(    ),  szSite  );
	
	for( new i = 1; i <= 3; i++ )
		DisplayMessages(  iPlayer,  i  );
	
	set_task(  0.1, "SignScreen", iPlayer  + SignTask  );
	
	return 1;
}

public SignScreen(  iPlayer  )
{
	
	iPlayer  -=  SignTask;
	if(  !is_user_connected( iPlayer )  )	return 1;
	
	client_cmd(  iPlayer,  "toggleconsole;snapshot;toggleconsole"  );
	
	if( get_pcvar_num(  gCvarMoveSpec  )  )
	{
		user_kill(  iPlayer,  1  );
		cs_set_user_team(  iPlayer,  CS_TEAM_SPECTATOR  );
	}
	
	set_task(  0.7, "UnSignPlayer",  iPlayer + UnSignTask );
	
	return 0;
	
}
	
public UnSignPlayer(  iPlayer  )
{
	iPlayer -= UnSignTask;
	if(  !is_user_connected( iPlayer ) )	return 0;
	
	ColorChat(  iPlayer, RED, "^x04%s^x03 Screenshot semnat..", szTag  );
	client_cmd(  iPlayer,  "echo %s^x03 Screenshot semnat..", szTag  );
	client_print(  iPlayer, print_center,  "Screenshot semnat.."  );
	
	if( is_user_alive(  iPlayer  )  )
	{
		set_user_godmode(  iPlayer,  0  );
		set_user_health(  iPlayer,  g_iUserHP[ iPlayer ]  );
		set_user_armor(  iPlayer,  g_iUserAP[ iPlayer ] );
	}
	
	g_iUserHP[ iPlayer ]  =  0;
	g_iUserAP[ iPlayer ]  =  0;
	
	return 0;
}

public DisplayMessages(  iPlayer,  const iMessage  )
{
	
	new szHostName[ 64 ];
	get_cvar_string( "hostname", szHostName, sizeof ( szHostName ) -1  );
	
	switch(  iMessage  )
	{
		case 1:
		{
			
			set_hudmessage(  255,  0,  0,  0.10, 0.25,  0,  0.0 , 0.2,  0.0,  0.1,  1  );
			ShowSyncHudMsg(  iPlayer,  SyncHudMessage,  "%s",  szHostName  );
		}
		case 2:
		{
			set_hudmessage(  235,  255,  45,  -1.0, -1.0,  0,  0.0 , 0.2,  0.0,  0.1,  2  );
			ShowSyncHudMsg(  iPlayer,  SyncHudMessage2,  "%s",  szHostName  );
		}
		case 3:
		{
			set_hudmessage(  0,  0,  255,  0.75, 0.75,  0,  0.0 , 0.2,  0.0,  0.1,  3  );
			ShowSyncHudMsg(  iPlayer,  SyncHudMessage3,  "%s",  szHostName  );
		}
	}
	
}




stock GetInfo( id, const iInfo )
{
	
	new szInfoToReturn[  64  ];
	
	switch(  iInfo  )
	{
		case INFO_NAME:
		{
			new szName[ 32 ];
			get_user_name(  id,  szName,  sizeof ( szName ) -1  );
			
			copy(  szInfoToReturn,  sizeof ( szInfoToReturn ) -1,  szName  );
		}
		case INFO_IP:
		{
			new szIp[ 32 ];
			get_user_ip(  id,  szIp,  sizeof ( szIp ) -1,  1  );
			
			copy(  szInfoToReturn,  sizeof ( szInfoToReturn ) -1,  szIp  );
		}
		case INFO_AUTHID:
		{
			new szAuthId[ 35 ];
			get_user_authid(  id,  szAuthId,  sizeof ( szAuthId ) -1  );
			
			copy(  szInfoToReturn,  sizeof ( szInfoToReturn ) -1,  szAuthId  );
		}
	}

	return szInfoToReturn;
}

stock _get_time( )
{
	new logtime[ 32 ];
	get_time("%d.%m.%Y - %H:%M:%S", logtime ,sizeof ( logtime ) -1 );
	
	return logtime;
}

CC_ColorChat.inc | Afiseaza codul

/*              	        __________________________________
* 			       |Functiile originade create de Numb|
*			        ¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯

* 				Fisier rescris si fixat de Askhanar.
*

*				Copyright © 2012, Askhanar @disconnect.ro
*			Acest fisier este prevazut asa cum este ( fara garantii )
*/

#if defined _CC_ColorChat_included
  #endinput
#endif
#define _CC_ColorChat_included

enum Color
{
	NORMAL = 1, 		// Culoarea care o are jucatorul setata in cvar-ul scr_concolor.
	GREEN, 			// Culoare Verde.
	TEAM_COLOR, 		// Culoare Rosu, Albastru, Gri.
	GREY, 			// Culoarea Gri.
	RED, 			// Culoarea Rosu.
	BLUE, 			// Culoarea Albastru.
}

new TeamName[  ][  ] = 
{
	"",
	"TERRORIST",
	"CT",
	"SPECTATOR"
}

ColorChat(  id, Color:iType, const msg[  ], { Float, Sql, Result, _}:...  )
{
	
	// Daca nu se afla nici un jucator pe server oprim TOT. Altfel dam de erori..
	if( !get_playersnum( ) ) return;
	
	new szMessage[ 256 ];

	switch( iType )
	{
		 // Culoarea care o are jucatorul setata in cvar-ul scr_concolor.
		case NORMAL:	szMessage[ 0 ] = 0x01;
		
		// Culoare Verde.
		case GREEN:	szMessage[ 0 ] = 0x04;
		
		// Alb, Rosu, Albastru.
		default: 	szMessage[ 0 ] = 0x03;
	}

	vformat(  szMessage[ 1 ], 251, msg, 4  );

	// Ne asiguram ca mesajul nu este mai lung de 192 de caractere.Altfel pica server-ul.
	szMessage[ 192 ] = '^0';
	

	new iTeam, iColorChange, iPlayerIndex, MSG_Type;
	
	if( id )
	{
		MSG_Type  =  MSG_ONE_UNRELIABLE;
		iPlayerIndex  =  id;
	}
	else
	{
		iPlayerIndex  =  CC_FindPlayer(  );
		MSG_Type = MSG_ALL;
	}
	
	iTeam  =  get_user_team( iPlayerIndex );
	iColorChange  =  CC_ColorSelection(  iPlayerIndex,  MSG_Type, iType);

	CC_ShowColorMessage(  iPlayerIndex, MSG_Type, szMessage  );
		
	if(  iColorChange  )	CC_Team_Info(  iPlayerIndex, MSG_Type,  TeamName[ iTeam ]  );

}

CC_ShowColorMessage(  id, const iType, const szMessage[  ]  )
{
	
	static bool:bSayTextUsed;
	static iMsgSayText;
	
	if(  !bSayTextUsed  )
	{
		iMsgSayText  =  get_user_msgid( "SayText" );
		bSayTextUsed  =  true;
	}
	
	message_begin( iType, iMsgSayText, _, id  );
	write_byte(  id  )		
	write_string(  szMessage  );
	message_end(  );
}

CC_Team_Info( id, const iType, const szTeam[  ] )
{
	static bool:bTeamInfoUsed;
	static iMsgTeamInfo;
	if(  !bTeamInfoUsed  )
	{
		iMsgTeamInfo  =  get_user_msgid( "TeamInfo" );
		bTeamInfoUsed  =  true;
	}
	
	message_begin( iType, iMsgTeamInfo, _, id  );
	write_byte(  id  );
	write_string(  szTeam  );
	message_end(  );

	return 1;
}

CC_ColorSelection(  id, const iType, Color:iColorType)
{
	switch(  iColorType  )
	{
		
		case RED:	return CC_Team_Info(  id, iType, TeamName[ 1 ]  );
		case BLUE:	return CC_Team_Info(  id, iType, TeamName[ 2 ]  );
		case GREY:	return CC_Team_Info(  id, iType, TeamName[ 0 ]  );

	}

	return 0;
}

CC_FindPlayer(  )
{
	new iMaxPlayers  =  get_maxplayers(  );
	
	for( new i = 1; i <= iMaxPlayers; i++ )
		if(  is_user_connected( i )  )
			return i;
	
	return -1;
}

si cum arata o poza corecta:




si cum nu ar trebui sa arata ss

[alecs14]

The best ca intotdeauna !

Sper ca l.ai pus pe server da?:)

[Raul]

Este foarte interesant pluginul .
Multumim .

[Scooby112]

@Askhanar ...ca sa faci 3 poze nu se poate ? doar o poza ?
nu poti pune sa se faca mai multe poze ?:-?

[mixatu]

Interesant, asta impiedica codatii sa fraiereasca adminii.

[Ulquiorra]

@Askhanar ...ca sa faci 3 poze nu se poate ? doar o poza ?
nu poti pune sa se faca mai multe poze ?:-?

bind mouse3 "amx_ss nume"

si te uiti pe el.. si apesi pe mouse3 de 3 ori la rand.. si gata 3 poze...

EDIT: si .. si... si... :))) asta e am zis`o:))

[mixatu]

Nu merge linkul la fisierul sma. Te rog posteaza-l.