eXtreamCS.com

Salut ! NU ştiu exact cum se cheamă pluginul , dar ştiu ce face :

când dau amx_maps îmi arată o listă cu hărţile instalate pe server

Îmi poate da şi mie un link pentru download acel plugin ? :D Mulţumesc . (sau măcar să-mi ziceţi cum se cheamă :-l)

Nu e nevoie neaparat de acel plugin. Lucrul acesta poti sa-l faci scriind tot in consola votemap 1 sa zicem, si iti arata toate hartile.

Mulţumesc de sugestie , dar adminii mei poate nu ştiu asta :D ce mă fac atunci ?

Pai ai 2 variante:

Ori scrii votemap cum ti-am zis, ori scrii "maps" mai scurt si mai usor, si ti le arata.

Din cate stiu.. daca scrii maps ti le arata pe cele care le ai tu instalate in PC.
Corectati`ma daca am gresit ^_^

| Afiseaza codul

[code=php]
/* Plugin generated by AMXX-Studio */

#include < amxmodx >
#include < amxmisc >

#define PLUGIN "Maps Shower"
#define VERSION "1.0"
#define AUTHOR "Ciprian"

new g_Maps[ 64 ][ 32 ];
new g_MapsFile[ ] = "maps.ini"
new i_MapsNumber;

public plugin_init ( ) {
    register_plugin ( PLUGIN, VERSION, AUTHOR );
    
    register_clcmd ( "amx_maps", "cmdShowMaps", ADMIN_KICK, "<nr. pagina> - arata toate hartile disponibile" );
}

public plugin_cfg ( ) {
    new s_ConfigsDir[ 64 ], s_File[ 64 ];
    get_configsdir ( s_ConfigsDir, charsmax ( s_ConfigsDir ) );
    
    formatex ( s_File, charsmax ( s_File ), "%s/%s", s_ConfigsDir, g_MapsFile );
    
    if ( ! file_exists ( s_File ) ) {
        server_print ( "[AMXX] Fisierul %s nu a fost gasit!", g_MapsFile );
        return PLUGIN_HANDLED;
    }
    
    new fp = fopen ( s_File, "rt" ); 
    i_MapsNumber = 0;
    
    while ( ! feof ( fp ) ) {
        new s_Buffer[ 32 ];
        fgets ( fp, s_Buffer, charsmax ( s_Buffer ) );
        
        if ( ! s_Buffer[ 0 ] || s_Buffer[ 0 ] == ';' || strlen ( s_Buffer )  < 5  ) 
            continue;
        
        copy ( g_Maps[ i_MapsNumber ], 31, s_Buffer );
        i_MapsNumber ++;
        
    }
    
    return PLUGIN_CONTINUE;
}

public cmdShowMaps ( id, level, cid ) {
    if ( ! cmd_access ( id, level, cid, 1 ) ) 
        return PLUGIN_HANDLED;
    
    new i_Start, i_Last;
    
    if ( read_argc ( ) > 1 ) {
        new s_Arg[ 16 ];
        read_argv ( 1, s_Arg, charsmax ( s_Arg ) );
        
        i_Start = min ( str_to_num ( s_Arg ), i_MapsNumber ) - 1;
    }
    else i_Start = 0;
    
    i_Last = min ( i_Start + 10, i_MapsNumber );
    
    console_print ( id, "----------------- Hartile Serverului -----------------" );
    
    for ( new i = i_Start; i < i_Last; i ++ ) 
        console_print ( id, "%d) %s", i+1, g_Maps[ i ] );
    
    console_print ( id, "" );
    
    if ( ++ i_Last < i_MapsNumber )
        console_print ( id, "Foloseste amx_maps %i pentru afisarea urmatoarei pagini", i_Last );
    
    console_print ( id, "------------------------------------------------------" );
    
    return PLUGIN_HANDLED;
}
 [/code]

PS.: In fisierul maps.ini din addons/amxmodx/configs treci toate hartile una sub alta, preferabil in ordine alfabetica.

Din cate stiu.. daca scrii maps ti le arata pe cele care le ai tu instalate in PC.
Corectati`ma daca am gresit ^_^

Nu este asa. Ti le arata hartile servererului, care le ai scrise in maps.ini. :)