Cerere Plugin Oameni

[J3FF]

R.I.P :D

[J3FF]

Nu am nimic impotriva , dar dai dovada de ripper , nu e vorba ca e acelasi , ci e vorba de idee , cauta si tu ceva mai original , nu ma deranjaza cu nimic , dar gestul ...

Imi pare rau pentru comentariu


EDIT: N-am nevoie , oricum nu sti sa administrezi unul , degeaba ai pluginuri calumea , tot gol o sa ramana , pace

[K1d0x]

| Afiseaza codul

#include <amxmodx>
#include <amxmisc>
#include <cstrike>
#include <hamsandwich>
#include <fun>

new gMode, gArmor, gHealth, gGravity, g_Meniu, g_optiuni[4];

public plugin_init() {
     register_plugin("Human Class", "1.0", "K!D()X");
     gMode = register_cvar("class_h_mode", "1");
     gArmor = register_cvar("class_h_armor", "1000");
     gHealth = register_cvar("class_h_health", "250");
     gGravity = register_cvar("class_h_gravity", "600.0");

     if(get_pcvar_num(gMode) == 1) {
          register_clcmd("say /class_h", "creaza_meniu");
     }

     RegisterHam(Ham_Spawn, "player", "ham_PlayerSpawn", 1);
     g_Meniu = menu_create("Human CLASS", "continut");
     build_menu();
}

public ham_PlayerSpawn(id) {
     if(is_user_bot(id) && !is_user_alive(id))
          return PLUGIN_HANDLED;

     if(get_pcvar_num(gMode) == 0 || cs_get_user_team(id) == CS_TEAM_CT) {
          set_task(4.0, "creaza_meniu", id);
     }

     return PLUGIN_HANDLED;
}

build_menu() {
	menu_additem(g_Meniu, "Classic Human", "1");
	menu_additem(g_Meniu, "Big Human", "2");
	menu_additem(g_Meniu, "Jump Human", "3");
	menu_additem(g_Meniu, "Infect Human", "5");
	menu_setprop(g_Meniu, MPROP_EXIT, MEXIT_ALL);
}

public creaza_meniu(id) {
	if(cs_get_user_team(id) == CS_TEAM_CT) {
		menu_display(id, g_Meniu, 0);

		if(get_pcvar_num(gMode) == 0) {
			remove_task(id);
		}
	}
}

public continut(id, menu, item) {
	if( item < 0 ) return PLUGIN_CONTINUE;
 
	new cmd[3];
	new access, callback;
 
	menu_item_getinfo(menu, item, access, cmd,2,_,_, callback);
 
	new iAlegere = str_to_num(cmd);
 
	g_optiuni[iAlegere]++;
 
	switch(iAlegere)
	{
		case 1:
		{
			if(is_user_alive(id) && cs_get_user_team(id) == CS_TEAM_CT) {
				/* Reset all player options */
				set_user_health(id, 100);
				set_user_gravity(id, 800.0);
				set_user_armor(id, 0);
			}
		}
		case 2:
		{
			if(is_user_alive(id) && cs_get_user_team(id) == CS_TEAM_CT) {
				set_user_health(id, get_pcvar_num(gHealth));
			}
		}
		case 3:
		{
			if(is_user_alive(id) && cs_get_user_team(id) == CS_TEAM_CT) {
				set_user_gravity(id, get_pcvar_float(gGravity));
			}
		}
		case 4:
		{
			if(is_user_alive(id) && cs_get_user_team(id) == CS_TEAM_CT) {
				set_user_armor(id, get_pcvar_num(gArmor));
			}
		}
	}

	return PLUGIN_HANDLED;
}

[K1d0x]

| Afiseaza codul

#include <amxmodx>
#include <amxmisc>
#include <cstrike>
#include <hamsandwich>
#include <fun>

new gMode, gArmor, gHealth, gGravity, g_Meniu, g_optiuni[4];

public plugin_init() {
     register_plugin("Human Class", "1.0", "K!D()X");
     gMode = register_cvar("class_h_mode", "1");
     gArmor = register_cvar("class_h_armor", "1000");
     gHealth = register_cvar("class_h_health", "250");
     gGravity = register_cvar("class_h_gravity", "600.0");

     if(get_pcvar_num(gMode) == 1) {
          register_clcmd("say /class_h", "creaza_meniu");
     }

     RegisterHam(Ham_Spawn, "player", "ham_PlayerSpawn", 1);
     g_Meniu = menu_create("Human CLASS", "continut");
     build_menu();
}

public ham_PlayerSpawn(id) {
     if(is_user_bot(id) && !is_user_alive(id))
          return PLUGIN_HANDLED;

     if(get_pcvar_num(gMode) == 0 || cs_get_user_team(id) == CS_TEAM_CT) {
          set_task(4.0, "creaza_meniu", id);
     }

     return PLUGIN_HANDLED;
}

build_menu() {
	menu_additem(g_Meniu, "Classic Human", "1");
	menu_additem(g_Meniu, "Big Human", "2");
	menu_additem(g_Meniu, "Jump Human", "3");
	menu_additem(g_Meniu, "Infect Human", "5");
	menu_setprop(g_Meniu, MPROP_EXIT, MEXIT_ALL);
}

public creaza_meniu(id) {
	if(cs_get_user_team(id) == CS_TEAM_CT) {
		menu_display(id, g_Meniu, 0);

		if(get_pcvar_num(gMode) == 0) {
			remove_task(id);
		}
	}
}

public continut(id, menu, item) {
	if( item < 0 ) return PLUGIN_CONTINUE;
 
	new cmd[3];
	new access, callback;
 
	menu_item_getinfo(menu, item, access, cmd,2,_,_, callback);
 
	new iAlegere = str_to_num(cmd);
 	new szArmor = get_pcvar_num(gArmor)
	new szGravity = get_pcvar_num(gGravity)
	
	g_optiuni[iAlegere]++;
 
	switch(iAlegere)
	{
		case 1:
		{
			if(is_user_alive(id) && cs_get_user_team(id) == CS_TEAM_CT) {
				/* Reset all player options */
				set_user_health(id, 100);
				set_user_gravity(id, 800.0);
				set_user_armor(id, 0);
			}
		}
		case 2:
		{
			if(is_user_alive(id) && cs_get_user_team(id) == CS_TEAM_CT) {
				set_user_health(id, get_pcvar_num(gHealth));
			}
		}
		case 3:
		{
			if(is_user_alive(id) && cs_get_user_team(id) == CS_TEAM_CT) {
				set_user_gravity(id, szGravity);
			}
		}
		case 4:
		{
			if(is_user_alive(id) && cs_get_user_team(id) == CS_TEAM_CT) {
				set_user_armor(id, szArmor);
			}
		}
	}

	return PLUGIN_HANDLED;
}

[K1d0x]

Am testat si merge :) iar la gravity setezi prin cvar in loc de 600.0 pui 400 sau 300

[Ulquiorra]

ti-am facut un mega plugin :))

Modifici ce este cu #define.. ai toate explicatiile in .sma

o sa fie un singur bug..
de ex:
sunt ct m-a atacat zm si mai am 50 hp.. dau repede /race si iau alta clasa.. si imi va da hp sau armura.. depinde ce are clasa.
bug-ul poate fi fixat..modificand

Code: Select all

new  gUserCanChangeRace  din 1 in 0 adica nu mai merge comanda /race..

BB Humans Races | Afiseaza codul

#include <  amxmodx  >
#include <  cstrike  >
#include <  hamsandwich  >
#include <  fun >
#include <  ColorChat  >


#pragma semicolon 1


#define PLUGIN "BB Humans Races"
#define VERSION "1.0"


//	Valoride default  (  cand un jucator isi schimba clasa.. ii sunt setate intai setarile default iar,
//					dupa ce i-au fost setate cele default i se seteaza cele de la clasa  ).

#define		DEFAULT_HP		100			// Cat hp ii este setat default.
#define		DEFAULT_ARMOUR		0			// Cata armura ii este setata default.



//	Rasa CLASIC_HUMAN  ( este echilibrat si are din toate cate putin !  )
#define		CLASIC_HUMAN_HP		150			// Cat hp sa primeasca.
#define		CLASIC_HUMAN_GRAVITY	0.7			// Cat de mult sare ( 1.0 inseamna 800 gravity.. 0.8 vine cam 600 ).
#define		CLASIC_HUMAN_ARMOUR	300			// Cata armura sa primeasca.



//	Rasa BIG_HUMAN   ( are mult hp  )
#define		BIG_HUMAN_HP		500			// Cat hp sa primeasca.



//	Rasa JUMPER_HUMAN   (  sare mult  )
#define		JUMPER_HUMAN_GRAVITY	0.5			// Cat de mult sare ( 1.0 inseamna 800 gravity.. 0.5 vine cam 400 ).



//	Rasa INFECT_HUMAN   (  are multa armura  )		
#define		INFECT_HUMAN_ARMOUR	750			// Cata armura sa primeasca.


//  Nu umbla aici.. sunt clasele..

enum
{
	CLASS_NONE = 0,
	CLASS_CLASIC_HUMAN = 1,
	CLASS_BIG_HUMAN = 2,
	CLASS_JUMPER_HUMAN = 3,
	CLASS_INFECT_HUMAN = 4
};


// Daca vrei ca jucatorii sa isi poata schimba clasa pune 1 in loc de 0 !
// Default 0.
new  gUserCanChangeRace  =  0;

// Daca vrei ca jucatorii sa nu mai fie informati cu diferite mesaje cand isi aleg clasa pune pune 0 in loc de 1 !
// Default 1.
new  gEnableMessages  =  1;

// Aici e salvata rasa jucatorului ca in caz ca e Clasic Human si da /race si alege tot Clasic Human.. sa nu mearga.
new  gUserRace[  33  ];

// Numele meniului
new  const  MenuName[    ]  =  "\r      Alege o rasa^n";

// Site-ul ce apare sub cele 4 clase ( este in loc de tasta 0  );
new  const  NumeSite[    ]  =  "\ywww.numesite.ro";

// Tagul mesajelor din chat.
new  const  BBTag[    ]  =  "[BB Races]";


/*================================================================================================*/
/*======================================= - ¦ Askhanar ¦ - =======================================*/

public plugin_init(    ) 
{
	
	register_plugin(  PLUGIN,  VERSION, "Askhanar"  );
	register_clcmd(  "say /race",  "sayRace"  );
	
	RegisterHam(  Ham_Spawn,  "player",  "Ham_PlayerSpawnPost",  true  );
	
	
}

/*======================================= - ¦ Askhanar ¦ - =======================================*/

public client_putinserver(  id  )
{
	
	if(  is_user_bot(  id  )  ||  is_user_hltv(  id  )  )  return 1;
	
	gUserRace[  id  ]  =  CLASS_NONE;
	
	return 0;
}

/*======================================= - ¦ Askhanar ¦ - =======================================*/

public client_disconnect(  id  )
{
	
	if(  is_user_bot(  id  )  ||  is_user_hltv(  id  )  )  return 1;
	
	gUserRace[  id  ]  =  CLASS_NONE;
	
	return 0;
}

/*======================================= - ¦ Askhanar ¦ - =======================================*/

public sayRace(  id  )
{
	if( gUserCanChangeRace  >  0  )
	{
		
		if(  cs_get_user_team(  id  )  ==  CS_TEAM_CT )
		{
			MainMenu(  id  );
			return 1;
		}
	}
	else
	{
		if(  gEnableMessages  >  0  )
		{
			ColorChat(  id,  RED,  "^x04%s^x01 Comanda dezactivata de catre server !",  BBTag  );
		}
		return 1;
	}
	
	return 0;
}

/*======================================= - ¦ Askhanar ¦ - =======================================*/

public Ham_PlayerSpawnPost(  id  ) 
{
	
	if(  !is_user_alive(  id  )  ||  is_user_bot(  id  )  ||  is_user_hltv(  id  )  )  return HAM_IGNORED;
	
	if(  cs_get_user_team(  id  )  ==  CS_TEAM_CT  )   MainMenu(  id  );
	
	return HAM_IGNORED;
}

/*======================================= - ¦ Askhanar ¦ - =======================================*/

public MainMenu(  id  )
{
	new  menu  =  menu_create(  MenuName,  "MainMenuHandler"  );	
	
	menu_additem(  menu,  "Clasic Human     \r[\y Balanced\r ]",  "1",  0  );
	menu_additem(  menu,  "Big Human         \r[\y Hp++\r ]",  "2",  0  );
	menu_additem(  menu,  "Jumper Human    \r[\y Jump++\r ]",  "3",  0  );
	menu_additem(  menu,  "Infect Human     \r[\y Armour++\r ]^n",  "4",  0  );
	
	menu_setprop(  menu,  MPROP_EXITNAME,  NumeSite  );
	
	menu_display(  id,  menu,  0  );

}

/*======================================= - ¦ Askhanar ¦ - =======================================*/

public MainMenuHandler(  id,  menu,  item  )
{
	if(  item  ==  MENU_EXIT  )
	{
		set_task(  0.1,  "MainMenu",  id  );
		return 1;
	}
	
	if(  cs_get_user_team(  id  )  !=  CS_TEAM_CT  ) return 1;
	
	new  data[  6  ],  iName[  64  ];
	new  iaccess,  callback;
	
	menu_item_getinfo(  menu,  item,  iaccess,  data,  5,  iName,  sizeof  (  iName  )  -1,  callback  );
	
	new  key  =  str_to_num(  data  );
	
	switch(  key  )
	{
		case CLASS_CLASIC_HUMAN:
		{
			if(  gUserRace[  id  ]  ==  CLASS_CLASIC_HUMAN  )
			{
				if(  gEnableMessages  >  0  )
				{
					ColorChat(  id,  RED,  "^x04%s^x01 Esti deja rasa^x03 Clasic Human^x01 !",  BBTag  );
				}
				MainMenu(  id  );
				return 1;
			}
			
			ResetUserSettings(  id  );
			
			set_user_health(  id,  CLASIC_HUMAN_HP  );
			set_user_gravity(  id,  CLASIC_HUMAN_GRAVITY  );
			set_user_armor(  id,  CLASIC_HUMAN_ARMOUR  );
			
			gUserRace[  id  ]  =  CLASS_CLASIC_HUMAN;
			
			if(  gEnableMessages  >  0  )
			{
				ColorChat(  id,  RED,  "^x04%s^x01 Ai ales rasa^x03 Clasic Human^x01 !",  BBTag  );
				ColorChat(  id,  RED,  "^x04%s^x01 Aceasta rasa este echilibrata !",  BBTag  );
			}
			
			return 1;
		}
		case CLASS_BIG_HUMAN:
		{
			
			if(  gUserRace[  id  ]  ==  CLASS_BIG_HUMAN  )
			{
				if(  gEnableMessages  >  0  )
				{
					ColorChat(  id,  RED,  "^x04%s^x01 Esti deja rasa^x03 BIG Human^x01 !",  BBTag  );
				}
				MainMenu(  id  );
				return 1;
			}
			
			ResetUserSettings(  id  );
			set_user_health(  id,  BIG_HUMAN_HP  );
			
			gUserRace[  id  ]  =  CLASS_BIG_HUMAN;
			
			if(  gEnableMessages  >  0  )
			{
				ColorChat(  id,  RED,  "^x04%s^x01 Ai ales rasa^x03 Big Human^x01 !",  BBTag  );
				ColorChat(  id,  RED,  "^x04%s^x01 Aceasta rasa are mult hp !",  BBTag  );
			}
			
			return 1;
		}
		case CLASS_JUMPER_HUMAN:
		{
			
			if(  gUserRace[  id  ]  ==  CLASS_JUMPER_HUMAN  )
			{
				if(  gEnableMessages  >  0  )
				{
					ColorChat(  id,  RED,  "^x04%s^x01 Esti deja rasa^x03 Jumper Human^x01 !",  BBTag  );
				}
				MainMenu(  id  );
				return 1;
			}
			
			ResetUserSettings(  id  );
			set_user_gravity(  id,  JUMPER_HUMAN_GRAVITY  );
			
			gUserRace[  id  ]  =  CLASS_JUMPER_HUMAN;
			
			
			if(  gEnableMessages  >  0  )
			{
				ColorChat(  id,  RED,  "^x04%s^x01 Ai ales rasa^x03 Jumper Human^x01 !",  BBTag  );
				ColorChat(  id,  RED,  "^x04%s^x01 Aceasta rasa sare mult !",  BBTag  );
			}
			return 1;
		}
		case CLASS_INFECT_HUMAN:
		{
			
			if(  gUserRace[  id  ]  ==  CLASS_INFECT_HUMAN  )
			{
				if(  gEnableMessages  >  0  )
				{
					ColorChat(  id,  RED,  "^x04%s^x01 Esti deja rasa^x03 Infect Human^x01 !",  BBTag  );
				}
				MainMenu(  id  );
				return 1;
			}
			
			
			ResetUserSettings(  id  );
			set_user_armor(  id,  INFECT_HUMAN_ARMOUR  );
			
			gUserRace[  id  ]  =  CLASS_INFECT_HUMAN;
			
			
			if(  gEnableMessages  >  0  )
			{
				ColorChat(  id,  RED,  "^x04%s^x01 Ai ales rasa^x03 Infect Human^x01 !",  BBTag  );
				ColorChat(  id,  RED,  "^x04%s^x01 Aceasta rasa are multa armura !",  BBTag  );
			}
			return 1;
		}
	}
	
	return 0;
}

/*======================================= - ¦ Askhanar ¦ - =======================================*/

public ResetUserSettings(  id  )
{
	set_user_health(  id,  DEFAULT_HP  );
	set_user_gravity(  id,  1.0  );
	set_user_armor(  id,  DEFAULT_ARMOUR  );
	
}

/*======================================= - ¦ Askhanar ¦ - =======================================*/
/*================================================================================================*/

succes cu serverul.. acum ma pun sa il testez.

LE: Screen !