Plugin 2 in 1

[Laur3]

Salut am si eu nevoie de un plugin.
Vreau un plugin care atunci cand castiga o echipa sa apare in mijloc in partea de sus a ecranului mesajul hud "Teroristii au castigat" sau "Counter-Teroristii au castigat".
Si vreau inca un plugin care atunci cand incepe runda de ex: Am mp_freezetime 3 la server, cand incepe runda sa apara in hud tot asa in mijloc sus mesajul "Runda incepe in X secunde" iar cand freezetime-ul sa terminat sa apara "Runda a inceput".

Dau 10 multumesc-uri celui care ma rezolva.

[Nubo]

Hmm.... Tot ce ai cerut e default.
Cine castiga scrie, iar timpul la freezetime arata jos la ceas cu rosu.
Ai nevoie numaidecat de mesaje hud?

[Laur3]

ăă... DA. Am nevoie neaparat de hud. :)

[Nubo]

Primul. Netestat.

.SMA | Afiseaza codul

/* Plugin generated by AMXX-Studio */
//Credits: Alternative End Round Sounds by Arkshine

#include <amxmodx>
#include <amxmisc>

#define PLUGIN "Round End HUD"
#define VERSION "1.0"
#define AUTHOR "Nubo"


public plugin_init() {
	register_plugin(PLUGIN, VERSION, AUTHOR)
	register_event( "SendAudio", "eT_win" , "a", "2&%!MRAD_terwin" );
	register_event( "SendAudio", "eCT_win", "a", "2&%!MRAD_ctwin"  );
}

public eT_win(){
	new mess[128];
	format(mess,127,"Teroristii au castigat!")
	set_hudmessage(0, 255, 0, -1.0, -1.0, 0, 6.0, 10.0)
	show_hudmessage(0, mess)
}

public eCT_win(){
	new mess[128];
	format(mess,127,"Counter-Teroristii au castigat!")
	set_hudmessage(0, 255, 0, -1.0, -1.0, 0, 6.0, 10.0)
	show_hudmessage(0, mess)
}

-------
Al doilea. Netestat. Compilat fara erori. Dar nu cred ca e bun. Testeaza-l.
Nu stiu cum sa afli valoarea unui cvar deja existent, de aia trebuie sa introduci manual alt cvar care sa fie egal cu freezetime de pe server.
Cel putin, poate va fi de folos pentru alt cineva, cumva.

.SMA | Afiseaza codul

/* Plugin generated by AMXX-Studio */

#include <amxmodx>
#include <amxmisc>

#define PLUGIN "Freezetime HUD"
#define VERSION "1.0"
#define AUTHOR "Nubo"

new times[33];

public plugin_init() {
	register_plugin(PLUGIN, VERSION, AUTHOR)
	register_event("HLTV", "NewRound", "a", "1=0", "2=0")
	register_cvar("freezetime_hud","3")
}

public NewRound(id){
	times[id] = get_cvar_num("freezetime_hud")
	timer(id)
}

public timer(id){
	if(times[id] > 0){
		new msg[128];
		format(msg,127,"Runda incepe in %d secunde!",times[id])
		set_hudmessage(0, 255, 0, -1.0, -1.0, 0, 6.0, 10.0)
		show_hudmessage(0,msg)
		times[id]--;
		set_task(1.0,"timer",id,_,_,"b")
	}else{
		set_hudmessage(0, 255, 0, -1.0, -1.0, 0, 6.0, 10.0)
		show_hudmessage(0,"Runda a inceput!")
	}
}

[Askwrite]

La cvar faci ceva de genu` :
new freezetimepoint;
freezetimepoint = get_cvar_pointer( "mp_freezetime" );

si in code adaugi :
get_pcvar_float( freezetimepoint )
ceva de genu.

[Nubo]

Si o sa afle valoarea cvarului direct din amxx.cfg sau server.cfg ??
Nu prea cred. Dar nu stiu exact.
Eu stiu ca get_cvar_* se folosesc in interior la plugin.

[Laur3]

Mersi dar din pacate nu merge. Mai astept raspunsuri.

[Askwrite]

Din server.cfg :)

[Gabriel eXtream]

Ar trebui sa nu te ajut , ;) te dadeai autor la Bonus Box

| Afiseaza codul

#include < amxmodx >


#pragma semicolon 1

#define PLUGIN "Furien Invasion "
#define VERSION "1.0"
#define AUTHOR "Askhanar"

new const InvasionSounds[ 6 ][ ] = {
	
	"timestart",
	"timer01",
	"timer02",
	"timer03",
	"timer04",
	"timer05"
};

new SecondsUntillInvasion = 6;
new mp_freezetime;

new SyncHudMessage;

public plugin_init( )
{
	register_plugin( PLUGIN, VERSION, AUTHOR );
	
	register_event( "HLTV", "ev_HookRoundStart", "a", "1=0", "2=0" );
	register_event( "SendAudio","ev_TerroWin","a","2=%!MRAD_terwin");
	register_event( "SendAudio","ev_CounterWin","a","2=%!MRAD_ctwin");
	
	mp_freezetime = get_cvar_pointer( "mp_freezetime" );
	set_pcvar_num( mp_freezetime, 5 );
	SyncHudMessage = CreateHudSyncObj( );
}

public plugin_precache( )
{
	new soundpath[ 64 ];
	for( new i = 0 ; i < 6 ; i++ )
	{
		formatex( soundpath, sizeof ( soundpath ) -1 , "misc/%s.wav", InvasionSounds[ i ] );
		precache_sound( soundpath );
	}
}


public ev_HookRoundStart( )
{
	
	SecondsUntillInvasion = 5;
	set_task( 0.1, "CountDown" );
}
public CountDown( )
{
	if( SecondsUntillInvasion > 0 )
	{
		TerroTeamEffects( );
		CounterTeamEffects( );
		
		set_hudmessage( 0, 255, 0, -1.0, 0.29, 0, 0.0, 1.0, 0.0, 1.0, 4);
		client_cmd(0,"spk misc/%s",InvasionSounds[ SecondsUntillInvasion ] );
		static const Seconds[6][ ] = { "","o","doua","trei","patru","cinci" };
		ShowSyncHudMsg( 0, SyncHudMessage, "Furienii vor invada planeta in %s secund%s !",Seconds[ SecondsUntillInvasion ] , SecondsUntillInvasion  == 1? "a" : "e");

	}
	
	else if( SecondsUntillInvasion <= 0 )
	{
		set_hudmessage( 255, 0, 0, -1.0, 0.29, 0, 0.0, 1.0, 0.0, 1.0, 4);
		ShowSyncHudMsg( 0, SyncHudMessage, "Furienii au invadat planeta !");
		client_cmd(0,"spk misc/%s",InvasionSounds[ SecondsUntillInvasion ] );
		return 1;
	}
	
	SecondsUntillInvasion -= 1;
	set_task( 1.0, "CountDown");
	
	return 0;
}
public ev_TerroWin( )
{
	set_hudmessage( 255, 255, 255, -1.0, 0.45, 0, 0.0, 2.0, 0.0, 5.0, 4);
	ShowSyncHudMsg( 0, SyncHudMessage, "Furienii au castigat !^nPlaneta a fost cucerita!" );

	new iPlayers[ 32 ];
	new iPlayersNum;

	get_players( iPlayers, iPlayersNum, "c" );		
	for( new i = 0 ; i < iPlayersNum ; i++ )
	{
		if( is_user_connected( iPlayers[ i ] ) )
		{
			ShakeScreen( iPlayers[ i ], 3.0 );
			FadeScreen( iPlayers[ i ] , 3.0, 230, 0, 0, 160 );
		}
	}
}
public ev_CounterWin( )
{
	set_hudmessage( 255, 255, 25, -1.0, 0.45, 0, 0.0, 2.0, 0.0, 5.0, 4);
	ShowSyncHudMsg( 0, SyncHudMessage, "AntiFurienii au castigat !^nPlaneta a fost salvata !" );

	new iPlayers[ 32 ];
	new iPlayersNum;

	get_players( iPlayers, iPlayersNum, "c" );		
	for( new i = 0 ; i < iPlayersNum ; i++ )
	{
		if( is_user_connected( iPlayers[ i ] ) )
		{
			
			ShakeScreen( iPlayers[ i ], 3.0 );
			FadeScreen( iPlayers[ i ] , 3.0, 0, 0, 230, 160 );

		}
	}
}

public TerroTeamEffects( )
{
	new iPlayers[ 32 ];
	new iPlayersNum;
	
	get_players(iPlayers, iPlayersNum, "ae", "TERRORIST");
	
	for( new i = 0 ; i < iPlayersNum ; i++ )
	{
		if( is_user_connected( iPlayers[ i ] ) )
		{	
			ShakeScreen( iPlayers[ i ], 0.7 );
			FadeScreen( iPlayers[ i ] , 0.5, 230, 0, 0, 160 );
		}
	}
}
public CounterTeamEffects( )
{
	new iPlayers[ 32 ];
	new iPlayersNum;
	
	get_players( iPlayers, iPlayersNum, "ae", "CT" );
	
	for( new i = 0 ; i < iPlayersNum ; i++ )
	{
		if( is_user_connected( iPlayers[ i ] ) )
		{	
			ShakeScreen( iPlayers[ i ], 0.7 );
			FadeScreen( iPlayers[ i ] , 0.5, 0, 0, 230, 160 );
		}
	}
}

public ShakeScreen( id, const Float:seconds )
{
	message_begin( MSG_ONE, get_user_msgid( "ScreenShake" ), { 0, 0, 0 }, id );
	write_short( floatround( 4096.0 * seconds, floatround_round ) );
	write_short( floatround( 4096.0 * seconds, floatround_round ) );
	write_short( 1<<13 );
	message_end( );
	
}

public FadeScreen( id, const Float:seconds, const red, const green, const blue, const alpha )
{      
	message_begin( MSG_ONE, get_user_msgid( "ScreenFade" ), _, id );
	write_short( floatround( 4096.0 * seconds, floatround_round ) );
	write_short( floatround( 4096.0 * seconds, floatround_round ) );
	write_short( 0x0000 );
	write_byte( red );
	write_byte( green );
	write_byte( blue );
	write_byte( alpha );
	message_end( );

}

[Laur3]

Mersi mult man, si la faza cu Bonus-Box-ul eu l-am facut public prima oara. Si in acest mesaj imi cer scuze fata de Aragon ca m-am dat drept autor.