Ore jucate pe server in total.

[Alexandru]

Vreau si eu un plugin care, daca tastezi in chat o comanda, sa-ti arate totalul de ore jucate pe server. Chestia e ca am gasit un plugin pentru asa ceva aici, dar este numai pe IP sau SteamID. Eu il vreau sa salveze pe nick, cum eu nu stiu sa modific plugin-uri, m-am gandit sa va cer ajutorul pentru asta.

Multumesc anticipat.

[Ciprian]

Vezi asta:

PlayedTime | Afiseaza codul

/* Plugin generated by AMXX-Studio */

#include < amxmodx >
#include < nvault >

#define PLUGIN "PlayedTime"
#define VERSION "1.0"
#define AUTHOR "crazy.cipry"

new const g_Commands[ ] [ ] = {
	"say /orejucate",
	"say_team /orejucate"
}

new g_Nvault;

public plugin_init ( ) {
	register_plugin ( PLUGIN, VERSION, AUTHOR );
	
	for ( new i = 0; i < sizeof ( g_Commands ); i++ )
		register_clcmd ( g_Commands[ i ], "cmdOreJucate" );

	g_Nvault = nvault_open ( "Played_Time" );
}

public client_disconnect ( id ){
	new name[ 32 ], vaultkey[ 64 ], vaultdata[ 64 ], TimeStamp, szTime[ 8 ], CurrentTime, TotalPlayedTime;
	
	get_user_name ( id, name, charsmax ( name ) );
	formatex ( vaultkey, charsmax ( vaultkey ), "%s", name );
	
	CurrentTime = get_user_time ( id, 1 );
	TotalPlayedTime = 0;
	
	if ( nvault_lookup ( g_Nvault, vaultkey, szTime, charsmax ( szTime ), TimeStamp ) ) {
		TotalPlayedTime = str_to_num ( szTime ) + CurrentTime;
		formatex ( vaultdata, charsmax ( vaultdata ), "%d", TotalPlayedTime );
	}
	else 
		formatex ( vaultdata, charsmax ( vaultdata ), "%d", CurrentTime );
	
	nvault_set ( g_Nvault, vaultkey, vaultdata );
	nvault_close ( g_Nvault );
}

public cmdOreJucate ( id ) {
	new OreJucate, name[ 32 ], szTime[ 8 ], TimeStamp;
	
	get_user_name ( id, name, charsmax ( name ) );
	
	if ( nvault_lookup ( g_Nvault, name, szTime, charsmax ( szTime ), TimeStamp ) )
		OreJucate = str_to_num ( szTime ) + get_user_time ( id );
	else
		OreJucate = get_user_time ( id );
	
	client_print ( id, print_chat, "You have played on this server for %d h.", OreJucate );
	
	return PLUGIN_CONTINUE;
}

Sau iti inscrii serverul pe gametracker.

[Alexandru]

L-am pus, contorizeaza doar pentru sesiunea cand m-am conectat pe server. Daca dau retry o ia de la capat. Am pus debug in dreptul lui si imi da eroarea asta:

Code: Select all

[AMXX] Run time error 10: native error (native "nvault_lookup")
[AMXX]    [0] ore.sma::cmdOreJucate (line 51)

IP dinamic, deci optiunea asta cade.

[burn09]

ai activat modulul nvault?

[Alexandru]

Da, am verificat asta.

[Ciprian]

ai activat modulul nvault?

Oricum se activeaza singur daca nu e activat. Alesule, imi pare rau, dar nu am reusit sa-i dau de cap erorii aleia.

[Alexandru]

Nu-i nimic, e altcineva care ma poate ajuta pe aici?:D

[aNNakin]

Vezi asta + nu mai trebuie modul

| Afiseaza codul

[code]#include < amxmodx >

#define PLUGIN "Played Time"
#define VERSION "1.0"
#define AUTHOR "aNNakin"

#define _vault_dir "addons/amxmodx/data/file_vault"

// - - -
new const gs_VaultName[ ] = "PlayedTime";
// - - -

new gi_PlayedTime[ 33 ];

public plugin_init ( )
{
	register_plugin ( PLUGIN, VERSION, AUTHOR );
	register_clcmd ( "say /playedtime", "playedtime_cmd" );
}

public client_disconnect ( id )
	SaveTime ( id );
public client_putinserver ( id )
	LoadTime ( id );
	
public SaveTime ( id )
{
	gi_PlayedTime[ id ] += get_user_time ( id );
	
	new s_Name[ 32 ], s_Data[ 16 ];
	get_user_name ( id, s_Name, 31 );
	num_to_str ( gi_PlayedTime[ id ], s_Data, charsmax ( s_Data ) );
    
	fvault_set_data ( gs_VaultName, s_Name, s_Data );
}

public LoadTime ( id )
{
	new s_Name[ 32 ], s_Data[ 16 ];
	get_user_name ( id, s_Name, 31 );
    
	if ( fvault_get_data ( gs_VaultName, s_Name, s_Data, charsmax ( s_Data ) ) )
		gi_PlayedTime[ id ] = str_to_num ( s_Data );
	else
		gi_PlayedTime[ id ] = 0;
}

public playedtime_cmd ( id )
{
	new i_Total = gi_PlayedTime[ id ] + get_user_time ( id );
	
	if ( i_Total < 60 )
		client_print ( id, print_chat, "Timp total: %d secunde", i_Total );
	else if ( i_Total >= 60 && i_Total < 3600 )
		client_print ( id, print_chat, "Timp total: %d minute", ( i_Total / 60 ) );
	else if ( i_Total >= 3600 )
		client_print ( id, print_chat, "Timp total: %d ore si %d minute", ( i_Total / 3600 ), ( i_Total % 3600 ) );
	
	return 0;
}

// - - -

fvault_set_data(const vaultname[], const key[], const data[])
{
	static const temp_vault_name[] = "fvault_set_data.txt";
	
	new file = fopen(temp_vault_name, "wt");
	
	new filename[128];
	_FormatVaultName(vaultname, filename, sizeof(filename) - 1);
	
	new vault = fopen(filename, "rt");
	
	new _data[512], _key[64], _other[3];
	
	new bool:replaced = false;
	
	while( !feof(vault) )
	{
		fgets(vault, _data, sizeof(_data) - 1);
		parse(_data, _key, sizeof(_key) - 1, _other, sizeof(_other) - 1);
		
		if( equal(_key, key) && !replaced )
		{
			fprintf(file, "^"%s^" ^"%s^"^n", key, data);
			
			replaced = true;
		}
		else
		{
			fputs(file, _data);
		}
	}
	
	if( !replaced )
	{
		fprintf(file, "^"%s^" ^"%s^"^n", key, data);
	}
	
	fclose(file);
	fclose(vault);
	
	delete_file(filename);
	
	while( !rename_file(temp_vault_name, filename, 1) ) { }
	
	//delete_file(temp_vault_name);
}

fvault_get_data(const vaultname[], const key[], data[], len)
{
	new filename[128];
	_FormatVaultName(vaultname, filename, sizeof(filename) - 1);
	
	new vault = fopen(filename, "rt");
	
	new _data[512], _key[64];
	
	while( !feof(vault) )
	{
		fgets(vault, _data, sizeof(_data) - 1);
		parse(_data, _key, sizeof(_key) - 1, data, len);
		
		if( equal(_key, key) )
		{
			fclose(vault);
			
			return 1;
		}
	}
	
	fclose(vault);
	
	copy(data, len, "");
	
	return 0;
}

_FormatVaultName(const vaultname[], filename[], len)
{
	static const invalid_chars[][] =
	{
		"/", "\", "*", ":", "?", "^"", "<", ">", "|"
	};
	
	static tempvault[128], i;
	copy(tempvault, sizeof(tempvault) - 1, vaultname);
	
	for( i = 0; i < sizeof(invalid_chars); i++ )
	{
		replace(tempvault, sizeof(tempvault) - 1, invalid_chars, "");
	}
	
	if( !dir_exists(_vault_dir) )
	{
		mkdir(_vault_dir);
	}
	
	formatex(filename, len, "%s/%s.txt", _vault_dir, tempvault);
}[/code]

[Alexandru]

Multumesc frumos, merge. Dar mai am o mica cerinta la el, daca se poate. Atunci cand scriu /playedtime nume, sa apara timpul acelui jucator.
Iar optional, daca stii si nu-ti ia prea mult timp, sa faci un top 15 al celor mai activi jucatori pe server.

[aNNakin]

| Afiseaza codul

[code]#include < amxmodx >
#include < amxmisc >

#define PLUGIN "Played Time"
#define VERSION "1.0"
#define AUTHOR "aNNakin"

#define _vault_dir "addons/amxmodx/data/file_vault"

// - - - - - - - - -

// * numele fisierului unde se salveaza timpuljucat
new const gs_VaultName[ ] = "PlayedTime";

// * comanda say /timeplayed nume
new const gs_Command[ ] = "/timeplayed";

//* caracterul din fata comenzii
new const gs_Char[ ] = "/";

// * primii x jucatori care vor fi afisati in top
#define TOP_PLAYERS	15

// - - - - - - - - -

new gi_PlayedTime[ 33 ];
new g_Sort[ 33 ][ 2 ];

public plugin_init ( )
{
	register_plugin ( PLUGIN, VERSION, AUTHOR );
	register_clcmd ( "say /playedtime", "playedtime_cmd" );
	register_clcmd ( "say /topplayedtime", "show_top" );
	
	register_clcmd ( "say", "hook_say" );
	
	new s_Console[ 32 ], s_Command[ 32 ];
	copy ( s_Console, charsmax ( s_Console ), gs_Command );
	replace ( s_Console, charsmax ( s_Console ), gs_Char, "" );
	formatex ( s_Command, charsmax ( s_Command ),"amx_%s", s_Console );
	register_concmd ( s_Command, "playedtime_console" );
}

public client_disconnect ( id )
	SaveTime ( id );
public client_putinserver ( id )
	LoadTime ( id );
	
public SaveTime ( id )
{
	gi_PlayedTime[ id ] += get_user_time ( id );
	
	new s_Name[ 32 ], s_Data[ 16 ];
	get_user_name ( id, s_Name, 31 );
	num_to_str ( gi_PlayedTime[ id ], s_Data, charsmax ( s_Data ) );
    
	fvault_set_data ( gs_VaultName, s_Name, s_Data );
}

public LoadTime ( id )
{
	new s_Name[ 32 ], s_Data[ 16 ];
	get_user_name ( id, s_Name, 31 );
    
	if ( fvault_get_data ( gs_VaultName, s_Name, s_Data, charsmax ( s_Data ) ) )
		gi_PlayedTime[ id ] = str_to_num ( s_Data );
	else
		gi_PlayedTime[ id ] = 0;
}

public playedtime_cmd ( id )
{
	new i_Total = gi_PlayedTime[ id ] + get_user_time ( id );
	
	if ( i_Total < 60 )
		client_print ( id, print_chat, "Timp total: %d secunde", i_Total );
	else if ( i_Total >= 60 && i_Total < 3600 )
		client_print ( id, print_chat, "Timp total: %d minute", ( i_Total / 60 ) );
	else if ( i_Total >= 3600 )
		client_print ( id, print_chat, "Timp total: %d ore si %d minute", ( i_Total / 3600 ), ( i_Total % 3600 ) );
	
	return 0;
}

public hook_say ( e_Index )
{
	static s_Args[ 192 ], s_Command[ 192 ];
	read_args ( s_Args, charsmax ( s_Args ) );
	
	remove_quotes ( s_Args[ 0 ] );
	if ( ! s_Args[ 0 ] )
		return PLUGIN_CONTINUE;
		
	if ( equal ( s_Args, gs_Command, strlen ( gs_Command ) ) )
	{
		replace ( s_Args, charsmax ( s_Args ), gs_Char, "" );
		formatex ( s_Command, charsmax ( s_Command ),"amx_%s", s_Args );
		client_cmd ( e_Index, s_Command );
	}
	
	return PLUGIN_CONTINUE;
}
	
public playedtime_console ( id )
{
	new s_Arg[ 32 ];
	read_argv ( 1, s_Arg, 31 );
	
	new e_Target = cmd_target ( id, s_Arg, 31 );
	if ( ! e_Target )
		return PLUGIN_HANDLED;
	
	new s_Name[ 32 ];
	get_user_name ( e_Target, s_Name, 31 );
	
	new i_Total = gi_PlayedTime[ e_Target ] + get_user_time ( e_Target );
	
	if ( i_Total < 60 )
		client_print ( id, print_chat, "Timp total %s: %d secunde", s_Name, i_Total );
	else if ( i_Total >= 60 && i_Total < 3600 )
		client_print ( id, print_chat, "Timp total %s: %d minute", s_Name, ( i_Total / 60 ) );
	else if ( i_Total >= 3600 )
		client_print ( id, print_chat, "Timp total %s: %d ore si %d minute", s_Name, ( i_Total / 3600 ), ( i_Total % 3600 ) );
		
	return PLUGIN_HANDLED;
}

public show_top ( id )
{
	new players[ 32 ], index, count, num, i;
	get_players( players, num );
	
	for( ; i < num; i++ )
	{
		index = players[ i ];
		
		g_Sort[ count ][ 0 ] = index;
		g_Sort[ count ][ 1 ] = gi_PlayedTime[ index ];
		
		count++;
	}
	
	SortCustom2D( g_Sort, count, "time_compare" );
	
	new Motd[ 1024 ], Len;	
	
	Len = format( Motd, charsmax( Motd ),"<body bgcolor=#000000><font color=#98f5ff><pre>" );
	Len += format( Motd[ Len ], charsmax( Motd ) - Len,"%s %-22.22s %3s^n", "#", "Name", "Time Played" );
	
	
	new b = clamp( count, 0, TOP_PLAYERS );
	
	new name[ 32 ], player, j;
	
	for ( ; j < b; j++ )
	{
		player = g_Sort[ j ][ 0 ];
		
		get_user_name ( player, name, 31 );		
		Len += format ( Motd[ Len ], charsmax( Motd )-Len,"%d %-22.22s %d^n", j+1, name, g_Sort[ j ][ 1 ] );
	}
	Len += format ( Motd[ Len ], charsmax( Motd )-Len,"</body></font></pre>" );
	
	show_motd ( id, Motd, "Playedtime Top" );
	return PLUGIN_CONTINUE;
}

public time_compare ( elem1[ ], elem2[ ] )
{
	if ( elem1[ 1 ] > elem2[ 1 ] )
		return -1;
	else if ( elem1[ 1 ] < elem2[ 1 ] )
		return 1;
		
	return 0;
}
// - - -

fvault_set_data(const vaultname[], const key[], const data[])
{
	static const temp_vault_name[] = "fvault_set_data.txt";
	
	new file = fopen(temp_vault_name, "wt");
	
	new filename[128];
	_FormatVaultName(vaultname, filename, sizeof(filename) - 1);
	
	new vault = fopen(filename, "rt");
	
	new _data[512], _key[64], _other[3];
	
	new bool:replaced = false;
	
	while( !feof(vault) )
	{
		fgets(vault, _data, sizeof(_data) - 1);
		parse(_data, _key, sizeof(_key) - 1, _other, sizeof(_other) - 1);
		
		if( equal(_key, key) && !replaced )
		{
			fprintf(file, "^"%s^" ^"%s^"^n", key, data);
			
			replaced = true;
		}
		else
		{
			fputs(file, _data);
		}
	}
	
	if( !replaced )
	{
		fprintf(file, "^"%s^" ^"%s^"^n", key, data);
	}
	
	fclose(file);
	fclose(vault);
	
	delete_file(filename);
	
	while( !rename_file(temp_vault_name, filename, 1) ) { }
	
	//delete_file(temp_vault_name);
}

fvault_get_data(const vaultname[], const key[], data[], len)
{
	new filename[128];
	_FormatVaultName(vaultname, filename, sizeof(filename) - 1);
	
	new vault = fopen(filename, "rt");
	
	new _data[512], _key[64];
	
	while( !feof(vault) )
	{
		fgets(vault, _data, sizeof(_data) - 1);
		parse(_data, _key, sizeof(_key) - 1, data, len);
		
		if( equal(_key, key) )
		{
			fclose(vault);
			
			return 1;
		}
	}
	
	fclose(vault);
	
	copy(data, len, "");
	
	return 0;
}

_FormatVaultName(const vaultname[], filename[], len)
{
	static const invalid_chars[][] =
	{
		"/", "\", "*", ":", "?", "^"", "<", ">", "|"
	};
	
	static tempvault[128], i;
	copy(tempvault, sizeof(tempvault) - 1, vaultname);
	
	for( i = 0; i < sizeof(invalid_chars); i++ )
	{
		replace(tempvault, sizeof(tempvault) - 1, invalid_chars, "");
	}
	
	if( !dir_exists(_vault_dir) )
	{
		mkdir(_vault_dir);
	}
	
	formatex(filename, len, "%s/%s.txt", _vault_dir, tempvault);
}[/code]

Modificari:

| Afiseaza codul

[code]// - - - - - - - - -

// * numele fisierului unde se salveaza timpuljucat
new const gs_VaultName[ ] = "PlayedTime";

// * comanda say /timeplayed nume
new const gs_Command[ ] = "/timeplayed";

//* caracterul din fata comenzii
new const gs_Char[ ] = "/";

// * primii x jucatori care vor fi afisati in top
#define TOP_PLAYERS	15

// - - - - - - - - -[/code]

Comanda pentru top:

| Afiseaza codul

register_clcmd ( "say /topplayedtime", "show_top" );

[pirvu]

Len += format( Motd[ Len ], charsmax( Motd ) - Len,"%s %-22.22s %3s^n", "#", "Name", "Zoomless Kills" );


??? HEH Zoomless Kills :-o !?

[aNNakin]

Len += format( Motd[ Len ], charsmax( Motd ) - Len,"%s %-22.22s %3s^n", "#", "Name", "Zoomless Kills" );


??? HEH Zoomless Kills :-o !?

Opss...luasem codul din pluginul meu Zoomless Announcer si acolo am uitat sa modific, done.