[REZOLVAT] Cerere plugin BONUS

[zLow123]

Plugin Cerut: Plugin /bonus CSGO REMAKE
Descriere (adica ce face el mai exact): In fiecare zi , prin intermediul acestei comenzi , poate sa-ti dea de la 1000 puncte la 4000, de la 5 cufere la 10, de la 5 key la 10 , de la 20 pulberi la 100 , etc , cum le setez eu.
Serverul impune conditii strict HLDS/REHLDS?:HLDS
Ai cautat pluginul?(daca da, precizeaza cum):Da , dar am gasit ceva , care nu are acel include.
Necesita mod special?:CSGO REMAKE 1GX
Native:
register_native("csgor_get_user_points", "native_get_user_points", 0);
register_native("csgor_set_user_points", "native_set_user_points", 0);
register_native("csgor_get_user_cases", "native_get_user_cases", 0);
register_native("csgor_set_user_cases", "native_set_user_cases", 0);
register_native("csgor_get_user_keys", "native_get_user_keys", 0);
register_native("csgor_set_user_keys", "native_set_user_keys", 0);
register_native("csgor_get_user_dusts", "native_get_user_dusts", 0);
register_native("csgor_set_user_dusts", "native_set_user_dusts", 0);
register_native("csgor_get_user_rang", "native_get_user_rang", 0);
register_native("csgor_set_user_rang", "native_set_user_rang", 0);
register_native("csgor_get_user_skins", "native_get_user_skins", 0);
register_native("csgor_set_user_skins", "native_set_user_skins", 0);
register_native("csgor_is_user_logged", "native_is_user_logged", 0);

[Shadows Adi]

[spoiler]https://leaguecs.ro/forum/index.php?/to ... go-remake/[/spoiler]

[zLow123]

Daca s-ar putea , cu meniu , sa alegi tu ce sa pice...

[Capy Trifoi]

| Afiseaza codul

#include < amxmodx >
#include < nvault >
#include < colorchat >
#include < csgo_remake >

#define MAXIM_POINTS 10
#define MAXIM_DUSTS 10
#define MAXIM_CASES 10
#define MAXIM_KEYS 10

new g_szAuthId[ 33 ][ 36 ], g_szDay[ 3 ], g_iVault, g_iDay;

public plugin_init( )
{
	register_plugin( "Daily Login Reward", "1.0", "OciXCrom" );
	get_time( "%d", g_szDay, charsmax( g_szDay ) );
	g_iDay = str_to_num( g_szDay );
	g_iVault = nvault_open( "DailyRewards" );
	if( g_iVault == INVALID_HANDLE )	set_fail_state( "I got some problems for ^"DailyRewards^" ." );
	register_clcmd( "say /bonus", "PreDailyReward" );
}

public client_authorized( id )	if( !is_user_bot( id ) || !is_user_hltv( id ) )	get_user_authid( id, g_szAuthId[ id ], charsmax( g_szAuthId[ ] ) );

public PreDailyReward( id ) {
	if( !csgor_is_user_logged( id ) )	return;
	
	new iDay = nvault_get( g_iVault, g_szAuthId[ id ] ); 
	if( !iDay || iDay != g_iDay )	DailyReward( id );
	else	ColorChat( id, RED, "^1You have taken today's daily reward." );
}
public DailyReward( id ) {
	new menu = menu_create( "Daily Bonus", "reward_handler" );
	
	menu_additem( menu, "Cases" );
	menu_additem( menu, "Keys" );
	menu_additem( menu, "Points" );
	menu_additem( menu, "Dusts" );
	
	menu_setprop( menu, MPROP_EXIT, MEXIT_ALL );
	menu_display( id, menu, 0 );
}
public reward_handler( id, menu, item )
{
	new rand;
	switch( item )
	{
		case 0:
		{
			rand = random( MAXIM_CASES );
			csgor_set_user_cases( id, csgor_get_user_cases( id ) + rand );
			ColorChat( id, RED, "^1Rewarded -^4 %d^1 cas%s", rand, rand == 1 ? "" : "s" );
		}
		case 1:
		{
			rand = random( MAXIM_KEYS );
			csgor_set_user_keys( id, csgor_get_user_keys( id ) + rand );
			ColorChat( id, RED, "^1Rewarded -^4 %d^1 key%s", rand, rand == 1 ? "" : "s" );
		}
		case 2:
		{
			rand = random( MAXIM_POINTS );
			csgor_set_user_points( id, csgor_get_user_points( id ) + rand );
			ColorChat( id, RED, "^1Rewarded -^4 %d^1 point%s",rand, rand == 1 ? "" : "s" );
		}
		case 3:
		{
			rand = random( MAXIM_DUSTS );
			csgor_set_user_dusts( id, csgor_get_user_dusts( id ) + rand );
			ColorChat( id, RED, "^1Rewarded -^4 %d^1 dust%s", rand, rand == 1 ? "" : "s" );
		}
	}
	nvault_set( g_iVault, g_szAuthId[ id ], g_szDay );
}

public plugin_end( )	if( g_iVault != INVALID_HANDLE )	nvault_close( g_iVault );

#pragma tabsize 0

de aici

| Afiseaza codul

#define MAXIM_POINTS 10
#define MAXIM_DUSTS 10
#define MAXIM_CASES 10
#define MAXIM_KEYS 10

iti modifici dupa bunul plac

[zLow123]

| Afiseaza codul

#include < amxmodx >
#include < nvault >
#include < colorchat >
#include < csgo_remake >

#define MAXIM_POINTS 10
#define MAXIM_DUSTS 10
#define MAXIM_CASES 10
#define MAXIM_KEYS 10

new g_szAuthId[ 33 ][ 36 ], g_szDay[ 3 ], g_iVault, g_iDay;

public plugin_init( )
{
	register_plugin( "Daily Login Reward", "1.0", "OciXCrom" );
	get_time( "%d", g_szDay, charsmax( g_szDay ) );
	g_iDay = str_to_num( g_szDay );
	g_iVault = nvault_open( "DailyRewards" );
	if( g_iVault == INVALID_HANDLE )	set_fail_state( "I got some problems for ^"DailyRewards^" ." );
	register_clcmd( "say /bonus", "PreDailyReward" );
}

public client_authorized( id )	if( !is_user_bot( id ) || !is_user_hltv( id ) )	get_user_authid( id, g_szAuthId[ id ], charsmax( g_szAuthId[ ] ) );

public PreDailyReward( id ) {
	if( !csgor_is_user_logged( id ) )	return;
	
	new iDay = nvault_get( g_iVault, g_szAuthId[ id ] ); 
	if( !iDay || iDay != g_iDay )	DailyReward( id );
	else	ColorChat( id, RED, "^1You have taken today's daily reward." );
}
public DailyReward( id ) {
	new menu = menu_create( "Daily Bonus", "reward_handler" );
	
	menu_additem( menu, "Cases" );
	menu_additem( menu, "Keys" );
	menu_additem( menu, "Points" );
	menu_additem( menu, "Dusts" );
	
	menu_setprop( menu, MPROP_EXIT, MEXIT_ALL );
	menu_display( id, menu, 0 );
}
public reward_handler( id, menu, item )
{
	new rand;
	switch( item )
	{
		case 0:
		{
			rand = random( MAXIM_CASES );
			csgor_set_user_cases( id, csgor_get_user_cases( id ) + rand );
			ColorChat( id, RED, "^1Rewarded -^4 %d^1 cas%s", rand, rand == 1 ? "" : "s" );
		}
		case 1:
		{
			rand = random( MAXIM_KEYS );
			csgor_set_user_keys( id, csgor_get_user_keys( id ) + rand );
			ColorChat( id, RED, "^1Rewarded -^4 %d^1 key%s", rand, rand == 1 ? "" : "s" );
		}
		case 2:
		{
			rand = random( MAXIM_POINTS );
			csgor_set_user_points( id, csgor_get_user_points( id ) + rand );
			ColorChat( id, RED, "^1Rewarded -^4 %d^1 point%s",rand, rand == 1 ? "" : "s" );
		}
		case 3:
		{
			rand = random( MAXIM_DUSTS );
			csgor_set_user_dusts( id, csgor_get_user_dusts( id ) + rand );
			ColorChat( id, RED, "^1Rewarded -^4 %d^1 dust%s", rand, rand == 1 ? "" : "s" );
		}
	}
	nvault_set( g_iVault, g_szAuthId[ id ], g_szDay );
}

public plugin_end( )	if( g_iVault != INVALID_HANDLE )	nvault_close( g_iVault );

#pragma tabsize 0

de aici

| Afiseaza codul

#define MAXIM_POINTS 10
#define MAXIM_DUSTS 10
#define MAXIM_CASES 10
#define MAXIM_KEYS 10

iti modifici dupa bunul plac

Îmi poți lăsa si inc-ul ? Că ăsta l-am găsit pe net , dar nu găseam include-ul

[robbencsgo]

Code: Select all

#if defined _csgo_remake_included
	#endinput
#endif

#define _csgo_remake_included

//#pragma reqlib csgo_remake

#if AMXX_VERSION_NUM >= 175
	#pragma reqlib csgo_remake
	#if !defined AMXMODX_NOAUTOLOAD
		#pragma loadlib csgo_remake
	#endif
#else
	#pragma library csgo_remake
#endif

/**
 * Returns a player's points.
 *
 * @param id		Player index.
 * @return			Amount of points. -1 on error.
 */
native csgor_get_user_points(id);

/**
 * Sets a player's points to the desired amount.
 *
 * @param id		Player index.
 * @param amount	A valid amount of points.
 * @return			True on success, false otherwise.
 */
native csgor_set_user_points(id, amount);

/**
 * Returns a player's dusts.
 *
 * @param id		Player index.
 * @return			Amount of dusts. -1 on error.
 */
native csgor_get_user_dusts(id);

/**
 * Sets a player's dusts to the desired amount.
 *
 * @param id		Player index.
 * @param amount	A valid amount of dusts.
 * @return			True on success, false otherwise.
 */
native csgor_set_user_dusts(id, amount);

/**
 * Returns a player's keys.
 *
 * @param id		Player index.
 * @return			Amount of keys. -1 on error.
 */
native csgor_get_user_keys(id);

/**
 * Sets a player's keys to the desired amount.
 *
 * @param id		Player index.
 * @param amount	A valid amount of keys.
 * @return			True on success, false otherwise.
 */
native csgor_set_user_keys(id, amount);

/**
 * Returns a player's cases.
 *
 * @param id		Player index.
 * @return			Amount of cases. -1 on error.
 */
native csgor_get_user_cases(id);

/**
 * Sets a player's cases to the desired amount.
 *
 * @param id		Player index.
 * @param amount	A valid amount of cases.
 * @return			True on success, false otherwise.
 */
native csgor_set_user_cases(id, amount);

/**
 * Returns a player's Rang ID. Set Rang name in output.
 *
 * @param id		Player index.
 * @param output	Output array for rang name.
 * @param len		Max length of a output array.
 * @return			Player Rang ID. -1 on error.
 */
native csgor_get_user_rang(id, output[], len);

/**
 * Sets a player's Rang ID. Set the appropriate amount of kills.
 *
 * @param id		Player index.
 * @param rangid	A valid Rang ID.
 * @return			True on success, false otherwise.
 */
native csgor_set_user_rang(id, rangid);

/**
 * Returns a player's amount of skins by specified Skin ID.
 *
 * @param id		Player index.
 * @param skinid	A valid Skin ID.
 * @return			Amount of skins. -1 on error.
 */
native csgor_get_user_skins(id, skinid);

/**
 * Sets a player's skins (by specific Skin ID) to desired amount.
 *
 * @param id		Player index.
 * @param skinid	A valid Skin ID.
 * @param amount	A valid amount of skins.
 * @return			True on success, false otherwise.
 */
native csgor_set_user_skins(id, skinid, amount);

/**
 * Returns whether a player is logged.
 *
 * @param id		Player index.
 * @return			True if it is, false otherwise.
 */
native csgor_is_user_logged(id);

/**
 * Called when a player log in account.
 *
 * @param id		Player index forwarding the event.
 */
forward csgor_user_log_in(id);

/**
 * Called when a player make assist.
 *
 * @param id			Assist index.
 * @param killer		Killer index.
 * @param victim		Victim index.
 * @param head			1 if HeadShot, 0 otherwise.
 */
forward csgor_user_assist(id, killer, victim, head);

/**
 * Called when a player is MVP.
 *
 * @param id			MVP index.
 * @param event			Event type. (0 - Top Killer, 1 - Planter, 2 - Defuser)
 * @param kills			Player's kills.
 */
forward csgor_user_mvp(id, event, kills);

[zLow123]

Rezolvat , mersi.