[Cerere Plugin] grenade trail modificat cu random colors!

[RaFy1995]

Plugin Cerut: Grenade Trail modificat cu random colors sa aiba ceva effect frumos nu doar linia aia
Descriere (adica ce face el mai exact): https://screenshots.gamebanana.com/img/ ... b1851.webp
Serverul impune conditii strict HLDS/REHLDS?: REHLDS
Ai cautat pluginul?(daca da, precizeaza cum): Da am cautat pe Alliedmodders sau pe gamebanana,
Necesita mod special?: Am vorbit cu Carnacior aseara si mi-a spus sa fac cerere pentru ca nu este asa de complicat, doresc sa fie random colors la He!

Cu stima!

[robbencsgo]

Code: Select all

/*
	Grenade Trail 1.0
	Author: Jim

	Cvars:
	grenade_tr: default 2
	0 - None
	1 - Random Colors
	2 - Nade Specific
	3 - Team Specific

	grenade_he "255000000" set the trail color of Hegrenade
	grenade_fb "000000255" set the trail color of Flashbang
	grenade_sg "000255000" set the trail color of Smokegrenade
*/

#include <amxmodx>
#include <csx>

#define PLUGIN "Grenade Trail"
#define VERSION "1.0"
#define AUTHOR "Jim"

new g_cvar_tr
new g_cvar_he
new g_cvar_fb
new g_cvar_sg
new g_trail

public plugin_init()
{
	register_plugin(PLUGIN, VERSION, AUTHOR)
	g_cvar_tr = register_cvar("grenade_tr", "1")
	g_cvar_he = register_cvar("grenade_he", "255000000")
	g_cvar_fb = register_cvar("grenade_fb", "000000255")
	g_cvar_sg = register_cvar("grenade_sg", "000255000")
}

public plugin_precache()
{
	g_trail = precache_model("sprites/smoke.spr")
}

public grenade_throw(id, gid, wid)
{
	new gtm = get_pcvar_num(g_cvar_tr)
	if(!gtm) return
	new r, g, b
	switch(gtm)
	{
		case 1:
		{
			r = random(256)
			g = random(256)
			b = random(256)
		}
		case 2:
		{
			new nade, color[10]
			switch(wid)
			{
				case CSW_HEGRENADE:	nade = g_cvar_he
				case CSW_FLASHBANG:	nade = g_cvar_fb
				case CSW_SMOKEGRENADE:	nade = g_cvar_sg
			}
			get_pcvar_string(nade, color, 9)
			new c = str_to_num(color)
			r = c / 1000000
			c %= 1000000 
			g = c / 1000
			b = c % 1000
		}
		case 3:
		{
			switch(get_user_team(id))
			{
				case 1: r = 255
				case 2: b = 255
			}
		}
	}
	message_begin(MSG_BROADCAST, SVC_TEMPENTITY)
	write_byte(TE_BEAMFOLLOW)
	write_short(gid)
	write_short(g_trail)
	write_byte(10)
	write_byte(5)
	write_byte(r)
	write_byte(g)
	write_byte(b)
	write_byte(192)
	message_end()
}

cvar: grenade_tr 1/2/3

1 - Culori random
2 - He trail rosu, Flash trail alb, Smoke trail verde sau ce setezi tu prin cvar-uri(grenade_he, grenade_fb, grenade_sg)
3 - Tero arunca He, flash, smoke cu trail rosu iar CT arunca cu culoarea albastra.

[darkallience3]

Folositor!