Ak47 gold [rezolvat]

[DeNisQwAnKiDo]

Descriere plugin cerut: As vrea un plug-in cu golden ak
Alte informatii: Atunci cand scrii in chat /ak47 sa iti dea arma | daca ai 10000 $ | ( normal e /goldenak , dar eu vreau sa fie /ak47 ). Si mesajele sa fie traduse daca se poate :D ( la mine nu merge sa modific )

Multumesc ! :)

[kaRbooN]

Poftim:

| Afiseaza codul

/* AMX Mod script
* 
* (c) 2009, AlejandroSk
* This file is provided as is (no warranties).
*
*/



#include <amxmodx>
#include <fakemeta>
#include <fun>
#include <hamsandwich>
#include <cstrike>
#include <amxmisc>


#define is_valid_player(%1) (1 <= %1 <= 32)

new AK_V_MODEL[64] = "models/v_golden_ak47.mdl"
new AK_P_MODEL[64] = "models/p_golden_ak47.mdl"

/* Pcvars */
new cvar_dmgmultiplier, cvar_goldbullets,  cvar_custommodel, cvar_uclip, cvar_cost

new bool:g_HasAk[33]

new g_hasZoom[ 33 ]
new bullets[ 33 ]

// Sprite
new m_spriteTexture

const Wep_ak47 = ((1<<CSW_AK47))

public plugin_init()
{
	
	/* CVARS */
	cvar_dmgmultiplier = register_cvar("goldenak_dmg_multiplier", "5")
	cvar_custommodel = register_cvar("goldenak_custom_model", "1")
	cvar_goldbullets = register_cvar("goldenak_gold_bullets", "1")
	cvar_uclip = register_cvar("goldenak_unlimited_clip", "1")
	cvar_cost = register_cvar("goldenak_cost", "10000")
	
	// Register The Buy Cmd
	register_clcmd("say /ak47", "CmdBuyAk")
	register_clcmd("say_team /ak47", "CmdBuyAk")
	register_concmd("amx_ak47", "CmdGiveAk", ADMIN_BAN, "<name>")
	
	// Register The Plugin
	register_plugin("Golden Ak 47", "1.0", "AlejandroSk")
	// Death Msg
	register_event("DeathMsg", "Death", "a")
	// Weapon Pick Up
	register_event("WeapPickup","checkModel","b","1=19")
	// Current Weapon Event
	register_event("CurWeapon","checkWeapon","be","1=1")
	register_event("CurWeapon", "make_tracer", "be", "1=1", "3>0")
	// Ham TakeDamage
	RegisterHam(Ham_TakeDamage, "player", "fw_TakeDamage")
	register_forward( FM_CmdStart, "fw_CmdStart" )
	RegisterHam(Ham_Spawn, "player", "fwHamPlayerSpawnPost", 1)
	
}

public client_connect(id)
{
	g_HasAk[id] = false
}

public client_disconnect(id)
{
	g_HasAk[id] = false
}

public Death()
{
	g_HasAk[read_data(2)] = false
}

public fwHamPlayerSpawnPost(id)
{
	g_HasAk[id] = false
}

public plugin_precache()
{
	precache_model(AK_V_MODEL)
	precache_model(AK_P_MODEL)
	m_spriteTexture = precache_model("sprites/dot.spr")
	precache_sound("weapons/zoom.wav")
}

public checkModel(id)
{
	if ( !g_HasAk[id] )
		return PLUGIN_HANDLED
	
	new szWeapID = read_data(2)
	
	if ( szWeapID == CSW_AK47 && g_HasAk[id] == true && get_pcvar_num(cvar_custommodel) )
	{
		set_pev(id, pev_viewmodel2, AK_V_MODEL)
		set_pev(id, pev_weaponmodel2, AK_P_MODEL)
	}
	return PLUGIN_HANDLED
}

public checkWeapon(id)
{
	new plrClip, plrAmmo, plrWeap[32]
	new plrWeapId
	
	plrWeapId = get_user_weapon(id, plrClip , plrAmmo)
	
	if (plrWeapId == CSW_AK47 && g_HasAk[id])
	{
		checkModel(id)
	}
	else 
	{
		return PLUGIN_CONTINUE
	}
	
	if (plrClip == 0 && get_pcvar_num(cvar_uclip))
	{
		// If the user is out of ammo..
		get_weaponname(plrWeapId, plrWeap, 31)
		// Get the name of their weapon
		give_item(id, plrWeap)
		engclient_cmd(id, plrWeap) 
		engclient_cmd(id, plrWeap)
		engclient_cmd(id, plrWeap)
	}
	return PLUGIN_HANDLED
}



public fw_TakeDamage(victim, inflictor, attacker, Float:damage)
{
	if ( is_valid_player( attacker ) && get_user_weapon(attacker) == CSW_AK47 && g_HasAk[attacker] )
	{
		SetHamParamFloat(4, damage * get_pcvar_float( cvar_dmgmultiplier ) )
	}
}

public fw_CmdStart( id, uc_handle, seed )
{
	if( !is_user_alive( id ) ) 
		return PLUGIN_HANDLED
	
	if( ( get_uc( uc_handle, UC_Buttons ) & IN_ATTACK2 ) && !( pev( id, pev_oldbuttons ) & IN_ATTACK2 ) )
	{
		new szClip, szAmmo
		new szWeapID = get_user_weapon( id, szClip, szAmmo )
		
		if( szWeapID == CSW_AK47 && g_HasAk[id] == true && !g_hasZoom[id] == true)
		{
			g_hasZoom[id] = true
			cs_set_user_zoom( id, CS_SET_AUGSG552_ZOOM, 0 )
			emit_sound( id, CHAN_ITEM, "weapons/zoom.wav", 0.20, 2.40, 0, 100 )
		}
		
		else if ( szWeapID == CSW_AK47 && g_HasAk[id] == true && g_hasZoom[id])
		{
			g_hasZoom[ id ] = false
			cs_set_user_zoom( id, CS_RESET_ZOOM, 0 )
			
		}
		
	}
	return PLUGIN_HANDLED
}


public make_tracer(id)
{
	if (get_pcvar_num(cvar_goldbullets))
	{
		new clip,ammo
		new wpnid = get_user_weapon(id,clip,ammo)
		new pteam[16]
		
		get_user_team(id, pteam, 15)
		
		if ((bullets[id] > clip) && (wpnid == CSW_AK47) && g_HasAk[id]) 
		{
			new vec1[3], vec2[3]
			get_user_origin(id, vec1, 1) // origin; your camera point.
			get_user_origin(id, vec2, 4) // termina; where your bullet goes (4 is cs-only)
			
			
			//BEAMENTPOINTS
			message_begin( MSG_BROADCAST,SVC_TEMPENTITY)
			write_byte (0)     //TE_BEAMENTPOINTS 0
			write_coord(vec1[0])
			write_coord(vec1[1])
			write_coord(vec1[2])
			write_coord(vec2[0])
			write_coord(vec2[1])
			write_coord(vec2[2])
			write_short( m_spriteTexture )
			write_byte(1) // framestart
			write_byte(5) // framerate
			write_byte(2) // life
			write_byte(10) // width
			write_byte(0) // noise
			write_byte( 255 )     // r, g, b
			write_byte( 215 )       // r, g, b
			write_byte( 0 )       // r, g, b
			write_byte(200) // brightness
			write_byte(150) // speed
			message_end()
		}
		
		bullets[id] = clip
	}
	
}

public CmdBuyAk(id)
{
	if ( !is_user_alive(id) )
	{
		client_print(id,print_chat, "[AMXX] Pentru a cumpara Ak47 trebuie sa fii viu!")
		return PLUGIN_HANDLED
	}
	
	new money = cs_get_user_money(id)
	
	if (money >= get_pcvar_num(cvar_cost))
	{
		cs_set_user_money(id, money - get_pcvar_num(cvar_cost))
		give_item(id, "weapon_ak47")
		g_HasAk[id] = true
	}
	
	else
	{
		client_print(id, print_chat, "[AMXX] Nu ai destui bani pentru a cumpara Ak 47. Costa $%d", get_pcvar_num(cvar_cost))
	}
	return PLUGIN_HANDLED
}

public CmdGiveAk(id,level,cid)
{
	if (!cmd_access(id,level,cid,2))
		return PLUGIN_HANDLED;
	new arg[32];
	read_argv(1,arg,31);
	
	new player = cmd_target(id,arg,7);
	if (!player) 
		return PLUGIN_HANDLED;
	
	new name[32];
	get_user_name(player,name,31);
	
	give_item(player, "weapon_ak47")
	g_HasAk[player] = true
	
	return PLUGIN_HANDLED
}

stock drop_prim(id) 
{
	new weapons[32], num
	get_user_weapons(id, weapons, num)
	for (new i = 0; i < num; i++) {
		if (Wep_ak47 & (1<<weapons)) 
		{
			static wname[32]
			get_weaponname(weapons, wname, sizeof wname - 1)
			engclient_cmd(id, "drop", wname)
		}
	}
}
/* AMXX-Studio Notes - DO NOT MODIFY BELOW HERE
*{\\ rtf1\\ ansi\\ deff0{\\ fonttbl{\\ f0\\ fnil Tahoma;}}\n\\ viewkind4\\ uc1\\ pard\\ lang1034\\ f0\\ fs16 \n\\ par }
*/

Modelul de la arma il iei de aici: https://forums.alliedmods.net/showthread.php?p=827532

[DeNisQwAnKiDo]

Am modificat in .sma cum ai zis tu , dar tot /goldenak trebuie sa scriu :| si textul e tot in engleza

[kaRbooN]

Am modificat in .sma cum ai zis tu , dar tot /goldenak trebuie sa scriu :| si textul e tot in engleza

Nu are cum. Nu l-ai instalat bine poate. Sterge pluginul care il ai si sma si amxx si intaleaza-l de la capat ca nu are cum sa nu-ti mearga.

Copie sursa pe care am postat-o in primul reply.

Poftim pluginul compilat. http://www.amxmodx.org/webcompiler.cgi?go=dl&id=1690811

Il pui in plugins si in configs / plugins.ini scrii ak47.amxx

[DeNisQwAnKiDo]

Am facut asta de 3 ori ... Tot asa e ... Nu s-a modificat nimic :|

[DaNNe.]

| Afiseaza codul

#include <amxmodx>
#include <cstrike>
#include <fakemeta>
#include <fakemeta_util>
#include <hamsandwich>

#define PLUGIN "BUY: Golden AK47"
#define VERSION "1.0"
#define AUTHOR "DaNNe."

new AK47GOLDENModel_V[] = "models/v_golden_ak47.mdl";
new AK47GOLDENModel_P[] = "models/p_golden_ak47.mdl";

new bool:HAVECUSTOMAK47[33];
new cvar_cost, cvar_damage;

public plugin_init() {
	register_plugin(PLUGIN, VERSION, AUTHOR)
	
	register_clcmd("say /ak47", "CMDAK47")
	
	register_event("CurWeapon", "EVENT_CurWeapon", "be", "1=1")
	register_event("DeathMsg", "EVENT_Death", "a")
	
	RegisterHam(Ham_TakeDamage, "player", "Ham_Take_Damage")
	
	cvar_cost = register_cvar("ak47gold_cost", "10000")
	cvar_damage = register_cvar("ak47gold_damage", "2.0")
}

public CMDAK47(id) {
	if(!is_user_alive(id))
		return;
	new Money = cs_get_user_money(id) - get_pcvar_num(cvar_cost)
	if(Money < 0)
		client_print(id, print_center, "Nu ai suficienti bani!")
	else {
		fm_give_item(id, "weapon_ak47")
		cs_set_user_bpammo(id, CSW_AK47, 90)
		HAVECUSTOMAK47[id] = true;
		EVENT_CurWeapon(id)
		cs_set_user_money(id, Money)
	}
}

public EVENT_CurWeapon(id) {
	if(HAVECUSTOMAK47[id]) {
		set_pev(id, pev_viewmodel2, AK47GOLDENModel_V)
		set_pev(id, pev_weaponmodel2, AK47GOLDENModel_P)
	}
}

public EVENT_Death() 
	HAVECUSTOMAK47[read_data(2)] = false;
	
public Ham_Take_Damage(Victim, Inflictor, Attacker, Float:Damage) {
	if(is_user_connected(Attacker) && is_user_alive(Attacker)) {
		if(get_user_weapon(Attacker) == CSW_AK47 && HAVECUSTOMAK47[Attacker])
			SetHamParamFloat(4, Damage * get_pcvar_float(cvar_damage))
	}
}

Modelele le cauti pe NET.
Ai in sursa cvar-uri pentru pret si damage.

[DeNisQwAnKiDo]

Eu vreau sa dea playerilor ak47 gold atunci cand scriu in chat /ak47 , nu /goldenak ... Tot nu merge :|

[Cosmin]

| Afiseaza codul

#include <amxmodx>
#include <fun>
#include <cstrike>
#include <hamsandwich>
#include <fakemeta>

static const
	PLUGIN[] = "Golden Kalashnikov",
	VERSION[] = "1.0",
	AUTHOR[] = "C0sm1N";
	
new const Ak47[][] =
{
	"models/goldenak47/v_ak47.mdl",
	"models/goldenak47/p_ak47.mdl"
}

const m_pPlayer = 41
const XO_WEAPON = 4

new bool:ak[33],money

public plugin_init(){
	register_plugin(PLUGIN,VERSION,AUTHOR);
	
	register_clcmd("say /ak47","cmdAk47");
	
	RegisterHam(Ham_Spawn,"player","fwd_spawn",1);
	RegisterHam(Ham_Item_Deploy,"weapon_ak47","fwd_deploy",1);
	
	money = register_cvar("cvar_cost_ak47","3000")
}
public fwd_spawn(id)	ak[id] = false

public cmdAk47(id) {
	if(!is_user_alive(id) || ak[id])	return
	
	if(cs_get_user_money(id) >= get_pcvar_num(money))
	{
		cs_set_user_money(id,cs_get_user_money(id) - get_pcvar_num(money))
		give_item(id,"weapon_ak47")
		cs_set_user_bpammo(id,CSW_AK47,90)
		ak[id] = true
	}
}
public fwd_deploy(weapon)
{
	new id = get_pdata_cbase(weapon,m_pPlayer,XO_WEAPON)
	if(ak[id])
	{
		set_pev(id, pev_viewmodel2,Ak47[0])
		set_pev(id, pev_weaponmodel2,Ak47[1])
	}
}
public client_disconnect(id)	ak[id] = false
public client_putinserver(id)	ak[id] = false
public plugin_precache(){
	static i
	for(i = 0; i < sizeof Ak47; i++)
		precache_model(Ak47)
}

cvar:

Code: Select all

cvar_cost_ak47 "5000" //cat sa coste aceasta arma

modelele le adaugi tu,creezi in models un folder numit goldenak47 si adaugi in el v_ak47.mdl si p_ak47.mdl in el

[DaNNe.]

Eu vreau sa dea playerilor ak47 gold atunci cand scriu in chat /ak47 , nu /goldenak ... Tot nu merge :|

Tu nu stii sa instalezi un plugin. Garantez!
Eu am testat sursa care ti-am dat-o si merge perfect!

[DeNisQwAnKiDo]

Eu stiu sa modific si sa pun un plug-inuri pe un server ( am 2 servre ) . . . Problema asta o am la mai multe plug-inuri ... Degeaba le modific si traduc ca ele tot asa sunt ... cum le instalez asa raman ...

[DaNNe.]

Eu stiu sa modific si sa pun un plug-inuri pe un server ( am 2 servre ) . . . Problema asta o am la mai multe plug-inuri ... Degeaba le modific si traduc ca ele tot asa sunt ... cum le instalez asa raman ...

Bossulica, eu ce ti-am dat merge perfect! L-am testat eu.

[DeNisQwAnKiDo]

Am facut eu alt plugin si merge acum :D ... Multumesc !