PLUGIN MVP

[GENERALU']

Cine imi coloreaza mesajele din chat? Tagul sa fie cu verde [MVP], enuntul cu, culoarea echipei iar numele jucatorului tot cu verde. Multumesc :)

| Afiseaza codul

/* Plugin generated by AMXX-Studio */

#include <amxmodx>
#include <amxmisc>
#include <cstrike>
#include <fakemeta_util>
#include <dhudmessage>
#include <csx>

#define PLUGIN "MVP"
#define VERSION "1.0.3"
#define AUTHOR "Kia"

// ===============================================================================
// 	Variables
// ===============================================================================

/* Defines */

#define NO_BOMB_PLANTED 9191
#define NO_BOMB_DEFUSED 1919

#define CHECK_DELAY 0.5

/* Integers */

new g_iEnemiesKilled[33]
new g_iHostagesRescued[33]

new g_iBombPlanter
new g_iBombDefuser

/* Boolean */

new bool:g_bBombExploded
new bool:g_bAllHostagesRescued

// ===============================================================================
// 	plugin_init
// ===============================================================================

public plugin_init() 
{
	register_plugin(PLUGIN, VERSION, AUTHOR)
	
	/* Events */
	
	register_event("HLTV", "Event_NewRound", "a", "1=0", "2=0") 
	
	register_event("SendAudio", "Event_RoundWon_T" , "a", "2&%!MRAD_terwin") 
	register_event("SendAudio", "Event_RoundWon_CT", "a", "2&%!MRAD_ctwin")
	register_event("TextMsg", "Event_AllHostagesRescued", "a", "2&#All_Hostages_R");
	
	register_logevent("Event_HostageRescued", 3, "2=Rescued_A_Hostage") 
	
	register_event("DeathMsg", "Event_DeathMsg", "a")
}

// ===============================================================================
// 	Event_NewRound - Called when a new Round begins
// ===============================================================================

public Event_NewRound()
{
	g_iBombPlanter = NO_BOMB_PLANTED
	g_iBombDefuser = NO_BOMB_DEFUSED
	
	g_bBombExploded = false
	g_bAllHostagesRescued = false
	
	arrayset(g_iEnemiesKilled, 0, sizeof(g_iEnemiesKilled))
	arrayset(g_iHostagesRescued, 0 , sizeof(g_iHostagesRescued))
}

// ===============================================================================
// 	Event_RoundWon_T - Called when the Counter-Terrorists when the Round
// ===============================================================================

public Event_RoundWon_T()
{
	set_task(CHECK_DELAY, "CheckTConditions")
}

public CheckTConditions()
{
	if(g_iBombPlanter != NO_BOMB_PLANTED && g_bBombExploded == false)
	{
		new iTopKiller = GetTopKiller(1)
		ShowMVPMessage(iTopKiller, 1)
		
		return PLUGIN_HANDLED
	}
	
	/*new iTopKiller = GetTopKiller(1)
	ShowMVPMessage(iTopKiller, 1)*/
	
	return PLUGIN_HANDLED
}

// ===============================================================================
// 	Event_RoundWon_CT - Called when the Counter-Terrorists when the Round
// ===============================================================================

public Event_RoundWon_CT()
{
	set_task(CHECK_DELAY, "CheckCTConditions")
}

public CheckCTConditions()
{
	if(g_iBombDefuser != NO_BOMB_DEFUSED)
	{
		ShowMVPMessage(g_iBombDefuser, 2)
		return PLUGIN_HANDLED
	}
	
	if(g_bAllHostagesRescued)
	{
		new iTopRescuer = GetTopRescuer()
		ShowMVPMessage(iTopRescuer, 4)
		
		return PLUGIN_HANDLED
	}
	
	new iTopKiller = GetTopKiller(2)
	ShowMVPMessage(iTopKiller, 1)
	
	return PLUGIN_HANDLED
}

// ===============================================================================
// 	Event_AllHostagesRescued - Called when ALL Hostages were rescued
// ===============================================================================

public Event_AllHostagesRescued()
{
	g_bAllHostagesRescued = true
	
	new iTopRescuer = GetTopRescuer()
	ShowMVPMessage(iTopRescuer, 4)	
}

// ===============================================================================
// 	Event_HostageRescued - Called when ONE Hostage was rescued
// ===============================================================================

public Event_HostageRescued()
{
	static szLog[80], szName[32], id
	
	read_logargv(0, szLog, charsmax(szLog))
	parse_loguser(szLog, szName, charsmax(szName))
	
	id = get_user_index(szName)
	
	g_iHostagesRescued[id]++
}	

// ===============================================================================
// 	Event_DeathMsg - Called when someone dies
// ===============================================================================

public Event_DeathMsg()
	g_iEnemiesKilled[read_data(1)]++

// ===============================================================================
// 	bomb_planted - Called when the Bomb was planted
// ===============================================================================

public bomb_planted(iPlanter)
	g_iBombPlanter = iPlanter
	
// ===============================================================================
//  	bomb_explode - Called when the Bomb exploded
// ===============================================================================

public bomb_explode(iPlanter, iDefuser)
{
	g_bBombExploded = true
	ShowMVPMessage(g_iBombPlanter, 3)
}
	
// ===============================================================================
// 	bomb_defused - Called when the Bomb was defused
// ===============================================================================

public bomb_defused(iDefuser)
	g_iBombDefuser = iDefuser
	
// ===============================================================================
// 	GetTopKiller - Returns the id of the player who made the most kills
// ===============================================================================

public GetTopKiller(iTeam) // 1 : Terrorist - 2 : Counter-Terrorists
{
	new iPlayers[32], iPlayersnum;
	
	get_players(iPlayers, iPlayersnum, "e", iTeam == 1 ? "TERRORIST" : "CT")
	SortCustom1D(iPlayers, iPlayersnum, "SortByKills")
	
	return iPlayers[0]
}

public SortByKills(elem1, elem2) 
{
	if ( g_iEnemiesKilled[elem1] > g_iEnemiesKilled[elem2] )
		return -1
	else if ( g_iEnemiesKilled[elem1] < g_iEnemiesKilled[elem2] )
		return 1
	return 0
}

// ===============================================================================
// 	GetTopRescuer - Returns the id of the player who rescued the most hostages
// ===============================================================================

public GetTopRescuer() // 1 : Terrorist - 2 : Counter-Terrorists
{
	new iPlayers[32], iPlayersnum;
	
	get_players(iPlayers, iPlayersnum, "e", "CT")
	SortCustom1D(iPlayers, iPlayersnum, "SortByHostages")
	
	return iPlayers[0]
}

public SortByHostages(elem1, elem2) 
{
	if ( g_iHostagesRescued[elem1] > g_iHostagesRescued[elem2] )
		return -1
	else if ( g_iHostagesRescued[elem1] < g_iHostagesRescued[elem2] )
		return 1
	return 0
}

// ===============================================================================
// 	ShowMVPMessage - Shows the Director HUD Message
// ===============================================================================

public ShowMVPMessage(iMVP, iReason) // 1 : Kills - 2 : Bomb defused - 3 : Bomb exploded - 4 : Hostage rescued
{
	new szMVPName[33]
	get_user_name(iMVP, szMVPName, charsmax(szMVPName))
	
	set_dhudmessage(0, 255, 0, -1.0, 0.15, 0, 6.0, 12.0)
	
	switch(iReason)
	{
	//	case 1: show_dhudmessage(0, "MVP : %s for making the most kills this round.", szMVPName)
	//	case 2: show_dhudmessage(0, "MVP : %s for defusing the Bomb.", szMVPName)
	//	case 3: show_dhudmessage(0, "MVP : %s for planting the Bomb.", szMVPName)
	//	case 4: show_dhudmessage(0, "MVP : %s for rescuing %i Hostages.", szMVPName, g_iHostagesRescued[iMVP])

                case 1: client_print(0, print_chat, "MVP : %s for making the most kills this round.", szMVPName)
		case 2: client_print(0, print_chat, "MVP : %s for defusing the Bomb.", szMVPName)
		case 3: client_print(0, print_chat, "MVP : %s for planting the Bomb.", szMVPName)
		case 4: client_print(0, print_chat, "MVP : %s for rescuing %i Hostages.", szMVPName, g_iHostagesRescued[iMVP])
	}		
}
/* AMXX-Studio Notes - DO NOT MODIFY BELOW HERE
*{\\ rtf1\\ ansi\\ deff0{\\ fonttbl{\\ f0\\ fnil Tahoma;}}\n\\ viewkind4\\ uc1\\ pard\\ lang1031\\ f0\\ fs16 \n\\ par }
*/

[Laurentiu P.]

Adaugi la sfarsitul sursei

Code: Select all

stock print_color( const id, const input[ ], any:... )
{
new count = 1, players[ 32 ]

static msg[ 191 ]
vformat( msg, 190, input, 3 )

replace_all( msg, 190, "!v", "^4" ) //- verde
replace_all( msg, 190, "!g", "^1" ) //- galben
replace_all( msg, 190, "!e", "^3" ) //- echipa
replace_all( msg, 190, "!n", "^0" ) //- normal

if( id ) players[ 0 ] = id; else get_players( players, count, "ch" )
{
for( new i = 0; i < count; i++ )
{
if( is_user_connected( players[ i ] ) )
{
message_begin( MSG_ONE_UNRELIABLE, get_user_msgid( "SayText" ), _, players[ i ] )
write_byte( players[ i ] );
write_string( msg );
message_end( );
}
}
}
}

Iar case-urile alea 4 le schimbi cu asta

| Afiseaza codul

case 1: print_color(0, "!vMVP : %s !efor making the most kills this round.", szMVPName)
case 2: print_color(0, "!vMVP : %s !efor defusing the Bomb.", szMVPName)
case 3: print_color(0, "!vMVP : %s !efor planting the Bomb.", szMVPName)
case 4: print_color(0, "!vMVP : %s !efor rescuing !v%i !eHostages.", szMVPName, g_iHostagesRescued[iMVP])

[*Or!g!naL*]

mutat la modificari