Cerere Plugin no name change [Rezolvat]

[infinit]

Plugin Cerut:no name change
Descriere (adica ce face el mai exact):sa nu-ti poti schimba numele cand esti pe server
Serverul ruleaza (HLDS/ReHLDS):rehlds
Versiune AMX Mod X:1.8.2
Modul Serverului:zombie

[Rainq]

Code: Select all

#include <amxmodx>
#include <cromchat>
#include <fakemeta>

#define PLUGIN_VERSION "1.1"

new g_pAdminFlag, g_pMaxChanges
new g_iAdminFlag, g_iMaxChanges
new g_iChanges[33]

public plugin_init()
{
	register_plugin("No Name Change", PLUGIN_VERSION, "OciXCrom")
	register_cvar("CRXNoNameChange", PLUGIN_VERSION, FCVAR_SERVER|FCVAR_SPONLY|FCVAR_UNLOGGED)
	register_forward(FM_ClientUserInfoChanged, "OnUserInfoChanged")
	register_dictionary("NoNameChange.txt")
	g_pAdminFlag = register_cvar("nnc_admin_flag", "")
	g_pMaxChanges = register_cvar("nnc_max_changes", "0")
	CC_SetPrefix("&x04[NNC]")
}

public plugin_cfg()
{
	new szFlag[2]
	get_pcvar_string(g_pAdminFlag, szFlag, charsmax(szFlag))
	g_iAdminFlag = read_flags(szFlag)
	g_iMaxChanges = get_pcvar_num(g_pMaxChanges)
}

public client_putinserver(id)
{
	if(g_iMaxChanges)
		g_iChanges[id] = 0
}

public OnUserInfoChanged(id)
{
	if(g_iAdminFlag && get_user_flags(id) & g_iAdminFlag)
		return FMRES_IGNORED
	
	static const szName[] = "name"
	static szOldName[32], szNewName[32]
	pev(id, pev_netname, szOldName, charsmax(szOldName))
	
	if(szOldName[0])
	{
		get_user_info(id, szName, szNewName, charsmax(szNewName))
		
		if(!equal(szOldName, szNewName))
		{
			if(g_iChanges[id] < g_iMaxChanges)
			{
				g_iChanges[id]++
				
				new g_iChangesLeft = g_iMaxChanges - g_iChanges[id]
				CC_SendMessage(id, "%L", id, !g_iChangesLeft ? "NNC_CHANGE_ZERO" : g_iChangesLeft == 1 ? "NNC_CHANGE_ONE" : "NNC_CHANGE_MORE", g_iChangesLeft)
				return FMRES_IGNORED
			}
			
			set_user_info(id, szName, szOldName)
			CC_SendMessage(id, "%L", id, "NNC_MESSAGE")
			return FMRES_HANDLED
		}
	}
	
	return FMRES_IGNORED
}

NoNameChange.txt(asta vine in data/lang) :

Code: Select all

[en]
NNC_MESSAGE = You are not allowed to change your name.
NNC_CHANGE_ONE = You can change your name &x04%i &x01more time.
NNC_CHANGE_MORE = You can change your name &x04%i &x01more times.
NNC_CHANGE_ZERO = You can't change your name during this session anymore.

[mk]
NNC_MESSAGE = Nemash pravo da si go promenish imeto.
NNC_CHANGE_ONE = Mozhesh da si go smenish imeto ushte &x04%i &x01pat.
NNC_CHANGE_MORE = Mozhesh da si go smenish imeto ushte &x04%i &x01pati.
NNC_CHANGE_ZERO = Vekje ne mozhesh da si go menuvash imeto za ovaa sesija.

[bg]
NNC_MESSAGE = Nqmash pravo da si promenish imeto.
NNC_CHANGE_ONE = Mojesh da si promenish imeto oshte &x04%i &x01put.
NNC_CHANGE_MORE = Mojesh da si promenish imeto oshte &x04%i &x01puti.
NNC_CHANGE_ZERO = Veche ne mojesh da si promenqsh imeto za tazi sesiq.

[levin]

Code: Select all

#include <amxmodx> 
#include <fakemeta> 

#define VERSION "0.1.0" 

public plugin_init() 
{ 
    register_plugin("One Name", VERSION, "ConnorMcLeod") 
    register_forward(FM_ClientUserInfoChanged, "ClientUserInfoChanged") 
} 

public ClientUserInfoChanged(id) 
{ 
    static const name[] = "name" 
    static szOldName[32], szNewName[32] 
    pev(id, pev_netname, szOldName, charsmax(szOldName)) 
    if( szOldName[0] ) 
    { 
        get_user_info(id, name, szNewName, charsmax(szNewName)) 
        if( !equal(szOldName, szNewName) ) 
        { 
            set_user_info(id, name, szOldName) 
            return FMRES_HANDLED 
        } 
    } 
    return FMRES_IGNORED 
}  

[infinit]

multumesc ca mai ajutat
puteti da TC

[WHOAMI?]

Marcat ca "Rezolvat"