Plugin ts_menu

[CsN^ ;x]

Am si eu acest plugin care il veti vedea mai jos si am o problema la el ,cand te baga tero iti da meniu tot frumos dar are niste buguri da meniu cand vrea el .. gen mie pe o mapa nu mi-a dat deloc meniu si la multi alti playerii .Deci el da tot ce zice iti arata meniu dar nu mereu adica nu cand esti tero ,da meniu cand vrea el .

Necazu este aici | Afiseaza codul

#include <amxmodx>
#include <fun>
#include <cstrike>
#include <ColorChat>

new gInvizibil[32];
new gViteza[32];
new gGravitatie[32];
new gJucatori;

public plugin_init()
{
	register_plugin("Ts_menu", "1.0", "Raul");
	register_logevent("Inceput_runda", 2, "1=Round_Start");
	gJucatori = get_maxplayers( ); 
}

public Inceput_runda()
{
	for(new id = 0; id < gJucatori; id++)  
	{ 
		if(gInvizibil[id])
			set_user_rendering(id, kRenderFxNone, 0, 0, 0, kRenderTransAlpha, 255);
		
		if(gViteza[id])
			set_user_maxspeed(id, 250.0 );
		
		if(gGravitatie[id])
			set_user_gravity(id, 800.0);
		
		if ( is_user_alive( id ) &&  cs_get_user_team(id) == CS_TEAM_T)
			set_task(1.0, "Creare_meniu", id);
	}
}
public Creare_meniu(id)
{
	
	new menu = menu_create("Alege o optiune:", "menu_handler");
	menu_additem(menu, "\wInvizibilitate \r(80 %)", "1", 0);
	menu_additem(menu, "\w10 HE-uri \rsi \w7 gloante DEAGLE", "2", 0);
	menu_additem(menu, "\w10 FLAS-uri \rsi \w7 gloante DEAGLE", "3", 0);
	menu_additem(menu, "\wSa moara dusmanii", "4", 0);
	menu_additem(menu, "\w1000 Hp", "5", 0);
	menu_additem(menu, "\rONLY ADMIN", "6", 0);
	
	menu_setprop(menu, MPROP_EXIT, MEXIT_ALL);
	
	menu_display(id, menu, 0);
}

public menu_handler(id, menu, item)
{
	if( item == MENU_EXIT )
	{
		menu_destroy(menu);
		return PLUGIN_HANDLED;
	}
	
	new data[6], szName[64];
	new access, callback;
	menu_item_getinfo(menu, item, access, data,charsmax(data), szName,charsmax(szName), callback);
	
	new key = str_to_num(data);
	
	switch(key)
	{
		case 1:
		{
			
			ColorChat( id, GREEN, "[LCS-MENIU TERO]^x03 Acum esti^x04 80^x01 la suta invizibil");
			gInvizibil[id] = 1;
			set_user_rendering(id, kRenderFxNone, 0, 0, 0, kRenderTransAlpha, 51);
			menu_destroy(menu);
			return PLUGIN_HANDLED;
		}
		case 2:
		{
			ColorChat( id, GREEN, "[LCS-MENIU TERO]^x03 Ai primit^x04 10 HE-uri^x01 si un^x04 deagle^x01 cu 7 gloante !");
			give_item(id,"weapon_hegrenade")
			cs_set_user_bpammo(id, CSW_HEGRENADE, 10)
			cs_set_weapon_ammo ( give_item(id,"weapon_deagle") , 7)
			menu_destroy(menu);
			return PLUGIN_HANDLED;
		}
		case 3:
		{
			ColorChat( id, GREEN, "[LCS-MENIU TERO]^x03 Ai primit^x04 10 FLASH-uri ^x01si un^x04 deagle ^x01cu 7 gloante");
			give_item(id,"weapon_flashbang")
			cs_set_user_bpammo(id, CSW_FLASHBANG, 10)
			cs_set_weapon_ammo ( give_item(id,"weapon_deagle") , 7)
			menu_destroy(menu);
			return PLUGIN_HANDLED;
		}
		case 4:
		{
			ColorChat( id, GREEN, "[LCS-MENIU TERO]^x03 Ai primit un^x04  MP5 ^x01si^x04  1 HE^x01");
			give_item(id, "weapon_hegrenade");
		
			cs_set_weapon_ammo ( give_item(id,"weapon_mp5navy") , 60)
			
			
			menu_destroy(menu);
			return PLUGIN_HANDLED;
		}
		case 5:
		{
			ColorChat( id, GREEN, "[LCS-MENIU TERO]^x03 Ai primit^x04 1000 HP^x01");
			set_user_health(id, 1000);
			menu_destroy(menu);
			return PLUGIN_HANDLED;
		}
		case 6:
		{
			if( get_user_flags(id) & read_flags("bc")) {
			ColorChat( id, GREEN, "[LCS-MENIU TERO]^x03 Ai primit ^x04MP5^x01, ^x04Invizibilitate^x01 +^x04 1 HE ^x01+^x04 1 FLASH^x01 +^x04 500 HP ^x01!");
			give_item(id,"weapon_hegrenade");
			give_item(id,"weapon_flashbang");
			cs_set_weapon_ammo ( give_item(id,"weapon_mp5navy") , 60)
			set_user_health(id, 500);
			set_user_rendering(id, kRenderFxNone, 0, 0, 0, kRenderTransAlpha, floatround( ( 255.0 / 100.0 ) * 40, floatround_floor ) );
			menu_destroy(menu);
			return PLUGIN_HANDLED;
		            }
			    else{
			    client_print(id, print_chat, "[LCS-MENIU TERO]^x03 ^x03Nu esti admin , alege alt numar !");
                            Creare_meniu(id)
			   }
		}
		
	}
	menu_destroy(menu);
	return PLUGIN_HANDLED;
}
/* AMXX-Studio Notes - DO NOT MODIFY BELOW HERE
*{\\ rtf1\\ ansi\\ ansicpg1252\\ deff0\\ deflang1033{\\ fonttbl{\\ f0\\ fnil Tahoma;}}\n\\ viewkind4\\ uc1\\ pard\\ f0\\ fs16 \n\\ par }
*/

[Gabriel963]

Asta iti ziceam si eu ca are bug , tu mi l-ai dat .. mi l-a modificat cyby ca dadea niste erori, il am pe server, merge perfect , iti apare cand se schimba tero cu dr_Fixround.
Schimbi tu reclamele.

Code: Select all

#include <amxmodx>
#include <cstrike>
#include <fun>
#include <hamsandwich>

public plugin_init()
{
	register_plugin("Meniul Teroristului", "1.0", "cyby")
	
	RegisterHam(Ham_Spawn, "player", "player_spawn", 1)
}

public player_spawn(id)
{
	if(is_user_alive(id) && get_user_team(id) == 1)
	{
		set_user_rendering(id)
		show_t_menu(id)
	}
}

public show_t_menu(id)
{
	new menu = menu_create("\r[WATF]Alege o optiune:", "t_handler")
	menu_additem(menu, "\wInvizibilitate\r (80 %)", "1", 0)
	menu_additem(menu, "\w10\r HE\w +\r 7 Gloante Deagle", "2", 0)
	menu_additem(menu, "\w10\r FB\w +\r 7 Gloante Deagle", "3", 0)
	menu_additem(menu, "\wArma \r(Mp5Navy Gun)", "4", 0)
	menu_additem(menu, "\w+1000 HP", "5", 0)
	menu_additem(menu, "\rOnly Admins", "6", 0)
	menu_display(id, menu, 0)
}

public t_handler(id, menu, item)
{
	if(!is_user_alive(id))
	{
		color(id, ".v[WATF].g Esti mort.g.")
		menu_destroy(menu)
		return PLUGIN_HANDLED
	}
	
	if(get_user_team(id) != 1)
	{
		color(id, ".v[WATF].g Acest admin este destinat doar.e teroristilor.g.")
		menu_destroy(menu)
		return PLUGIN_HANDLED
	}

	new nume[32];
	get_user_name(id, nume, 31)
	switch(item)
	{
		case 0:
		{
			set_user_rendering(id, kRenderFxNone, 0, 0, 0, kRenderTransAlpha, 51)
			color(id, ".v[WATF].g Ai ales sa fii invizibil.e 80%.g.")
			color(0, ".v[WATF].g Teroristul.e %s.g ales sa fie invizibil.g 80%.g.", nume)
		}
		case 1:
		{
			give_item(id, "weapon_hegrenade")
			cs_set_user_bpammo(id, CSW_HEGRENADE, 10)
			cs_set_weapon_ammo(give_item(id, "weapon_deagle"), 7)
			color(id, ".v[WATF].g Ai ales sa primesti.e 7 Gloante Deagle + 10 HE.g.")
			color(0, ".v[WATF].g Teroristul.e %s.g ales sa primeasca.g 7 Gloante Deagle + 10 HE.g.", nume)			
		}
		case 2:
		{
			give_item(id, "weapon_flashbang")
			cs_set_user_bpammo(id, CSW_FLASHBANG, 10)
			cs_set_weapon_ammo(give_item(id, "weapon_deagle"), 7)
			color(id, ".v[WATF].g Ai ales sa primesti.e 7 Gloante Deagle + 10 FB.g.")
			color(0, ".v[WATF].g Teroristul.e %s.g ales sa primeasca.g 7 Gloante Deagle + 10 FB.g.", nume)			
		}
		case 3:
		{
			give_item(id, "weapon_hegrenade")
			cs_set_weapon_ammo(give_item(id, "weapon_mp5navy"), 60)
			color(id, ".v[WATF].g Ai ales sa primesti.e MP5 + 1 HE.g.")
			color(0, ".v[WATF].g Teroristul.e %s.g ales sa primeasca.g MP5 + 1 HE.g.", nume)			
		}
		case 4:
		{
			set_user_health(id, 1000)
			color(id, ".v[WATF].g Ai ales sa primesti.e 1000 HP.g.")
			color(0, ".v[WATF].g Teroristul.e %s.g ales sa primeasca.g 1000 HP.g.", nume)			
		}
		case 5:
		{
			if(get_user_flags(id) & ADMIN_RESERVATION)
			{
				give_item(id, "weapon_hegrenade")
				give_item(id, "weapon_flashbang")
				set_user_health(id, 500)
				cs_set_weapon_ammo(give_item(id, "weapon_mp5navy"), 60)
				set_user_rendering(id, kRenderFxNone, 0, 0, 0, kRenderTransAlpha, 70)
				color(id, ".v[WATF].g Ai ales sa primesti.e 500 HP + 1HE + 1FB + MP5.g.")
				color(0, ".v[WATF].g Teroristul.e %s.g ales sa primeasca.g 500 HP + 1HE + 1FB + MP5.g.", nume)
			}
			else
			{
				set_task(0.1, "show_t_menu", id)
				color(id, ".v[WATF].g Aceasta facilitate este doar pentru cei cu.e admin.g.")
			}
		}
	}
	menu_destroy(menu)
	return PLUGIN_HANDLED
}

stock color(const id, const input[], any:...)
{
	new count = 1, players[32]
	static msg[191]
	vformat(msg, 190, input, 3)

	replace_all(msg, 190, ".v", "^4")
	replace_all(msg, 190, ".g", "^1")
	replace_all(msg, 190, ".e", "^3")

	if (id) players[0] = id; else get_players(players, count, "ch")
	{
		for (new i = 0; i < count; i++)
		{
			if (is_user_connected(players[i]))
			{
				message_begin(MSG_ONE_UNRELIABLE, get_user_msgid("SayText"), _, players[i])
				write_byte(players[i]);
				write_string(msg);
				message_end();
			}
		}
	}
}

[CsN^ ;x]

Reclame :-& :)))
Mersi frumos ,mau zapacit astia ca nu le da meniu si na :D
Sper sa mearga dar daca ai zis ca l-ai testat sper si mie sa mearga

[Gabriel963]

Npc , la mine merge uns :), merge chiar daca il muta drfixround + daca ti-a ramas meniul si esti CT nu poti accesa, pe cel vechi accesai si dupa CT:))