tero menu (deathrun)

[Nubo]

Vezi asa:

| Afiseaza codul

/*
Nume: DeathRun Terro Menu
Autor: dracu stie am scris vreo 2 - 3 linii ( nu ma mai trec autor la nimic din ce pun/ voi pune)
Versiune: 1.0

credite:

!Sk|t!  --------- am luat cate ceva din pluginul creat de el in alt topic.

plugin cerut aici: cereri-cs/tero-menu-deathrun-t151534.html

			(c) http://www.extreamcs.com 2012
*/

#include <amxmodx>
#include <cstrike>
#include <fun>
#include <hamsandwich>

#pragma semicolon 1

#define RED  0
#define GREEN  255
#define BLUE  255

#define KEYS    ((1<<0)|(1<<1)|(1<<2)|(1<<9))

#define PLUGIN "DeathRun Terro Menu"
#define VERSION "1.0"
#define AUTHOR "Askhanar"

new const MenuName[] = "\rGeForces TeRRoRisT MeNu^n^n";
new const NumeSite[] = "\yWwW.GeForces.Ro";

new MENU;
new UseMenu[33];

public plugin_init() 
{
	register_plugin(PLUGIN, VERSION, AUTHOR);
	
	MENU = register_menuid("MENU");
	register_menucmd( MENU, KEYS, "MenuHandler");
	register_clcmd( "say /menu", "showMenu");
	
	RegisterHam(Ham_Spawn, "player", "fw_PlayerSpawn", 1);
	register_event("HLTV", "NewRound", "a", "1=0", "2=0");
}

public NewRound(){
	arrayset(UseMenu,0,33);
}

public fw_PlayerSpawn(id) 
{
	if( is_user_ok(id)) 
	{
		set_task( 3.0, "MakeUserSeeMenu", id + 112233 );
	}
	
	return HAM_IGNORED;
}	

public MakeUserSeeMenu( id )
{
	id -= 112233;
	if( !is_user_connected( id ) || !is_user_alive( id ) ) return 1;
	
	showMenu(id);
	
	return 0;
}

public showMenu(id) 
{
	if( !is_user_ok( id ) ) return 1;
	
	if(UseMenu[id] == 1){
		client_print(id,print_chat,"Ai folosit deja meniul, incearca tura urmatoare cand vei fi Terrorist.");
		return 1;
	}
	
	new szMenu[1024], n;

	n = formatex(szMenu, 1023, "%s",MenuName);

	n += formatex(szMenu[n], 1023-n, "\r1.\w Hp Full^n");
	n += formatex(szMenu[n], 1023-n, "\r2.\w Deagle^n");
	n += formatex(szMenu[n], 1023-n, "\r3.\w Shield^n^n\r0.\w Iesire^n^n%s",NumeSite);

	show_menu(id, KEYS, szMenu, -1, "MENU");
	
	return 0;
}
public MenuHandler(id, key)
{
	
	if(!is_user_ok(id)) return 1;
	
	switch(key)
	{
		case 0:
		{
			UseMenu[id] = 1;
			FullHp(id);
			return 1;
		}
		case 1:
		{
			UseMenu[id] = 1;
			Deagle(id);
			return 1;
		}
		case 2:
		{
			UseMenu[id] = 1;
			Shield(id);
			return 1;
		}
		case 9:
		{
			showMenu(id);
			return 1;
		}
	}
	return 0;
}
public FullHp(id) 
{
	new name[32];
	get_user_name(id,name,31);
	
	set_hudmessage(RED, GREEN, BLUE, 0.02, 0.20, 0, 6.0, 3.0);
	show_hudmessage(id, "%s has now 255 HP !",name);
	
	client_print(id,print_chat,"You have now 255 HP !");
	set_user_health( id, 255 );
}

public Deagle(id) 
{
	new name[32];
	get_user_name(id,name,31);
	
	set_hudmessage(RED, GREEN, BLUE, 0.02, 0.20, 0, 6.0, 3.0);
	show_hudmessage(id, "%s recived a Deagle !",name);
	
	client_print(id,print_chat,"You recived a Deagle !");
	give_item(id, "weapon_deagle");
	cs_set_user_bpammo(id,CSW_DEAGLE, 33 );
}

public Shield(id) 
{
	new name[32];
	get_user_name(id,name,31);
	
	set_hudmessage(RED, GREEN, BLUE, 0.02, 0.20, 0, 6.0, 3.0);
	show_hudmessage(id, "%s recived a Shield + Glock !",name);
	
	client_print(id,print_chat,"You recived a Shield + Glock !");
	give_item(id,"weapon_shield");
	give_item(id, "weapon_glock18");
	cs_set_user_bpammo(id,CSW_GLOCK18, 120 );
}
stock is_user_ok(id)
{
	if(is_user_alive(id) && is_user_connected(id) && cs_get_user_team(id) == CS_TEAM_T)
		return 1;
		
	return 0;
}

[Neb1]

extraordinar !!! ms mult nubo !!!!!!!! ai un multumesc d la mine :D

te mai rog ceva, daca poti sa faci un plugin ca asta

http://www.extreamcs.com/forum/cereri-c ... 97474.html

numa sa te deie in 2 secunde nu 3 (sa te reinvie) astept aici sa-mi zici daca-l poti face tot azi, ms mult inca odata !!!!

[Nubo]

Vezi asa, si imi spui daca mai trebuie ceva.
Necesita <hamsandwich>.
Timpul se seteaza cu cvar: respawn_secunde 2

| Afiseaza codul

/* Plugin generated by AMXX-Studio */

#include <amxmodx>
#include <hamsandwich>

#define PLUGIN "Simple Respawn"
#define VERSION "1.0"
#define AUTHOR "cyby"
#define Edit_by "Nubo"

new countdown[33];

public plugin_init() {
	register_plugin(PLUGIN, VERSION, AUTHOR)
	RegisterHam(Ham_Killed, "player", "player_killed")
	register_cvar("respawn_secunde","2")
}

public player_killed(victima, atacator, shouldgib)
{
	countdown[victima] = get_cvar_num("respawn_secunde")
	revive_player(victima)
}

public revive_player(victima)
{
	if(is_user_connected(victima) && !is_user_alive(victima))
	{
		set_hudmessage(127, 255, 255, 0.28, -1.0, 0, 6.0, 1.0)
		if(countdown[victima] > 1)
		{
			countdown[victima]--
			show_hudmessage(victima, "Vei fi respawnat in %d secunde.", countdown[victima])
			set_task(1.0, "revive_player", victima)
		}
		else if(countdown[victima] == 1)
		{
			countdown[victima]--
			show_hudmessage(victima, "Vei fi respawnat ACUM.")
			set_task(1.0, "revive_player", victima)
		}
		else if(countdown[victima] < 1)
		{
			respawn(victima)
		}
	}
}

public respawn(id)
{
	if(is_user_connected(id) && !is_user_alive(id))
	{
		ExecuteHamB(Ham_CS_RoundRespawn, id)
	}
}

[Neb1]

merge, numai ca zice tot Vei fi respawnat in 1 secunda. si Vei fi respawnat acum.

nu zice Vei fi respawnat in 3 secunde
Vei fi respawnat in 2 secunde
Vei fi respawn in 1 secunda..nu poti face sa fie dupa cvaru la csdm ? spawn_wait_time = 2.00

p.S @ acum mi-am dat seama, tu mi-ai dat respawn + timeleft, eu vreau doar timeleft ca am csdm 2.1.2 instalat, vreau doar sa aparaa timpu, att

[Neb1]

up up up

[Nubo]

Vezi asa:

| Afiseaza codul

/* Plugin generated by AMXX-Studio */

#include <amxmodx>
#include <hamsandwich>

#define PLUGIN "Simple Respawn"
#define VERSION "1.0"
#define AUTHOR "cyby"
#define Edit_by "Nubo"

new countdown[33];

public plugin_init() {
	register_plugin(PLUGIN, VERSION, AUTHOR)
	RegisterHam(Ham_Killed, "player", "player_killed")
	register_cvar("respawn_secunde","2")
}

public player_killed(victima, atacator, shouldgib)
{
	countdown[victima] = get_cvar_num("respawn_secunde")
	revive_player(victima)
}

public revive_player(victima)
{
	if(is_user_connected(victima) && !is_user_alive(victima))
	{
		set_hudmessage(127, 255, 255, 0.28, -1.0, 0, 6.0, 1.0)
		if(countdown[victima] > 1)
		{
			show_hudmessage(victima, "Vei fi respawnat in %d secunde.", countdown[victima])
                        countdown[victima]--
			set_task(1.0, "revive_player", victima)
		}
		else if(countdown[victima] == 1)
		{
			show_hudmessage(victima, "Vei fi respawnat ACUM.")
                        countdown[victima]--
			set_task(1.0, "revive_player", victima)
		}
		else if(countdown[victima] < 1)
		{
			show_hudmessage(victima, "Respawn!")
		}
	}
}

Setezi cvarul "respawn_secunde" egal cu acel de la CSDM.

[Neb1]

tot asa... apare acuma In 2 secunde.

Respawn !

oare pentru ca mai am un plugin hud mai jos ca ala ? care sta static

[cyby]

| Afiseaza codul

#include <amxmodx>
#include <hamsandwich>

#define PLUGIN "Simple Respawn"
#define VERSION "1.0"
#define AUTHOR "cyby"

new countdown, timp[33];

public plugin_init() 
{
	register_plugin(PLUGIN, VERSION, AUTHOR)
	RegisterHam(Ham_Killed, "player", "player_killed")
	countdown = register_cvar("rr_timp", "3")
}

public client_disconnect(id)
{
	if(task_exists(id))
	{
		remove_task(id)
	}
	timp[id] = 0
}

public player_killed(victima)
{
	timp[victima] = get_pcvar_num(countdown)
	revive_player(victima)
}

public revive_player(victima)
{
	if(is_user_connected(victima) && !is_user_alive(victima))
	{
		set_hudmessage(127, 255, 255, 0.28, -1.0, 0, 6.0, 1.1)
		if(timp[victima] > 1)
		{
			show_hudmessage(victima, "Vei fi respawnat in %d secunde.", timp[victima])
			timp[victima]--
			set_task(1.0, "revive_player", victima)
		}
		else if(timp[victima] == 1)
		{
			show_hudmessage(victima, "Vei fi respawnat ACUM.")
			timp[victima]--
			set_task(1.0, "revive_player", victima)
		}
		else if(timp[victima] < 1)
		{
			show_hudmessage(victima, "Respawn!")
		}
	}
}