Adaugare text intre orele X - Y

[Trudix]

Va salut!

Ma poate ajuta cineva sa adauge dupa [ /SHOP /BUYVIP /INFO /BOOST ] text FREE VIP EVENT: ON doar intre orele 22:00 - 10:00, ca mai apoi sa dispara?

Code: Select all

#include amxmodx

#define p. "Info HUD (2)"
#define v. "1.1"
#define a. "Jică Măcelaru'"

new pCvar;
new bool:g_bFreeVipTime;

public plugin_init ( ) {
	register_plugin(p., v., a.);
	
	pCvar = register_cvar ( "change_hud", "1" ); // 0 - off; 1 - hud; 2 - dhud
	
	set_task( 0.3, "infoHud2" ,_,_,_, "b" );
}

public infoHud2 ( ) {
	new hostname [ 62 ], 
		map [ 32 ],
		ora [ 6 ],
		timeleft = get_timeleft ( ),
		players;

	get_cvar_string( "hostname", hostname, charsmax ( hostname ) );
	get_mapname( map, charsmax(map) )
	get_time( "%H:%M", ora, charsmax ( ora ) )
	players = get_playersnum ( 1 );
	
	static r, g, b; r = random_num( 0, 255 ); g = random_num( 0, 255 ); b = random_num( 0, 255 );
	
	if ( get_pcvar_num ( pCvar ) == 1 ) {
		set_hudmessage( r, g, b, -1.0, 0.0, 1, 0.3, 0.3, 0.0, 0.0, -1 );
		show_hudmessage( 0, "DNS: RESPAWN.DARKCS.RO | Players: %d/32^nMap: %s | Timeleft: %d:%02d | Time: %s ^n[ /SHOP /BUYVIP /INFO /BOOST ]", players, map, timeleft / 60, timeleft % 60, ora );
	}
	
	else if ( get_pcvar_num ( pCvar ) == 2 ) {
		set_dhudmessage( r, g, b, -1.0, 0.0, 1, 0.1, 0.2 );
		show_dhudmessage( 0, "DNS: RESPAWN.DARKCS.RO | Players %d/32^nMap: %s | Timeleft: %d:%02d | Time: %s ^n[ /SHOP /BUYVIP /INFO /BOOST ]", players, map, timeleft / 60, timeleft % 60, ora );
	}
}

[levin]

g_bFreeVipTime nu e folosit în plg ăsta

[DaNNe.]

| Afiseaza codul

#include amxmodx
#include <dhudmessage>

#define p. "Info HUD (2)"
#define v. "1.1"
#define a. "Jică Măcelaru'"

new pCvar;
new bool:g_bFreeVipTime;

public plugin_init ( ) {
	register_plugin(p., v., a.);
	
	pCvar = register_cvar ( "change_hud", "1" ); // 0 - off; 1 - hud; 2 - dhud
	
	set_task( 0.3, "infoHud2" ,_,_,_, "b" );
}

public infoHud2 ( ) {
	new hostname [ 62 ], 
		map [ 32 ],
		ora [ 6 ],
		timeleft = get_timeleft ( ),
		players,
		Message[254], MessageLen 	= charsmax(Message),
		Hour;

	get_cvar_string( "hostname", hostname, charsmax ( hostname ) );
	get_mapname( map, charsmax(map) )
	get_time( "%H:%M", ora, charsmax ( ora ) )
	players = get_playersnum ( 1 );
	Hour = str_to_num(ora)
	static r, g, b; r = random_num( 0, 255 ); g = random_num( 0, 255 ); b = random_num( 0, 255 );
	if(Hour >= 22 || Hour < 10)
		formatex(Message, MessageLen, "DNS: RESPAWN.DARKCS.RO | Players: %d/32^nMap: %s | Timeleft: %d:%02d | Time: %s ^n[ /SHOP /BUYVIP /INFO /BOOST ] - FREE VIP EVENT ON", players, map, timeleft / 60, timeleft % 60, ora);
	else 
		formatex(Message, MessageLen, "DNS: RESPAWN.DARKCS.RO | Players: %d/32^nMap: %s | Timeleft: %d:%02d | Time: %s ^n[ /SHOP /BUYVIP /INFO /BOOST ]", players, map, timeleft / 60, timeleft % 60, ora);
		
	switch(get_pcvar_num(pCvar)) {
		case 1: {
			set_hudmessage( r, g, b, -1.0, 0.0, 1, 0.3, 0.3, 0.0, 0.0, -1 );
			show_hudmessage( 0, "%s", Message);
		}
		case 2: {		
			set_dhudmessage( r, g, b, -1.0, 0.0, 1, 0.1, 0.2 );
			show_dhudmessage( 0, "%s", Message);
		}	
	}
}