Cere plugin VIP- s

[Laurentiu P.]

Salut as dorii si eu un plugin modul counter - strike 1.6 clasic cu urmatoarele benficii:

* Flag's": bit
* Sa primeasca 125 si 125 HP / AP
* La fiecare kill facut sa primeasca bani si HP in plus: Kill - 15 HP, HeadShout - 25 HP si Kill - 250$, HeadShout - 350$
* Sa vada dmg-ul facut in timp real
* 2x Jump
* Deagle la fiecare spawn cu 28 gloante
* Sa apara in TAB SCORE si cand scrii /vips sa apara ca vip online (Vipi Conectati: nume , nume )
* Un meniu cu Ak47 si M4A1 gratuit si sa-l poata folosii odata la 3 runde
*In legatura cu Deaglul si granazile la hartile gen 35hp sau 1hp sau cele care folosesc doar Kniful se poate oprii folosirea Deaglului si a grenazilor?

[Laurentiu P.]

Cineva? :D>-

[Cosmin]

Poate imi fac eu timp in seara asta :)
EDIT1:

| Afiseaza codul

/* Credite: fatzzu pentru multijump */

#include <amxmodx>
#include <hamsandwich>
#include <fun>
#include <cstrike>
#include <engine>

#define PLUGIN "VIP nenicule vip :))"
#define VERSION "1.0"
#define AUTHOR "C0sm1N"

static const COLOR[] = "^x04"

new gmsgSayText

new jumpnum[33] = 0
new bool:dojump[33] = false

new bool:bulletdamage[33], g_hudmsg1;

new TASK_ID = 23232

public plugin_init() {
	register_plugin(PLUGIN, VERSION, AUTHOR)
	RegisterHam( Ham_Spawn, "player", "spawnpost", 1)
	register_event( "DeathMsg", "evmsg", "a" );
	register_event("Damage", "on_damage", "b", "2!0", "3=0", "4!0")	
	register_event( "ResetHUD", "ev_ResetHud", "be" );
	g_hudmsg1 = CreateHudSyncObj()
	register_clcmd ("say /vips","Vipsss");
	gmsgSayText = get_user_msgid("SayText");
}

stock bool:Vips(id)
{
	if(get_user_flags(id) & read_flags("bit"))
		return true
	
	return false
}

public spawnpost(id)
{
	if(Vips(id))
	{
		set_user_health(id, get_user_health(id) + 25)
		set_user_armor(id, get_user_armor(id) + 25)
		bulletdamage[id] = true
		
		give_item(id, "weapon_deagle")
		cs_set_user_bpammo(id, CSW_DEAGLE, 28)
	}
}

public evmsg(id)
{
	if(Vips(id))
	{
		new iKiller
		new iVictim
		new iHeadshot
		
		iKiller = read_data( 1 )
		iVictim = read_data( 2 )
		iHeadshot = read_data( 3 )
		
		if(iKiller != iVictim && is_user_alive(iKiller))
		{
			set_user_health(iKiller, get_user_health(iKiller) + 15)
			cs_set_user_money(iKiller, cs_get_user_money(iKiller) + 250)
		}
		if(iHeadshot)
		{
			
			set_user_health(iKiller, get_user_health(iKiller) + 25)
			cs_set_user_money(iKiller, cs_get_user_money(iKiller) + 350)
		}
		
		
		
	}
}
public on_damage(id)
{
	static attacker; attacker = get_user_attacker(id)
	static damage; damage = read_data(2)
	if(is_user_connected(attacker) && bulletdamage[attacker])
	{
		set_hudmessage(0, 100, 200, -1.0, 0.55, 2, 0.1, 4.0, 0.02, 0.02, -1)
		ShowSyncHudMsg(attacker, g_hudmsg1, "%i^n", damage)
	}
}

public client_PreThink(id)
{
	if(is_user_alive(id) && Vips(id))
	{
		
		new nbut = get_user_button(id)
		new obut = get_user_oldbutton(id)
		if((nbut & IN_JUMP) && !(get_entity_flags(id) & FL_ONGROUND) && !(obut & IN_JUMP))
		{
			if(jumpnum[id] < 1)
			{
				dojump[id] = true
				jumpnum[id]++
				return PLUGIN_CONTINUE
			}
		}
		if((nbut & IN_JUMP) && (get_entity_flags(id) & FL_ONGROUND))
		{
			jumpnum[id] = 0
			return PLUGIN_CONTINUE
		}
	}
	return PLUGIN_CONTINUE
}

public client_PostThink(id)
{
	if(is_user_alive(id) && Vips(id))
	{
		if(dojump[id] == true)
		{
			new Float:velocity[3]	
			entity_get_vector(id,EV_VEC_velocity,velocity)
			velocity[2] = random_float(265.0,285.0)
			entity_set_vector(id,EV_VEC_velocity,velocity)
			dojump[id] = false
			return PLUGIN_CONTINUE
		}
	}
	return PLUGIN_CONTINUE
}

public ev_ResetHud( id )
{
	set_task( 2.0, "settabscore", id + TASK_ID );
}

public settabscore( taskid )
{
	new id = taskid - TASK_ID;
	
	if( Vips(id) && is_user_connected( id ) )
	{
		message_begin( MSG_ALL, get_user_msgid( "ScoreAttrib" ) );
		
		write_byte( id );
		write_byte( 4 );
		
		message_end( );
	}
}
public Vipsss(user) 
{
	new adminnames[33][32]
	new message[256]
	new id, count, x, len
	new maxplayers = get_maxplayers()
	for(id = 1 ; id <= maxplayers ; id++)
		if(is_user_connected(id))
		if(Vips(id))
		get_user_name(id, adminnames[count++], 31)
	
	len = format(message, 255, "%s VIP ONLINE: ",COLOR)
	if(count > 0) {
		for(x = 0 ; x < count ; x++) {
			len += format(message[len], 255-len, "%s%s ", adminnames[x], x < (count-1) ? ", ":"")
			if(len > 96 ) {
				print_message(user, message)
				len = format(message, 255, "%s ",COLOR)
			}
		}
		print_message(user, message)
	}
	else {
		len += format(message[len], 255-len, "Nu sunt VIPI online.")
		print_message(user, message)
	}
}

print_message(id, msg[]) {
	message_begin(MSG_ONE, gmsgSayText, {0,0,0}, id)
	write_byte(id)
	write_string(msg)
	message_end()
}

public client_putinserver(id)
{
	jumpnum[id] = 0
	dojump[id] = false
}

public client_disconnect(id)
{
	jumpnum[id] = 0
	dojump[id] = false
	bulletdamage[id] = false
}
/* AMXX-Studio Notes - DO NOT MODIFY BELOW HERE
*{\\ rtf1\\ ansi\\ ansicpg1252\\ deff0\\ deflang1033{\\ fonttbl{\\ f0\\ fnil Tahoma;}}\n\\ viewkind4\\ uc1\\ pard\\ f0\\ fs16 \n\\ par }
*/

Mai am de adaugat acel meniu de zici tu cu arme,apropo testeaza faza cu saritura dubla..nu sunt sigur ca merge :)