screenfade_util.inc[rezolvat]

[Scooby112]

am si eu nevoie de va rog frumos..de un module pentru server de cs 1.6 pe LINUX ..eu am cautat pe internet si nu am gasit ..am impresia ca se numeste screenfade_util.inc
Am nevoie de acest module...deoarece am achizitionat un addons aliens vs hunters..si fara acest module,addons-ul nu are farmec...

imi puteti face rost va rog frumos de acest screenfade ?am impresia ca acest screenfade se refera la urmatoarele faze:
la mine de exemplu...la addonsul meu se refera in special la:
Cand un alien ii da o ghiara unui om,omul se cracaneaza,sau mai clar,"ecranul" se lasa intr-o parte..si nu numai cand ii da o ghiara,cand ii da si cu coada(click dreapta) ..cred ca mai mult screenfade-ul este facut pentru click dreapta..nu stiu sigur..dar mi-l puteti face ?va rog frumos

Respectele mele,
HunteR

[roby_the_dude]

Salut,poftim ceea ce cauți tu:

screenfade_util.inc | Afiseaza codul

#if defined _screenfade_util_included
	#endinput
#endif
#define _screenfade_util_included

#define FFADE_IN			0x0000		// Just here so we don't pass 0 into the function
#define FFADE_OUT			0x0001		// Fade out (not in)
#define FFADE_MODULATE		0x0002		// Modulate (don't blend)
#define FFADE_STAYOUT		0x0004		// ignores the duration, stays faded out until new ScreenFade message received

enum {
	Red,
	Green,
	Blue
};

stock FixedUnsigned16(Float:flValue, iScale)
{
	new iOutput;

	iOutput = floatround(flValue * iScale);

	if ( iOutput < 0 )
		iOutput = 0;

	if ( iOutput > 0xFFFF )
		iOutput = 0xFFFF;

	return iOutput;
}

stock UTIL_ScreenFade(id=0,iColor[3]={0,0,0},Float:flFxTime=-1.0,Float:flHoldTime=0.0,iAlpha=0,iFlags=FFADE_IN,bool:bReliable=false,bool:bExternal=false)
{
	if( id && !is_user_connected(id))
		return;

	new iFadeTime;
	if( flFxTime == -1.0 )
	{
		iFadeTime = 4;
	}
	else
	{
		iFadeTime = FixedUnsigned16( flFxTime , 1<<12 );
	}

	static gmsgScreenFade;
	if( !gmsgScreenFade )
	{
		gmsgScreenFade = get_user_msgid("ScreenFade");
	}

	new MSG_DEST;
	if( bReliable )
	{
		MSG_DEST = id ? MSG_ONE : MSG_ALL;
	}
	else
	{
		MSG_DEST = id ? MSG_ONE_UNRELIABLE : MSG_BROADCAST;
	}

	if( bExternal )
	{
		emessage_begin( MSG_DEST, gmsgScreenFade, _, id );
		ewrite_short( iFadeTime );
		ewrite_short( FixedUnsigned16( flHoldTime , 1<<12 ) );
		ewrite_short( iFlags );
		ewrite_byte( iColor[Red] );
		ewrite_byte( iColor[Green] );
		ewrite_byte( iColor[Blue] );
		ewrite_byte( iAlpha );
		emessage_end();
	}
	else
	{
		message_begin( MSG_DEST, gmsgScreenFade, _, id );
		write_short( iFadeTime );
		write_short( FixedUnsigned16( flHoldTime , 1<<12 ) );
		write_short( iFlags );
		write_byte( iColor[Red] );
		write_byte( iColor[Green] );
		write_byte( iColor[Blue] );
		write_byte( iAlpha );
		message_end();
	}
}

stock UTIL_FadeToBlack(id,Float:fxtime=3.0,bool:bReliable=false,bool:bExternal=false)
{
	UTIL_ScreenFade(id, _, fxtime, fxtime, 255, FFADE_OUT|FFADE_STAYOUT,bReliable,bExternal);
}

Sau ai aici altul diferit, de pe Alliedmodders: http://forums.alliedmods.net/showpost.p ... ostcount=9 .

[Scooby112]

asa si explicami te rog cum fac cu asta ?trebuie compilat sau cum ?ca sa inteleg si eu ...pus in .sma si facut amxx ?sau cum ?ca din cate stiu el este module ..si eu am sv de linux..deci ar trebui sa il fac ceva de genu screenfade_inc_amxx_i386.so ?nu ?
imi poti explica tu te rog frumos ?
si multumesc ca mi-ai facut rost de el

[KronoS eXtream]

asa si explicami te rog cum fac cu asta ?trebuie compilat sau cum ?ca sa inteleg si eu ...pus in .sma si facut amxx ?sau cum ?ca din cate stiu el este module ..si eu am server de linux..deci ar trebui sa il fac ceva de genu screenfade_inc_amxx_i386.so ?nu ?
imi poti explica tu te rog frumos ?
si multumesc ca mi-ai facut rost de el

Nu.Faci un fisier numit screenfade_util.inc pe care il pui in scripting/includes.Acest fisier este pentru compilarea unui plugin.

EDIT: Poti sa-mi dai si mie modul?A fost publicat pe forumul AMXX dar l-au sters.