cerere C4 plant

[cyby]

Da, scoate-l sau foloseste asta:

| Afiseaza codul

#include <amxmodx>
#include <csx>

#pragma semicolon 1


#define PLUGIN "FMU Bomb Events"
#define VERSION "1.0"

#define C4_TASK		112233

new const g_iRed[ ] =
{
	0,
	125,
	255
};

new const g_iGreen[ ] =
{
	255,
	125,
	10
};

new const g_iBlue[ ] =
{
	255,
	0,
	0
};

new gCvarOn;
new gCvarDropped;
new gCvarPicked;

new g_C4Timer, g_iColor = 0;
new g_pMpC4Timer;
new g_TextMsg;

new gSyncHudMessage;

public plugin_init( )
{
	register_plugin( PLUGIN, VERSION, "Askhanar" );
	
	gCvarOn = register_cvar( "fmu_be_on", "1" );
	gCvarDropped = register_cvar( "fmu_be_dropped", "1" );
	gCvarPicked = register_cvar( "fmu_be_picked", "1" );
	
	
	register_event( "ResetHUD", "ev_ResetHUD", "be" );
	register_event( "SendAudio", "TeamWonOrRoundDraw", "a", "2&%!MRAD_terwin", "2&%!MRAD_ctwin", "2&%!MRAD_rounddraw" );
	
	register_logevent( "le_RoundStart", 2, "1=Round_Start");
	register_logevent( "le_RoundEnd", 2, "1=Round_End");
	register_logevent( "le_RoundEnd", 2, "1&Restart_Round_");
	
	
	g_pMpC4Timer = get_cvar_pointer( "mp_c4timer" );
	
	g_TextMsg = get_user_msgid( "TextMsg" );
	register_message( g_TextMsg, "Hook_TextMessages" );

	gSyncHudMessage = CreateHudSyncObj(  );
}

public bomb_planted( ) 
{
	if( get_pcvar_num( gCvarOn ) == 0 )
		return;
	
	g_C4Timer = get_pcvar_num( g_pMpC4Timer ) - 1;
	
	set_task(1.0, "ShowTimeUntilExplosion", C4_TASK, "", 0, "b" );
}

public ShowTimeUntilExplosion(  )
{
	if( g_C4Timer > 0 )
	{
		if ( g_C4Timer > 20 )
			g_iColor = 0;
		else if ( g_C4Timer > 10 )
			g_iColor = 1;
		else if ( g_C4Timer <= 10 )
			g_iColor = 2;
			
		set_hudmessage( g_iRed[ g_iColor ], g_iGreen[ g_iColor ], g_iBlue[ g_iColor ], -1.0, 0.83, 0, 1.0, 1.0, 0.01, 0.01, -1 );
		ShowSyncHudMsg( 0, gSyncHudMessage, "Bomba explodeaza in: %i secund%s!", g_C4Timer, g_C4Timer == 1 ? "a" : "e" );
		g_C4Timer--;
	}

	else 
		remove_task( C4_TASK );
		
}

public Hook_TextMessages( iMsgId, iMsgDest, id )
{
	if( get_pcvar_num( gCvarOn ) == 0 )
		return PLUGIN_CONTINUE;
    
	static szMsg[ 64 ];
	get_msg_arg_string( 2, szMsg, sizeof ( szMsg ) - 1 );
	
	new iDropped = get_pcvar_num( gCvarDropped );
	if( iDropped && equal( szMsg, "#Game_bomb_drop" ) )
	{
		set_hudmessage( 255, 0, 0, -1.0, 0.16, 0, 0.0, 3.5, 0.1, 0.1, -1 );
		ShowSyncHudMsg( 0, gSyncHudMessage, "Furienii au pierdut bomba !" );
		return PLUGIN_HANDLED;
	}
	
	new iPicked = get_pcvar_num( gCvarPicked );
	if( iPicked  && equal( szMsg, "#Game_bomb_pickup" ) || iPicked  && equal( szMsg, "#Got_bomb" ) )
	{
		set_hudmessage( 255, 0, 0, -1.0, 0.16, 0, 0.0, 3.5, 0.1, 0.1, -1 );
		ShowSyncHudMsg( 0, gSyncHudMessage, "Furienii au recuperat bomba!" );
		return PLUGIN_HANDLED;
	}
		
	return PLUGIN_CONTINUE;
}

public ev_ResetHUD( )
{
	g_C4Timer = 0;
}

public TeamWonOrRoundDraw( )
{
	RemoveTimerTask( );
}

public le_RoundStart( )
{
	RemoveTimerTask( );
}

public le_RoundEnd()
{
	RemoveTimerTask( );
}

public plugin_end()
{
	RemoveTimerTask( );
}

public RemoveTimerTask( )
{
	if( get_pcvar_num( gCvarOn ) == 0 )
		return;
		
	g_C4Timer = -1;
	remove_task( C4_TASK );
}

[Ulquiorra]

merge bine si varianta lui cybi..
inca cv.. functia mp3 play se foloseste in felul urmator:

Code: Select all

client_cmd( 0, "mp3 play ^"sound/misc/fmu_bombplanted.mp3^"" );

eu am inteles ca atunci cand timpul a expirat sa se auda un sunet..
uite aici:

| Afiseaza codul

/* Plugin generated by AMXX-Studio */

	#include < amxmodx >
	#include < hamsandwich >
	#include < fakemeta >

	
	#pragma semicolon 1
	
	new const
		PLUGIN_NAME[ ] 		= "New Plugin",
		PLUGIN_VERSION[ ] 	= "1.0";
		
	new const
		SOUND[ ]		= "sound/misc/time.mp3";
		
	new Float:g_fBlockC4;
	new bool:CanPlant = false;
	
	
	new SyncHudMessage;
	new cvar_spawnblock;
	
public plugin_precache( )	precache_generic( SOUND );

public plugin_init( )
{
	register_plugin( PLUGIN_NAME, PLUGIN_VERSION, "Askhanar" );
	cvar_spawnblock = register_cvar( "amx_nobmbplant", "60" );
	
	register_event( "HLTV", "ev_HookRoundStart", "a", "1=0", "2=0" );
	register_event( "TextMsg", "evBombMessage", "b", "2=#C4_Plant_At_Bomb_Spot" ); 
	
	RegisterHam( Ham_Weapon_PrimaryAttack, "weapon_c4", "hamPrimaryAttackC4" );
	SyncHudMessage = CreateHudSyncObj( );
	
	set_task( 1.0, "CheckBombTime", _, _, _, "b", 0 );
}


public ev_HookRoundStart( )
{
		
	g_fBlockC4 = 0.0;
	g_fBlockC4 = get_gametime( );
	CanPlant = false;
	
	
}


public evBombMessage( id ) 
{ 
	if( CanPlant == false ) 
	{
		client_print( id, print_center, "" );
	}
}

public hamPrimaryAttackC4( iEnt )
{ 
	
	if( CanPlant == false )
	{
		new id = pev( iEnt, pev_owner );
		set_hudmessage( 0, 255, 0, -1.0, 0.45, 0, 0.0, 8.0, 0.0, 0.1, 4 );
		ShowSyncHudMsg( id, SyncHudMessage, "Mai sunt %.1f secunde pana vei putea planta bomba !",   get_pcvar_num( cvar_spawnblock ) - ( get_gametime( ) - g_fBlockC4 ) );
		return HAM_SUPERCEDE;
	}
	
	return HAM_IGNORED; 
}

public CheckBombTime( )
{
	if( CanPlant == false )
	{
		if( ( get_gametime( ) - g_fBlockC4 ) > float( get_pcvar_num( cvar_spawnblock ) ) )
		{
			set_hudmessage( 255, 0, 0, -1.0, 0.45, 0, 0.0, 8.5, 0.0, 5.0, 4 );
			ShowSyncHudMsg( 0, SyncHudMessage, "Furienii sunt aproape sa distruga planeta !^nEste haos total ! Antifurieni mai aveti o singura sansa !" );
			CanPlant = true;
			
			client_cmd( 0, "mp3 play ^"%s^"", SOUND );
			
		}
	}
		
}

sunetul trebuie sa fie .mp3 si il treci sus in

Code: Select all

new const
              SOUND[ ]                    = "sound/misc/time.mp3";

[shut.theart]

ms ask!
a ta merge perfect!