[Cerere Plugin] Refill la o noua runda. [ Rezolvat ]

[dragonCSX]

Plugin Cerut: Refill la ammo la fiecare runda .
Descriere (adica ce face el mai exact): Sa dea refill la ammo , in fiecare runda gen tu ai utilizat din 90 de cartuse la ak si ai ramas cu 40 , la inceput de runda sa le ai inapoi pe 90 adica ca un refil
Serverul ruleaza (HLDS/ReHLDS): REHLDS
Versiune AMX Mod X: 1.8.2
Modul Serverului: CSGO Classic

[A k c 3 n 7]

Poate am timp mai tarziu sa ti l fac :blush:

[dragonCSX]

Poate am timp mai tarziu sa ti l fac :blush:

hai te rog eu frumix <3

[faKe91]

| Afiseaza codul

[code]#include <amxmodx>
#include <hamsandwich>
#include <fakemeta>

#define PLUGIN "Auto Reload & Refill Ammo"
#define VERSION "1.0"
#define AUTHOR "faKe"

// offsets
const XO_WEAPON = 4
const MAX_ITEM_TYPES = 6
const m_pNext = 42
const m_iId = 43
const m_iClip = 51

#define cs_get_weapon_id(%1)			get_pdata_int(%1, m_iId, XO_WEAPON)
#define cs_set_weapon_ammo(%1,%2)		set_pdata_int(%1, m_iClip, %2, XO_WEAPON)

stock const m_rgpPlayerItems_CBasePlayer[MAX_ITEM_TYPES] = {367, 368, ...}

stock const g_iMaxClip[CSW_P90 + 1] = { 
	-1, 13, -1, 10, 1, 7, 1, 30, 30, 1, 30, 20, 25, 30, 35, 25, 
	12, 20, 10, 30, 100, 8, 30, 30, 20, 2, 7, 30, 30, -1, 50
}

stock const g_iMaxBPAmmo[CSW_P90 + 1] = { 
	-1, 52, -1, 90, 1, 32, 1, 100, 90, 1, 120, 100, 100, 90, 90, 90,
	100, 120, 30, 120, 200, 32, 90, 120, 90, 2, 35, 90, 90, -1, 100
}

stock const g_szAmmoType[CSW_P90 + 1][] = {
	"","357sig","","762nato","HEGrenade","buckshot","C4","45acp","556nato","SmokeGrenade","9mm", 
	"57mm","45acp","556nato","556nato","556nato","45acp","9mm","338magnum","9mm","556natobox",
	"buckshot","556nato","9mm","762nato","Flashbang","50ae","556nato","762nato","","57mm"
}

public plugin_init()
{
	register_plugin(PLUGIN, VERSION, AUTHOR)
	
	RegisterHam(Ham_Spawn, "player", "PlayerSpawn_Post", .Post = true)
}

public PlayerSpawn_Post(id)
	set_task(0.1, "Player_Spawned", id)

public Player_Spawned(id)
{
	if(!is_user_alive(id))
		return

	ReloadWeapons(id)
}

ReloadWeapons(id)
{
	new iSlot, wEnt, iId
	for(iSlot = 1; iSlot<= 2; iSlot++)
	{
		wEnt = get_pdata_cbase(id, m_rgpPlayerItems_CBasePlayer[iSlot])
		while(wEnt > 0)
		{
			iId = cs_get_weapon_id(wEnt)
			cs_set_weapon_ammo(wEnt, g_iMaxClip[iId])

			ExecuteHamB(Ham_GiveAmmo, id, g_iMaxBPAmmo[iId], g_szAmmoType[iId], g_iMaxBPAmmo[iId])

			wEnt = get_pdata_cbase(wEnt, m_pNext, XO_WEAPON)
		}
	}
}[/code]

Insa daca tot folosesti ReHLDS instaleaza si ReGameDLL_CS. Aici a fost deja realizat exact ce vrei tu si nu va mai trebui sa instalezi pluginul
Cvarurile:
mp_auto_reload_weapons https://github.com/s1lentq/ReGameDLL_CS ... me.cfg#L82
mp_refill_bpammo_weapons https://github.com/s1lentq/ReGameDLL_CS ... me.cfg#L91

[dragonCSX]

Iti multumesc fake.
poti da topic closed.

[WHOAMI?]

Marcat ca "Rezolvat"

#Informativ.