Cerere modificare plugin

FaTzZu · 03 Feb 2013, 14:31

Bun as vrea la acest plugin

#include <amxmodx> 
#include <cstrike> 
#include <fun> 
#include <amxmisc>  
#include <hamsandwich> 


#define PLUGIN    "Arme"  
#define AUTHOR    "Andu. <3"  
#define VERSION    "1.0" 


public plugin_init() 
{ 
    register_plugin("Furiens Weapons", "1.0", "Andu. <3") 
    
    //Hamsandwich 
    RegisterHam(Ham_Spawn, "player", "Player_Spawn", 1) 
} 

public Player_Spawn(id) 
{ 
    if(is_user_alive(id)) 
    { 
        new CsTeams:team = cs_get_user_team(id) 
        switch(team) 
        { 
            case CS_TEAM_T: 
            { 
                strip_user_weapons(id) 
                give_item(id, "weapon_knife") 
                give_item(id, "weapon_hegrenade")
                give_item(id, "weapon_smokegrenade")
                give_item(id, "weapon_flashbang")
                
            } 
            case CS_TEAM_CT: 
            { 
                strip_user_weapons(id) 
                give_item(id, "weapon_hegrenade")
                give_item(id, "weapon_deagle")
                give_item(id, "weapon_smokegrenade")
                give_item(id, "weapon_flashbang")
                give_item(id, "weapon_knife")
                cs_set_user_bpammo( id, CSW_DEAGLE, 70 )
                new menu = menu_create("Alegeti o arma :", "menu_handler");  
                
                menu_additem(menu, "Carabina", "1", 0);  
                menu_additem(menu, "KalashNikov", "2", 0);  
                menu_additem(menu, "Aspirina", "3", 0);  
                menu_additem(menu, "Automatu'", "4", 0);   
                menu_additem(menu, "Ultimate", "5", 0);
                
                
                menu_setprop(menu, MPROP_EXIT, MEXIT_ALL);  
                
                menu_display(id, menu, 0);  
                
            }
        }
    }  
}
public menu_handler(id, menu, item)  
{  
    if( item == MENU_EXIT )  
    {  
        menu_destroy(menu);  
        return PLUGIN_HANDLED;  
    }  
    new data[6], iName[64];  
    new access, callback;  
    menu_item_getinfo(menu, item, access, data,5, iName, 63, callback);  
    new key = str_to_num(data);  
    
    switch(key)  
    {  
        case 1:  
        {  
            give_item(id, "weapon_m4a1")  
            
            cs_set_user_bpammo(id,CSW_M4A1,250)    
            
        }  
        case 2:  
        {  
            give_item(id, "weapon_ak47")  
            
            cs_set_user_bpammo(id,CSW_AK47,250)    
            
        }  
        case 3:   
        {  
            give_item(id, "weapon_mp5navy")  
            
            cs_set_user_bpammo(id,CSW_MP5NAVY,250)    
            
        }  
        case 4:   
        {  
            give_item(id, "weapon_xm1014")  
            
            cs_set_user_bpammo(id,CSW_XM1014,250)    
            
        }  
          
          
		case 5:
		{
		
			new menu = menu_create("Alegeti o arma VIP :", "menu_handler2");
			menu_additem(menu, "Arma cu apa", "1", 0);
			
			menu_setprop(menu, MPROP_EXIT, MEXIT_ALL);  
                
            menu_display(id, menu, 0);
		}
    }
	
	menu_destroy(menu);  
    return PLUGIN_HANDLED; 
}


public menu_handler2(id, menu, item) 	
{  
    if( item == MENU_EXIT )  
    {  
        menu_destroy(menu);  
        return PLUGIN_HANDLED;  
    }  
    new data[6], iName[64];  
    new access, callback;  
    menu_item_getinfo(menu, item, access, data,5, iName, 63, callback);  
    new key = str_to_num(data);  
    
    switch(key)  
    {
		case 1:
		{
			give_item(id, "weapon_m4a1")
			
			cs_set_user_bpammo(id,CSW_M4A1,300) 
		}	
			
    
    }
   menu_destroy(menu);  
   return PLUGIN_HANDLED; 
   
}


/* AMXX-Studio Notes - DO NOT MODIFY BELOW HERE
*{ rtf1 ansi deff0{ fonttbl{ f0 fnil Tahoma;}}n viewkind4 uc1 pard lang2070 f0 fs16 n par }
*/

Atunci cand apas 5 apare acel meniu eh bun in acel meniu sa fie o arma noua

https://forums.alliedmods.net/showthread.php?t=175698 Dar numai daca persoana respectiva are un anumit flag

Multumesc anticipat

eNd. · 03 Feb 2013, 15:28

Poftim:

| Afiseaza codul

#include <amxmodx>
#include <cstrike>
#include <fun>
#include <amxmisc> 
#include <hamsandwich>
#include <fakemeta>

#define PLUGIN    "Arme" 
#define AUTHOR    "Andu. <3" 
#define VERSION    "1.0"
#define is_valid_player(%1) (1 <= %1 <= 32)
#define ACCESS ADMIN_KICK
new HW_V_MODEL[64] = "models/zombie_plague/v_holywater.mdl"
new HW_P_MODEL[64] = "models/zombie_plague/p_holywater.mdl"

/* Pcvars */
new cvar_dmgmultiplier, cvar_bluebullets,  cvar_custommodel, cvar_uclip

new bool:g_HasHw[33]

new bullets[ 33 ]

// Sprite
new m_spriteTexture

const Wep_FAMAS = ((1<<CSW_FAMAS))

public plugin_init()
{
	register_plugin("Furiens Weapons", "1.0", "Andu. <3")
	cvar_dmgmultiplier = register_cvar("holywater_dmg_multiplier", "4")
	cvar_custommodel = register_cvar("holywater_custom_model", "1")
	cvar_bluebullets = register_cvar("holywater_blue_bullets", "1")
	cvar_uclip = register_cvar("holywater_unlimited_clip", "1")
	// Death Msg
	register_event("DeathMsg", "Death", "a")
	// Weapon Pick Up
	register_event("WeapPickup","checkModel","b","1=19")
	// Current Weapon Event
	register_event("CurWeapon","checkWeapon","be","1=1")
	register_event("CurWeapon", "make_tracer", "be", "1=1", "3>0")
	// Ham TakeDamage	
	register_forward( FM_CmdStart, "fw_CmdStart" )
	RegisterHam(Ham_TakeDamage, "player", "fw_TakeDamage")
	RegisterHam(Ham_Spawn, "player", "Player_Spawn", 1)
}

public plugin_precache()
{
	precache_model(HW_V_MODEL)
	precache_model(HW_P_MODEL)
	m_spriteTexture = precache_model("sprites/dot.spr")
	
}

public client_connect(id)
{
	g_HasHw[id] = false
}

public client_disconnect(id)
{
	g_HasHw[id] = false
}

public Death()
{
	g_HasHw[read_data(2)] = false
}

public checkModel(id)
{
	if (cs_get_user_team(id) == CS_TEAM_T)
		return PLUGIN_HANDLED
	
	new szWeapID = read_data(2)
	
	if ( szWeapID == CSW_FAMAS && g_HasHw[id] == true && get_pcvar_num(cvar_custommodel) )
	{
		set_pev(id, pev_viewmodel2, HW_V_MODEL)
		set_pev(id, pev_weaponmodel2, HW_P_MODEL)
	}
	return PLUGIN_HANDLED
}

public checkWeapon(id)
{
	new plrClip, plrAmmo, plrWeap[32]
	new plrWeapId
	
	plrWeapId = get_user_weapon(id, plrClip , plrAmmo)
	
	if (plrWeapId == CSW_FAMAS && g_HasHw[id])
	{
		checkModel(id)
	}
	else 
	{
		return PLUGIN_CONTINUE
	}
	
	if (plrClip == 0 && get_pcvar_num(cvar_uclip))
	{
		// If the user is out of ammo..
		get_weaponname(plrWeapId, plrWeap, 31)
		// Get the name of their weapon
		give_item(id, plrWeap)
		engclient_cmd(id, plrWeap) 
		engclient_cmd(id, plrWeap)
		engclient_cmd(id, plrWeap)
	}
	return PLUGIN_HANDLED
}

public fw_TakeDamage(victim, inflictor, attacker, Float:damage)
{
	if ( is_valid_player( attacker ) && get_user_weapon(attacker) == CSW_FAMAS && g_HasHw[attacker] )
	{
		SetHamParamFloat(4, damage * get_pcvar_float( cvar_dmgmultiplier ) )
	}
}

public Player_Spawn(id)
{
	if(is_user_alive(id))
	{
		new CsTeams:team = cs_get_user_team(id)
		switch(team)
		{
			case CS_TEAM_T:
			{
				g_HasHw[id] = false
				strip_user_weapons(id)
				give_item(id, "weapon_knife")
				give_item(id, "weapon_hegrenade")
				give_item(id, "weapon_smokegrenade")
				give_item(id, "weapon_flashbang")
				
			}
			case CS_TEAM_CT:
			{
				g_HasHw[id] = false
				strip_user_weapons(id)
				give_item(id, "weapon_hegrenade")
				give_item(id, "weapon_deagle")
				give_item(id, "weapon_smokegrenade")
				give_item(id, "weapon_flashbang")
				give_item(id, "weapon_knife")
				cs_set_user_bpammo( id, CSW_DEAGLE, 70 )
				new menu = menu_create("Alegeti o arma :", "menu_handler"); 
				
				menu_additem(menu, "Carabina", "1", 0); 
				menu_additem(menu, "KalashNikov", "2", 0); 
				menu_additem(menu, "Aspirina", "3", 0); 
				menu_additem(menu, "Automatu'", "4", 0);   
				menu_additem(menu, "Ultimate", "5", 0);
				
				menu_setprop(menu, MPROP_EXIT, MEXIT_ALL); 
				
				menu_display(id, menu, 0); 
				
			}
		}
	} 
}
public menu_handler(id, menu, item) 
{ 
	if( item == MENU_EXIT ) 
	{ 
		menu_destroy(menu); 
		return PLUGIN_HANDLED; 
	} 
	new data[6], iName[64]; 
	new access, callback; 
	menu_item_getinfo(menu, item, access, data,5, iName, 63, callback); 
	new key = str_to_num(data); 
	
	switch(key) 
	{ 
		case 1: 
		{ 
			give_item(id, "weapon_m4a1") 
			
			cs_set_user_bpammo(id,CSW_M4A1,250)   
			
		} 
		case 2: 
		{ 
			give_item(id, "weapon_ak47") 
			
			cs_set_user_bpammo(id,CSW_AK47,250)   
			
		} 
		case 3:   
		{ 
			give_item(id, "weapon_mp5navy") 
			
			cs_set_user_bpammo(id,CSW_MP5NAVY,250)   
			
		} 
		case 4:   
		{ 
			give_item(id, "weapon_xm1014") 
			
			cs_set_user_bpammo(id,CSW_XM1014,250)   
			
		} 
		
		
		case 5:
		{
			
			if(get_user_flags(id) & ACCESS)
			{
				new menu = menu_create("Alegeti o arma VIP :", "menu_handler2");
				menu_additem(menu, "Arma cu apa", "1", 0);
				
				menu_setprop(menu, MPROP_EXIT, MEXIT_ALL); 
				
				menu_display(id, menu, 0);
			}
			else return PLUGIN_HANDLED
		}
	}
	menu_destroy(menu); 
	return PLUGIN_HANDLED;
}


public menu_handler2(id, menu, item)    
{ 
	if( item == MENU_EXIT ) 
	{ 
		menu_destroy(menu); 
		return PLUGIN_HANDLED; 
	} 
	new data[6], iName[64]; 
	new access, callback; 
	menu_item_getinfo(menu, item, access, data,5, iName, 63, callback); 
	new key = str_to_num(data); 
	
	switch(key) 
	{
		case 1:
		{
			if ( user_has_weapon(id, CSW_FAMAS) )
			{
				drop_prim(id)
			}
			
			give_item(id, "weapon_famas")
			client_print(id, print_chat, "Ai primit pistol cu apa!")
			g_HasHw[id] = true;
		}   
		
		
	}
	menu_destroy(menu); 
	return PLUGIN_HANDLED;
	
}

public make_tracer(id)
{
	if (get_pcvar_num(cvar_bluebullets))
	{
		new clip,ammo
		new wpnid = get_user_weapon(id,clip,ammo)
		new pteam[16]
		
		get_user_team(id, pteam, 15)
		
		if ((bullets[id] > clip) && (wpnid == CSW_FAMAS) && g_HasHw[id]) 
		{
			new vec1[3], vec2[3]
			get_user_origin(id, vec1, 1) // origin; your camera point.
			get_user_origin(id, vec2, 4) // termina; where your bullet goes (4 is cs-only)
			
			
			//BEAMENTPOINTS
			message_begin( MSG_BROADCAST,SVC_TEMPENTITY)
			write_byte (0)     //TE_BEAMENTPOINTS 0
			write_coord(vec1[0])
			write_coord(vec1[1])
			write_coord(vec1[2])
			write_coord(vec2[0])
			write_coord(vec2[1])
			write_coord(vec2[2])
			write_short( m_spriteTexture )
			write_byte(1) // framestart
			write_byte(5) // framerate
			write_byte(2) // life
			write_byte(10) // width
			write_byte(0) // noise
			write_byte( 30 )     // r, g, b
			write_byte( 144 )       // r, g, b
			write_byte( 255 )       // r, g, b
			write_byte(200) // brightness
			write_byte(150) // speed
			message_end()
		}
		
		bullets[id] = clip
	}
	
}

stock drop_prim(id) 
{
	new weapons[32], num
	get_user_weapons(id, weapons, num)
	for (new i = 0; i < num; i++) {
		if (Wep_FAMAS & (1<<weapons)) 
		{
			static wname[32]
			get_weaponname(weapons, wname, sizeof wname - 1)
			engclient_cmd(id, "drop", wname)
		}
	}
}

FaTzZu · 04 Feb 2013, 20:18

Wow frate mersi esti cel mai tare :D daca as putea ti-as da 1000+ de Multumesc

Auzi daca se poate sa mai pui sub arma cu apa in meniu alte 2 arme

http://forums.alliedmods.net/showthread.php?t=181375

http://forums.alliedmods.net/showthread.php?t=182405

Cerere modificare plugin

Who is online