MSG_TOO_LAZ [Eroare]

[mAke.]

Deci am un server de DR non-stop,pe linux si din 2 in 2 runde imi da acest mesaj

Code: Select all

[Deathrun] ML_NOTFOUND: MSG_TOO_LAZ

si nu stiu ce sa fac..sper sa ma ajutati voi..

Multumesc !!

[eXtAsY#o_O]

1. Foloseste ultima versiune de deathrunmanager. (Iti dau eu .sma-ul . Tu il compilezi. )

DeathrunManager v2.5 | Afiseaza codul

/***
 * Link to the plugin
 *
 *	http://forums.alliedmods.net/showthread.php?t=78197
 */

#include <amxmodx>
#include <engine>
#include <cstrike>
#include <fun>
#include <fakemeta>
#include <hamsandwich>

#pragma semicolon 1

// Plugin Version
#define VERSION	"2.5"

// Bot name
#define BOT_NAME "DRM Fake Player"

// Global Variables
new bool:g_bHauntedHouse, bool:g_bGamerFun, bool:g_bRandromized, bool:g_bStarting, bool:g_bFirstRound;
new g_iSemiClip[33], g_sv_restart, g_mp_autoteambalance, g_mp_limitteams, bool:g_isEnabled, g_HudSync, g_HudSync2;
new g_GameName, g_Toggle, g_SprayB, g_RadioB, g_Semiclip, g_GiveUsp, g_RemoveBZ, g_HideHud, g_BlockMoney, g_LifeSystem;
new g_iMaxplayers, g_iMsgHideWeapon, g_iMsgCrosshair, g_iMsgMoney, g_Lifes[33];
new g_iMsgTeamInfo, g_iMsgSayText, bool:gUserConnected[33], g_KillB;
new g_iLastTerr, g_szGameName[ 32 ], g_iFakeplayer;

// Macros
#if cellbits == 32
	#define OFFSET_BZ 235
#else
	#define OFFSET_BZ 268
#endif

// Colorchat
enum Color {
	NORMAL = 1,
	GREEN,
	RED,
	BLUE
};

new TeamName[][] = {
	"",
	"TERRORIST",
	"CT",
	"SPECTATOR"
};

// =======================================================================================

public plugin_init() {
	register_plugin( "Deathrun Manager", VERSION, "xPaw" );
	
	g_Toggle     = register_cvar( "deathrun_toggle",     "1" );
	g_SprayB     = register_cvar( "deathrun_spray",      "1" );
	g_RadioB     = register_cvar( "deathrun_radio",      "1" );
	g_KillB      = register_cvar( "deathrun_blockkill",  "1" );
	g_Semiclip   = register_cvar( "deathrun_semiclip",   "1" );
	g_GiveUsp    = register_cvar( "deathrun_giveusp",    "1" );
	g_RemoveBZ   = register_cvar( "deathrun_removebz",   "1" );
	g_HideHud    = register_cvar( "deathrun_hidehud",    "1" );
	g_BlockMoney = register_cvar( "deathrun_blockmoney", "1" );
	g_LifeSystem = register_cvar( "deathrun_lifesystem", "1" );
	g_GameName   = register_cvar( "deathrun_gamename",   "1" );
	
	// Lets get map name...
	new szMapName[ 64 ];
	get_mapname( szMapName, 63 );
	
	if( contain( szMapName, "deathrun_" ) != -1 ) {
		set_pcvar_num( g_Toggle, 1 );
		
		if( contain( szMapName, "hauntedhouse" ) != -1 )
			g_bHauntedHouse = true;
		else {
			g_bHauntedHouse = false;
			
			if( equal( szMapName, "deathrun_gamerfun" ) )
				g_bGamerFun = true;
			else
				g_bGamerFun = false;
		}
	} else
		set_pcvar_num( g_Toggle, 0 );
	
	format( g_szGameName, 31, "Deathrun v%s", VERSION);
	
	g_sv_restart         = get_cvar_pointer( "sv_restart" );
	g_mp_autoteambalance = get_cvar_pointer( "mp_autoteambalance" );
	g_mp_limitteams      = get_cvar_pointer( "mp_limitteams" );
	
	register_cvar("deathrun_version",	VERSION, FCVAR_SERVER|FCVAR_SPONLY);
	set_cvar_string("deathrun_version",	VERSION);
	
	// Registering Language file
	register_dictionary( "deathrun.txt" );
	
	// Logging Events
	register_logevent( "eStartRound", 2, "1=Round_Start" );
	register_logevent( "eRandromize", 2, "1=Round_End" );
	register_event( "SendAudio", "eTerrWin",    "a",  "2&%!MRAD_terwin" );
	register_event( "TextMsg",	 "eRandromize", "a",  "2&#Game_w" );
	register_event( "DeathMsg",	 "eDeath",      "a");
	register_event( "Money",	 "eMoney",      "b" );
	register_event( "ResetHUD",	 "eResetHUD",   "be" );
	
	g_bFirstRound    = true;
	g_iMaxplayers    = get_maxplayers();
	g_iMsgHideWeapon = get_user_msgid( "HideWeapon" );
	g_iMsgCrosshair  = get_user_msgid( "Crosshair" );
	g_iMsgMoney      = get_user_msgid( "Money" );
	g_iMsgSayText    = get_user_msgid( "SayText" );
	g_iMsgTeamInfo   = get_user_msgid( "TeamInfo" );
	
	g_HudSync        = CreateHudSyncObj();
	g_HudSync2       = CreateHudSyncObj();
	
	if( get_pcvar_num(g_Toggle) ) {
		// Forwards
		RegisterHam( Ham_Spawn, "player",        "FwdHamPlayerSpawnPost", 1 );
		register_forward( FM_ClientKill,         "FwdClientKill" );
		register_impulse( 201,                   "FwdImpulse_201" );
		
		if( get_pcvar_num( g_GameName ) )
			register_forward( FM_GetGameDescription, "FwdGameDesc" );
		
		register_clcmd("say /lifes", "cmdShowlifes");
		register_clcmd("say /lives", "cmdShowlifes");
		
		// Terrorist Check
		set_task(15.0, "eTerrorCheck", _,_,_, "b");
		
		// Lets make restart after 20 seconds from map start.
		set_task(20.0, "fnRestart");
		
		if( get_pcvar_num(g_RemoveBZ) ) {
			register_message( get_user_msgid("StatusIcon"), "MsgStatusIcon" ); // BuyZone Icon
			
			// Remove buyzone on map
			remove_entity_name( "info_map_parameters" );
			remove_entity_name( "func_buyzone" );
			
			// Create own entity to block buying
			new iEntity = create_entity( "info_map_parameters" );
			set_kvd( 0, KV_ClassName, "info_map_parameters" );
			set_kvd( 0, KV_KeyName, "buying" );
			set_kvd( 0, KV_Value, "3" );
			set_kvd( 0, KV_fHandled, 0 );
			
			dllfunc( DLLFunc_KeyValue, iEntity, 0 );
			dllfunc( DLLFunc_Spawn, iEntity );
		}
		
		if( get_pcvar_num(g_Semiclip) ) {
			register_forward( FM_StartFrame,	"FwdStartFrame", 0 );
			register_forward( FM_AddToFullPack,	"FwdFullPack",   1 );
		}
		
		g_isEnabled = true;
		log_amx("Deathrun Manager by xPaw v%s is ON.", VERSION);
		
		set_task( 5.0, "UpdateBot" );
	} else
		g_isEnabled = false;
}

// FAKEPLAYER
///////////////////////////////////////////
public UpdateBot( ) {
	new id = find_player( "i" );
	
	if( !id ) {
		id = engfunc( EngFunc_CreateFakeClient, BOT_NAME );
		if( pev_valid( id ) ) {
			engfunc( EngFunc_FreeEntPrivateData, id );
			dllfunc( MetaFunc_CallGameEntity, "player", id );
			set_user_info( id, "rate", "3500" );
			set_user_info( id, "cl_updaterate", "25" );
			set_user_info( id, "cl_lw", "1" );
			set_user_info( id, "cl_lc", "1" );
			set_user_info( id, "cl_dlmax", "128" );
			set_user_info( id, "cl_righthand", "1" );
			set_user_info( id, "_vgui_menus", "0" );
			set_user_info( id, "_ah", "0" );
			set_user_info( id, "dm", "0" );
			set_user_info( id, "tracker", "0" );
			set_user_info( id, "friends", "0" );
			set_user_info( id, "*bot", "1" );
			set_pev( id, pev_flags, pev( id, pev_flags ) | FL_FAKECLIENT );
			set_pev( id, pev_colormap, id );
			
			new szMsg[ 128 ];
			dllfunc( DLLFunc_ClientConnect, id, BOT_NAME, "127.0.0.1", szMsg );
			dllfunc( DLLFunc_ClientPutInServer, id );
			
			cs_set_user_team( id, CS_TEAM_T );
			ExecuteHamB( Ham_CS_RoundRespawn, id );
			
			set_pev( id, pev_effects, pev( id, pev_effects ) | EF_NODRAW );
			set_pev( id, pev_solid, SOLID_NOT );
			dllfunc( DLLFunc_Think, id );
			
			g_iFakeplayer = id;
		}
	}
}

// NEW TERRORIST
///////////////////////////////////////////
public eRandromize() {
	if( !g_isEnabled || g_bFirstRound || g_bRandromized )
		return PLUGIN_CONTINUE;
	
	g_bRandromized = true;
	
	new i, iPlayers[ 32 ], iNum, iPlayer;
	get_players( iPlayers, iNum, "c" );
	
	if( iNum <= 1 )
		return PLUGIN_CONTINUE;
	
	for( i = 0; i < iNum; i++ ) {
		iPlayer = iPlayers[ i ];
		
		if( cs_get_user_team( iPlayer ) == CS_TEAM_T )
			cs_set_user_team( iPlayer, CS_TEAM_CT );
	}
	
	new iRandomPlayer, CsTeams:iTeam;
	
	while( ( iRandomPlayer = iPlayers[ random_num( 0, iNum - 1 ) ] ) == g_iLastTerr ) { }
	
	g_iLastTerr = iRandomPlayer;
	
	iTeam = cs_get_user_team( iRandomPlayer );
	
	if( iTeam == CS_TEAM_T || iTeam == CS_TEAM_CT ) {
		cs_set_user_team(iRandomPlayer, CS_TEAM_T);
		
		new szName[32];
		get_user_name(iRandomPlayer, szName, 31);
		
		for( i = 0; i < iNum; i++ )
			ColorChat(iPlayers[ i ], RED, "[Deathrun]^4 %L", iPlayers[ i ], "DR_NOW_TERR", szName);
	} else {
		g_bRandromized = false;
		eRandromize();
	}
	
	return PLUGIN_CONTINUE;
}

// NEW ROUND
///////////////////////////////////////////
public eStartRound() {
	if( !g_isEnabled )
		return PLUGIN_CONTINUE;
	
	g_bRandromized	= false;
	g_bStarting	= false;
	
	new i, iPlayers[ 32 ], iNum, iRealPlayers, CsTeams:iTeam;
	get_players( iPlayers, iNum, "c" );
	
	if( iNum <= 1 )
		return PLUGIN_CONTINUE;
	
	for( i = 0; i < iNum; i++ ) {
		iTeam = cs_get_user_team( iPlayers[ i ] );
		
		if( iTeam == CS_TEAM_T || iTeam == CS_TEAM_CT )
			iRealPlayers++;
	}
	
	if( iRealPlayers <= 1 ) {
		set_hudmessage(0, 128, 0, -1.0, 0.1, 0, 4.0, 4.0, 0.5, 0.5, 4);
		
		for( i = 0; i < iNum; i++ )
			ShowSyncHudMsg(iPlayers[ i ], g_HudSync, "%L", iPlayers[ i ], "DR_NOT_ENOUGH" );
		
		return PLUGIN_CONTINUE;
	}
	
	set_pcvar_num(g_mp_autoteambalance, 0);
	set_pcvar_num(g_mp_limitteams, 0);
	
	if( g_bFirstRound ) {
		set_hudmessage(0, 128, 0, -1.0, 0.1, 0, 4.0, 4.0, 0.5, 0.5, 4);
		
		for( i = 0; i < iNum; i++ ) {
			ShowSyncHudMsg(iPlayers[ i ], g_HudSync, "%L", iPlayers[ i ], "DR_STARTING");
			
			ColorChat(iPlayers[ i ], RED, "[Deathrun]^1 %L", iPlayers[ i ], "DR_STARTING_CC");
		}
		
		set_task(9.0, "fnRestart");
		g_bStarting = true;
		g_bFirstRound = false;
	}
	
	return PLUGIN_CONTINUE;
}

// CHECK TERRORIST
///////////////////////////////////////////
public eTerrorCheck() {
	if( !g_isEnabled || g_bFirstRound || g_bStarting )
		return PLUGIN_CONTINUE;
	
	new i, iPlayers[ 32 ], iTerrors, iNum, iRealPlayers, CsTeams:iTeam;
	get_players( iPlayers, iNum, "c" );
	
	if( iNum <= 1 )
		return PLUGIN_CONTINUE;
	
	for( i = 0; i < iNum; i++ ) {
		iTeam = cs_get_user_team( iPlayers[ i ] );
		
		if( iTeam == CS_TEAM_T )
			iTerrors++;
		
		if( iTeam == CS_TEAM_T || iTeam == CS_TEAM_CT )
			iRealPlayers++;
	}
	
	if( iRealPlayers <= 1 ) {
		set_hudmessage(0, 128, 0, -1.0, 0.1, 0, 4.0, 4.0, 0.5, 0.5, 4);
		
		for( i = 0; i < iNum; i++ )
			ShowSyncHudMsg(iPlayers[ i ], g_HudSync, "%L", iPlayers[ i ], "DR_NOT_ENOUGH" );
		
		return PLUGIN_CONTINUE;
	}
	
	if( iTerrors == 0 ) {
		for( i = 0; i < iNum; i++ ) {
			ColorChat(iPlayers[ i ], RED, "[Deathrun]^1 %L", iPlayers[ i ], "DR_NO_DETECT");
			
			if( is_user_alive( iPlayers[ i ] ) && cs_get_user_team( iPlayers[ i ] ) == CS_TEAM_CT )
				user_silentkill( iPlayers[ i ] );
		}
		
		set_task( 0.5, "eRandromize" );
	}
	
	return PLUGIN_CONTINUE;
}

// LIFE SYSTEM
///////////////////////////////////////////
public eTerrWin() {
	if( !g_isEnabled || g_bFirstRound )
		return PLUGIN_CONTINUE;
	
	new iPlayers[ 32 ], iNum, iPlayer;
	get_players( iPlayers, iNum, "c" );
	
	if( iNum <= 1 )
		return PLUGIN_CONTINUE;
	
	new iLifeCvar = get_pcvar_num( g_LifeSystem );
	
	for( new i = 0; i < iNum; i++ ) {
		iPlayer = iPlayers[ i ];
		
		if( cs_get_user_team( iPlayer ) == CS_TEAM_T ) {
			set_user_frags( iPlayer, get_user_frags( iPlayer ) + 3 );
			
			if( iLifeCvar == 2 )
				g_Lifes[ iPlayer ]++;
		}
	}
	
	return PLUGIN_CONTINUE;
}

public eDeath() {
	if( !g_isEnabled || get_pcvar_num(g_LifeSystem) == 0 )
		return PLUGIN_CONTINUE;
	
	new iKiller = read_data( 1 );
	new iVictim = read_data( 2 );
	new iTeam = get_user_team( iVictim );
	
	if( iKiller != iVictim && get_user_team(iKiller) != iTeam )
		g_Lifes[iKiller]++;
	
	if( iTeam == 1 && is_user_alive( g_iFakeplayer ) )
		fakedamage( g_iFakeplayer, "worldspawn", 100.0, DMG_GENERIC );
	
	if( cs_get_user_team(iVictim) == CS_TEAM_CT && g_Lifes[iVictim] > 0 ) {
		new iCTcount;
		for( new i = 1; i <= g_iMaxplayers; i++ ) {
			if( is_user_alive(i) && cs_get_user_team(i) == CS_TEAM_CT )
				iCTcount++;
		}
		
		if( iCTcount > 1 ) {
			set_task(3.2, "fnRevivePlayer", iVictim);
			
			ColorChat(iVictim, RED, "[Deathrun]^1 %L", iVictim, "DR_LIFE_RESPAWN" );
		}
		/*else
			ColorChat(iVictim, RED, "[Deathrun]^1 %L", iVictim, "DR_LIFE_CANT" );*/
	}
	
	return PLUGIN_CONTINUE;
}

public fnRevivePlayer( id ) {
	if( gUserConnected[id] ) {
		if( cs_get_user_team( id ) == CS_TEAM_CT ) {
			new iCTcount;
			for( new i = 1; i <= g_iMaxplayers; i++ )
				if( is_user_alive( i ) && cs_get_user_team( i ) == CS_TEAM_CT )
					iCTcount++;
			
			if( iCTcount > 1 ) {
				ExecuteHamB(Ham_CS_RoundRespawn, id);
				
				g_Lifes[id]--;
			}
		}
	}
}

public cmdShowlifes( id ) {
	if( get_pcvar_num(g_LifeSystem) == 0 ) {
		ColorChat(id, RED, "[Deathrun]^1 %L", id, "DR_LIFE_DISABLE" );
		return PLUGIN_HANDLED;
	}
	
	if( g_Lifes[id] > 0 )
		ColorChat(id, RED, "[Deathrun]^1 %L", id, "DR_LIFE_CC_COUNT", g_Lifes[id] );
	else
		ColorChat(id, RED, "[Deathrun]^1 %L", id, "DR_LIFE_CC_NO" );
	
	return PLUGIN_HANDLED;
}

public Showlifes( id ) {
	set_hudmessage(0, 128, 0, 0.04, 0.71, 0, 2.5, 2.5, 0.5, 0.5, 3);
	
	if( g_Lifes[id] > 0 )
		ShowSyncHudMsg(id, g_HudSync2, "%L", id, "DR_LIFE_COUNT", g_Lifes[id]);
	else
		ShowSyncHudMsg(id, g_HudSync2, "%L", id, "DR_LIFE_NO");
}

// EVENTS
///////////////////////////////////////////
public eResetHUD( id ) {
	if( g_isEnabled && get_pcvar_num(g_HideHud) && !is_user_bot( id ) ) {
		message_begin( MSG_ONE_UNRELIABLE, g_iMsgHideWeapon, _, id );
		write_byte( ( 1<<4 | 1<<5 ) );
		message_end();
		
		message_begin( MSG_ONE_UNRELIABLE, g_iMsgCrosshair, _, id );
		write_byte( 0 );
		message_end();
	}
}

public eMoney( id ) {
	if( g_isEnabled && get_pcvar_num( g_BlockMoney ) ) {
		set_pdata_int( id, 115, 0 );
		
		message_begin( MSG_ONE_UNRELIABLE, g_iMsgMoney, _, id );
		write_long ( 0 );
		write_byte ( 1 );
		message_end( );
	}
}

public client_putinserver( id )
	gUserConnected[ id ] = true;

public client_disconnect( id ) {
	gUserConnected[ id ] = false;
	eTerrorCheck();
	
	if( g_iFakeplayer == id ) {
		set_task( 1.5, "UpdateBot" );
		
		g_iFakeplayer = 0;
	}
}

// SEMICLIP by danielkza
///////////////////////////////////////////
public FwdFullPack( es, e, ent, host, flags, player, pSet ) {
	if( !g_isEnabled )
		return FMRES_IGNORED;
	
	if( player && g_iSemiClip[ent] && g_iSemiClip[host] ) {
		set_es( es, ES_Solid, SOLID_NOT );
		set_es( es, ES_RenderMode, kRenderTransAlpha );
		set_es( es, ES_RenderAmt, 85 );
	}
	
	return FMRES_IGNORED;
}

public FwdStartFrame( ) {
	if( !g_isEnabled )
		return FMRES_IGNORED;
	
	static iPlayers[32], iNum, iPlayer, iPlayer2;
	get_players( iPlayers, iNum, "c" );
	
	arrayset( g_iSemiClip, 0, 32 );
	
	new iTeams[33] = {-1, ...};
	for( new i = 0; i < iNum; i++ ) {
		iPlayer = iPlayers;
		
		if( !is_user_alive(iPlayer) )
			continue;
		
		for( new j = 0; j < iNum; j++ ) {
			iPlayer2 = iPlayers[j];
			
			if(iPlayer == iPlayer2 || !is_user_alive(iPlayer2))
				continue;
			
			static Float:vOrigin1[3], Float:vOrigin2[3];
			pev(iPlayer, pev_origin, vOrigin1);
			pev(iPlayer2, pev_origin, vOrigin2);
			
			if( vector_distance( vOrigin1, vOrigin2 ) < 96 ) {
				if( iTeams[iPlayer] == -1 )
					iTeams[iPlayer] = get_user_team(iPlayer);
				if( iTeams[iPlayer2] == -1 )
					iTeams[iPlayer2] = get_user_team(iPlayer2);
				
				if( iTeams[iPlayer] == 2 && iTeams[iPlayer2] == 2 ) {
					g_iSemiClip[iPlayer]	= true;
					g_iSemiClip[iPlayer2]	= true;
				}
			}
		}
	}
	
	for( new i = 0; i < iNum; i++ ) {
		iPlayer = iPlayers;
		
		if( is_user_alive( iPlayer ) )
			set_pev(iPlayer, pev_solid, g_iSemiClip[iPlayer] ? SOLID_NOT : SOLID_SLIDEBOX);
	}
	
	return FMRES_IGNORED;
}

// FORWARDS
///////////////////////////////////////////
public FwdHamPlayerSpawnPost( id ) {
	if( !g_isEnabled || !is_user_alive( id ) )
		return HAM_IGNORED;
	
	if( get_pcvar_num(g_RadioB) ) // thanks to ConnorMcLeod for this good way :)
		set_pdata_int( id, 192, 0 );
	
	if( g_iFakeplayer == id ) {
		set_pev( id, pev_frags, -1000.0 );
		cs_set_user_deaths( id, -1000 );
		
		set_pev( id, pev_effects, pev(id, pev_effects) | EF_NODRAW );
		set_pev( id, pev_solid, SOLID_NOT );
		entity_set_origin(id, Float:{ 999999.0, 999999.0, 999999.0 } );
		dllfunc( DLLFunc_Think, id );
	} else {
		new CsTeams:iTeam = cs_get_user_team( id );
		
		// An small delay for message
		if( get_pcvar_num(g_LifeSystem) != 0 && iTeam == CS_TEAM_CT )
			set_task(0.8, "Showlifes", id);
		
		strip_user_weapons( id );
		give_item( id, "weapon_knife" );
		
		if( g_bGamerFun && iTeam == CS_TEAM_CT )
			give_item( id, "weapon_smokegrenade" );
		
		if( get_pcvar_num(g_GiveUsp) && iTeam == CS_TEAM_CT && !g_bHauntedHouse )
			set_task(1.0, "GiveUsp", id);
	}
	
	return HAM_IGNORED;
}

public GiveUsp( id ) {
	if( is_user_alive( id ) ) {	// who knows, maybe he died in 1second :D
		give_item( id, "weapon_usp" );
		cs_set_user_bpammo( id, CSW_USP, 100 );
	}
}

public FwdGameDesc() {
	forward_return( FMV_STRING, g_szGameName );
	
	return FMRES_SUPERCEDE;
}

public FwdClientKill( id ) {
	if( !g_isEnabled || !is_user_alive(id) )
		return FMRES_IGNORED;
	
	if( get_pcvar_num( g_KillB ) || cs_get_user_team( id ) == CS_TEAM_T ) {
		client_print( id, print_center, "%L", id, "DR_BLOCK_KILL" );
		client_print( id, print_console, "%L", id, "DR_BLOCK_KILL" );
	
		return FMRES_SUPERCEDE;
	}
	
	return FMRES_IGNORED;
}

public FwdImpulse_201( id, uc_handle, seed ) {	
	if( g_isEnabled && get_pcvar_num(g_SprayB) ) {
		if( is_user_alive( id ) ) {
			client_print(id, print_center, "%L", id, "DR_BLOCK_SPRAY");
			return PLUGIN_HANDLED_MAIN;
		}
	}
	
	return PLUGIN_CONTINUE;
}

public MsgStatusIcon( msg_id, msg_dest, id ) {
	new szIcon[8];
	get_msg_arg_string(2, szIcon, 7);
	
	if( equal(szIcon, "buyzone") ) {
		set_pdata_int( id, OFFSET_BZ, get_pdata_int( id, OFFSET_BZ, 5 ) & ~( 1 << 0 ), 5 );
		
		return PLUGIN_HANDLED;
	}
	
	return PLUGIN_CONTINUE;
}

public fnRestart( )
	set_pcvar_num( g_sv_restart, 1 );

// COLORCHAT
/////////////////////////////////////////////
ColorChat( id, Color:type, const szMessage[], {Float,Sql,Result,_}:... ) {
	if( !get_playersnum() ) return;
	
	new message[256];
	
	switch( type ) {
		case NORMAL: message[0] = 0x01;
		case GREEN: message[0] = 0x04;
		default: message[0] = 0x03;
	}
	
	vformat(message[1], 251, szMessage, 4);
	
	message[192] = '^0';
	
	replace_all( message, 191, "\YEL", "^1" );
	replace_all( message, 191, "\GRN", "^4" );
	replace_all( message, 191, "\TEM", "^3" );
	
	new iTeam, ColorChange, index, MSG_Type;
	
	if( id ) {
		MSG_Type = MSG_ONE_UNRELIABLE;
		index = id;
	} else {
		index = CC_FindPlayer();
		MSG_Type = MSG_BROADCAST;
	}
	
	iTeam = get_user_team( index );
	ColorChange = CC_ColorSelection(index, MSG_Type, type);

	CC_ShowColorMessage(index, MSG_Type, message);
	
	if( ColorChange )
		CC_Team_Info(index, MSG_Type, TeamName[iTeam]);
}

CC_ShowColorMessage( id, type, message[] ) {
	message_begin( type, g_iMsgSayText, _, id );
	write_byte( id );	
	write_string( message );
	message_end();	
}

CC_Team_Info( id, type, team[] ) {
	message_begin( type, g_iMsgTeamInfo, _, id );
	write_byte( id );
	write_string( team );
	message_end( );
	
	return 1;
}

CC_ColorSelection( index, type, Color:Type ) {
	switch( Type ) {
		case RED: return CC_Team_Info(index, type, TeamName[1]);
		case BLUE: return CC_Team_Info(index, type, TeamName[2]);
	}
	
	return 0;
}

CC_FindPlayer() {
	for( new i = 1; i <= g_iMaxplayers; i++ )
		if( gUserConnected )
			return i;
	
	return -1;
}

2. Intra in amxmodx/data/lang/deathrun.txt si sterge tot din fisier. Apoi da copy-paste la :

deathrun.txt | Afiseaza codul

[en]
DR_NOW_TERR = %s\YEL is now the terrorist.
DR_STARTING = Starting in 10 seconds.
DR_NO_DETECT = No terrorist detected, restarting now.
DR_NOT_ENOUGH = Not enough players to start Deathrun!
DR_STARTING_CC = Starting in\GRN 10\YEL seconds.

DR_LIFE_CC_COUNT = You have\TEM %i\YEL lifes.
DR_LIFE_CC_NO = You dont have lifes, kill enemy to get one!
DR_LIFE_COUNT = You have %i lifes.
DR_LIFE_NO = You dont have lifes^nKill enemy to get one!
DR_LIFE_DISABLE = Life system is disabled.
DR_LIFE_RESPAWN = You will be respawned in\TEM 3\YEL seconds!
DR_LIFE_CANT = You could be respawned but all CT's are dead now!

DR_BLOCK_SPRAY = Spray's not allowed on this server!
DR_BLOCK_KILL = You can't kill yourself!

[ru]
DR_NOW_TERR = %s\YEL teper' terrorist!
DR_STARTING = Nachinaem cherez 10 sekund.
DR_NO_DETECT = Terrorist nenajden, restart.
DR_NOT_ENOUGH = Nedostatochno igrokov chtoby nachat' igru!
DR_STARTING_CC = Nachinaem cherez\GRN 10\YEL sekund.

DR_LIFE_CC_COUNT = U tebja\TEM %i\YEL dopolnitel'nyh zhiznej.
DR_LIFE_CC_NO = U tebja net dopolnitel'nyh zhiznej, ubej vraga chtoby poluchit' odnu!
DR_LIFE_COUNT = U tebja %i dopolnitel'nyh zhiznej.
DR_LIFE_NO = U tebja net dopolnitel'nyh zhiznej^nUbej vraga chtoby poluchit' odnu!
DR_LIFE_DISABLE = Sistema dopolnitel'nyh zhiznej vykljuchena.
DR_LIFE_RESPAWN = Ty budesh respavnut cherez\TEM 3\YEL sekundy!
DR_LIFE_CANT = Ty mogby respavnutsja no ne ostalos' drugih zhivih CT!

DR_BLOCK_SPRAY = Pol'zovatsja sprejem na jetom servere nel'zja!
DR_BLOCK_KILL = Ty nemozhesh ubit' sebja!

[de]
DR_NOW_TERR = %s\YEL ist jetzt der Terrorist.
DR_STARTING = Es startet in 10 Sekunden.
DR_NO_DETECT = Keine Terroristen gefunden, neustart beginnt.
DR_NOT_ENOUGH = Nicht genuegent Spieler vorhanden um Deathrun zu Starten
DR_STARTING_CC = Es startet in\GRN 10\YEL Sekunden.

DR_LIFE_CC_COUNT = Sie haben\TEM %i\YEL Leben.
DR_LIFE_CC_NO = Sie haben kein Leben, Toede die feinde um ein Leben zu bekommen!
DR_LIFE_COUNT = Sie haben %i lifes.
DR_LIFE_NO = Sie haben kein Leben, Toede die feinde um ein Leben zu bekommen!
DR_LIFE_DISABLE = Life system ist Deaktiviert.
DR_LIFE_RESPAWN = Sie werden in \TEM 3\YEL Sekunden wiederbelebt!
DR_LIFE_CANT = Sie koennen nicht wiederbelebt werden da alle CTs Tod sind!

DR_BLOCK_SPRAY = Auf diesem Server ist Sprayen verboten!
DR_BLOCK_KILL = Sie koennen sich nicht selbst toeden!

[es]
DR_NOW_TERR = %s\YEL es ahora el terrorista.
DR_STARTING = Empezando en 10 segundos.
DR_NO_DETECT = No se ha detectado al terrorista, reiniciando.
DR_NOT_ENOUGH = No hay suficientes jugadores para empezar Deathrun!
DR_STARTING_CC = Empezando en\GRN 10\YEL segundos.

DR_LIFE_CC_COUNT = Tu tienes\TEM %i\YEL vidas.
DR_LIFE_CC_NO = No tienes vidas, **** a los enemigos para conseguirlas!
DR_LIFE_COUNT = Tu tienes %i vidas.
DR_LIFE_NO = Tu no tienes vidas^nMata a los enemigos para conseguirlas!
DR_LIFE_DISABLE = Sistema de vidas desactivado.
DR_LIFE_RESPAWN = Tu seras revivido en\TEM 3\YEL segundos!
DR_LIFE_CANT = Tu deberias ser revivido ahora, pero todos los CTs estan muertos!

DR_BLOCK_SPRAY = Los spray's no estan permitidos en este servidor!
DR_BLOCK_KILL = No puedes suicidarte!

[ro]
DR_NOW_TERR = %s\YEL este acum terorist.
DR_STARTING = Incepem in 10 secunde.
DR_NO_DETECT = Nu exista niciun terorist, se da restart.
DR_NOT_ENOUGH = Nu sunt destui jucatori pentru a incepe Deathrun!
DR_STARTING_CC = Incepem in\GRN 10\YEL secunde.

DR_LIFE_CC_COUNT = Ai\TEM %i\YEL vieti.
DR_LIFE_CC_NO = Nu ai nicio viata, ucide un inamic pentru a castiga una!
DR_LIFE_COUNT = Ai %i vieti.
DR_LIFE_NO = Nu ai vieti^nUcide un inamic pentru a castiga una!
DR_LIFE_DISABLE = Sistemul de vieti este oprit.
DR_LIFE_RESPAWN = Vei reinvia in\TEM 3\YEL secunde!
DR_LIFE_CANT = Puteai sa fi reinviat dar, toti CT sunt morti!

DR_BLOCK_SPRAY = Sunt interzise tatuajele pe acest server!
DR_BLOCK_KILL = Nu te poti sinucide!

[sv]
DR_NOW_TERR = %s\YEL 'a'r nu terroristen.
DR_STARTING = B'o'rjar om 10 sekunder.
DR_NO_DETECT = Ingen terrorist hittad, startar om nu.
DR_NOT_ENOUGH = Inte tillr'a'ckligt med spelare f'o'r att starta Deathrun.
DR_STARTING_CC = B'o'rjar om\GRN 10\YEL sekunder.

DR_LIFE_CC_COUNT = Du har\TEM %i\YEL liv.
DR_LIFE_CC_NO = Du har inga liv, d'o'da en fiende f'o'r att fa ett.
DR_LIFE_COUNT = Du har %i liv.
DR_LIFE_NO = Du har inga liv^nD'o'da en fiende f'o'r att fa ett!
DR_LIFE_DISABLE = Liv funktionen 'a'r av.
DR_LIFE_RESPAWN = Du kommer att bli aterupplivad om\TEM 3\YEL sekunder!
DR_LIFE_CANT = Du kunde bli aterupplivad men alla CT's 'a'r d'o'da.

DR_BLOCK_SPRAY = Sprej 'a'r inte tillaten pa den h'a'r servern.
DR_BLOCK_KILL = Du kan inte d'o'da dig sj'a'lv.

[bp]
DR_NOW_TERR = %s\YEL e agora o terrorista.
DR_STARTING = A comecar em 10 segundos.
DR_NO_DETECT = Nenhum terrorista detectado, a reiniciar.
DR_NOT_ENOUGH = Nao ha jogadores suficientes para comecar a Deathrun!
DR_STARTING_CC = A comecar em\GRN 10\YEL segundos.

DR_LIFE_CC_COUNT = Tens\TEM %i\YEL vidas.
DR_LIFE_CC_NO = Nao tens vidas, **** os teus inimigos para as obteres!
DR_LIFE_COUNT = Tens %i vidas.
DR_LIFE_NO = Nao tens vidas^**** os teus inimigos para as obteres!
DR_LIFE_DISABLE = O sistema de vidas esta desactivado.
DR_LIFE_RESPAWN = Vais renascer em \TEM 3\YEL segundos!
DR_LIFE_CANT = Tu poderias renascer mas, todos os CT's estao mortos!

DR_BLOCK_SPRAY = Nao sao permitidos sprays neste servidor!
DR_BLOCK_KILL = Nao te podes matar!

[nl]
DR_NOW_TERR = %s\YEL is nu een terrorist.
DR_STARTING = Het spel zal starten in 10 seconden.
DR_NO_DETECT = Geen terroristen gedetecteerd, spel herstart nu.
DR_NOT_ENOUGH = Niet genoeg spelers om DeathRun te spelen!
DR_STARTING_CC = Het spel start in\GRN 10\YEL seconden.

DR_LIFE_CC_COUNT = Je hebt\TEM %i\YEL levens.
DR_LIFE_CC_NO = Je hebt geen levens, vermoord tegenstanders om er te krijgen!
DR_LIFE_COUNT = Jij hebt %i levens.
DR_LIFE_NO = Je hebt geen levens^nVermoord spelers om er te krijgen!
DR_LIFE_DISABLE = Levens systeem is uitgeschakeld.
DR_LIFE_RESPAWN = Je zal terug tot leven komen in\TEM 3\YEL seconden!
DR_LIFE_CANT = Je zou jezelf kunnen tot leven wekken maar alle CTs zijn dood!

DR_BLOCK_SPRAY = Sprays zijn niet toegestaan in deze server!
DR_BLOCK_KILL = Je kan jezelf niet vermoorden!

[pl]
DR_NOW_TERR = %s\YEL zostal terrorysta.
DR_STARTING = Zaczynamy zabawe za 10 sekund.
DR_NO_DETECT = Brakuje terrorysty, wymagany restart.
DR_NOT_ENOUGH = Zbyt malo graczy! Zapros kolegow ;-)
DR_STARTING_CC = Zaczynamy zabawe za\GRN 10\YEL sekund.

DR_LIFE_CC_COUNT = You have\TEM %i\YEL lifes.
DR_LIFE_CC_NO = Nie posiadasz juz dodatkowych zyc, zabij kogos !
DR_LIFE_COUNT = Posiadasz %i zyc.
DR_LIFE_NO = Nie masz dodatkowych zyc^nZabij kogos aby je zyskac !
DR_LIFE_DISABLE = System zyc jest wylaczony.
DR_LIFE_RESPAWN = Odrodzisz sie w ciagu \TEM 3\YEL sekund!
DR_LIFE_CANT = Moglbys zostac odrodzony lecz wszyscy CT sa juz niezywi!

DR_BLOCK_SPRAY = Malowanie logajest wylaczone.
DR_BLOCK_KILL = Nie mozesz popelnic samobojstwa!

[lt]
DR_NOW_TERR = %s\YEL dabar teroristas.
DR_STARTING = Pradzia po 10 sekundziu.
DR_NO_DETECT = Nerastas teroristas, raundas restartuojamas.
DR_NOT_ENOUGH = Nepakanka zaideju, kad pradeti DeathRun!
DR_STARTING_CC = Pradzia po\GRN 10\YEL sekundziu.

DR_LIFE_CC_COUNT = Jus turite\TEM %i\YEL gyvybes.
DR_LIFE_CC_NO = Jus neturite gyvybiu, nusaukite priesa, kad gautumet viena!
DR_LIFE_COUNT = Jus turite %i gyvybe.
DR_LIFE_NO = Jus neturite gyvybiu^nNusaukite priesininka, kad gautumet viena!
DR_LIFE_DISABLE = Gyvybiu sistema isjungta..
DR_LIFE_RESPAWN = Jus prisikelsite po\TEM 3\YEL sekundziu!
DR_LIFE_CANT = Jus galite prisikelti, bet visi CT yra negyvi!

DR_BLOCK_SPRAY = Spray logo neleistini siame serveryje!
DR_BLOCK_KILL = Jus negalite uzmusti saves!

[sk]
DR_NOW_TERR = %s\YEL je teraz terorista.
DR_STARTING = Zaciname za 10 sekund.
DR_NO_DETECT = Ziadny terorista , restart.
DR_NOT_ENOUGH = Malo hracov pre zacatie Deathrunu!
DR_STARTING_CC = Zaciname za\GRN 10\YEL sekund.

DR_LIFE_CC_COUNT = Mas\TEM %i\YEL zivotov.
DR_LIFE_CC_NO = Nemas zivot, zabi nepriatela a dostan jeden!
DR_LIFE_COUNT = Mas %i zivotov.
DR_LIFE_NO = Nemas zivot^nzabi nepriatela a dostan jeden!
DR_LIFE_DISABLE = System so zivotmi je vypaty.
DR_LIFE_RESPAWN = Respawnes sa za\TEM 3\YEL sekund!
DR_LIFE_CANT = Mozes byt respawnuty , ale secky CT su kaput!

DR_BLOCK_SPRAY = Spreje nesu povolene!
DR_BLOCK_KILL = Nemozes seba zajebat!

[sr]
DR_NOW_TERR = %s\YEL je sada Terrorist.
DR_STARTING = Igra pocinje za 10 sekundi.
DR_NO_DETECT = Nema terorista, RESTART.
DR_NOT_ENOUGH = Nema dovoljno igraca za DeathRun.
DR_STARTING_CC = Startuje se za\GRN 10\YEL Sekundi !

DR_LIFE_CC_COUNT = Ti imas\TEM %i\YEL zivota..
DR_LIFE_CC_NO = Ti nemas zivota, ubi nekoga da uzmes jedan!
DR_LIFE_COUNT = Ti imas %i zivota.
DR_LIFE_NO = Ti nemas zivota^ potrebno ti je da ubijes nekoga da bi uzeo zivot.
DR_LIFE_DISABLE = Life sistem je iskljucen.
DR_LIFE_RESPAWN = Ti ces se oziveti za\TEM 3\YEL sekunde!
DR_LIFE_CANT = Mogao bi da se ozivis, ali CT team je mrtav.

DR_BLOCK_SPRAY = Sprej/Potpis nije dozvoljen na ovom serveru.
DR_BLOCK_KILL = Ti se ne mozes ubiti!

[bg]
DR_NOW_TERR = %s\YEL sega e terorista.
DR_STARTING = Igrata zapochva sled 10 sekundi.
DR_NO_DETECT = Nqma terorist, restartirane na igrata.
DR_NOT_ENOUGH = Nqma dostatachno igrachi, za da zapochne DeathRun!
DR_STARTING_CC = Igrata zapochva sled\GRN 10\YEL sekundi.
 
DR_LIFE_CC_COUNT = Imash\TEM %i\YEL jivota.
DR_LIFE_CC_NO = Nqmash jivoti, ubii vrag, za da poluchish edin!
DR_LIFE_COUNT = Imash %i jivota.
DR_LIFE_NO = Nqmash jivoti.^nUbii vrag, za da poluchish edin!
DR_LIFE_DISABLE = Sistemata s jivoti e izkliuchena.
DR_LIFE_RESPAWN = Shte badesh sajiven sled\TEM 3\YEL sekundi!
DR_LIFE_CANT = Mojesh da badesh sujiven, no vsichki teroristi sa martvi!
 
DR_BLOCK_SPRAY = Spreq ne e pozvolen v servera!
DR_BLOCK_KILL = Ne mojesh da se samoubiesh!

[fr]
DR_NOW_TERR = %s\YEL est transfere en terroriste.
DR_STARTING = Depart dans 10 seconds.
DR_NO_DETECT = Pas de terroriste detecte! Restart immediat.
DR_NOT_ENOUGH = Pas de joueur pour demmarrer la deathrun!
DR_STARTING_CC = Depart dans\GRN 10\YEL secondes.

DR_LIFE_CC_COUNT = Tu as\TEM %i\YEL vies.
DR_LIFE_CC_NO = Tu n'as pas de vie, Tues un ennemies pour en avoir une!
DR_LIFE_COUNT = Tu as %i vies.
DR_LIFE_NO = Tu n'as pas de vie,^nTues un ennemies pour en avoir une!
DR_LIFE_DISABLE = Le systeme de vie est actif.
DR_LIFE_RESPAWN = Tu revies dans\TEM 3\YEL secondes!
DR_LIFE_CANT = Tu ne peux revivre maintenant car tout les CT's sont morts!

DR_BLOCK_SPRAY = Les Tags sont interdits sur ce serveur!
DR_BLOCK_KILL = Tu ne peux pas te suicider!

Sper ca te-am ajutat >:D< !

[mAke.]

Am rezolvat dupa 30 min dupa post..
Ms Oricum :)

[eXtAsY#o_O]

Ok. totusi iti recomand acea versiune de drm.
Poti posta rezolvarea pentru unii mai :-nb(la plural) care o sa aiba aceasta problema?