Cerere Plugin Skin

[AcridGamer]

Plugin Cerut: Change Default Skin
Descriere (adica ce face el mai exact): As dori sa schimb Caracterele de la CT / TERO cu un singur Skin (Tero 1 Skin Rosu) CT - 1 Skin Albastru)
Serverul ruleaza (HLDS/ReHLDS): ReHLDS
Versiune AMX Mod X: -
Modul Serverului: xMas

PS: Am cautat pe internet dar tot ce am gasit erau cateva aiureli ce nu functionau!

PS: Daca aveti si din greseala acel skinpack full cu xmas skin :) as ramane dator :P

[levin]

https://forums.alliedmods.net/showthread.php?t=106094
https://forums.alliedmods.net/showthread.php?t=21086

[BUNNY.]

Salut, pluginul are doar 3 cvar-uri:
amx_model_name_t "numeskin" - Numele skinului de tero fara extensia .mdl
amx_model_name_ct "numeskin" - Numele skinului de ct fara extensia .mdl
amx_only_admin 0/1 - Daca vrei sa se aplice numai adminilor il setezi pe 1 daca nu il lasi pe 0

model_changer.sma | Afiseaza codul

#include <amxmodx>
#include <amxmisc>
#include <cstrike>
#include <hamsandwich>

new cvar_model_tero, cvar_model_ct, cvar_only_admin;

public plugin_precache()
{
	cvar_model_tero		=	register_cvar("amx_model_name_t", "teroskin");
	cvar_model_ct		=	register_cvar("amx_model_name_ct", "ctskin");
	cvar_only_admin		=	register_cvar("amx_only_admin", "0");

	// Incepem procesul de descarcare a modelelor
	new skin_tero[32], skin_ct[32], skin_temp[128];

	// Modelul Tero
	get_pcvar_string(cvar_model_tero, skin_tero, charsmax(skin_tero));
	formatex(skin_temp, charsmax(skin_temp), "models/player/%s/%s.mdl", skin_tero, skin_tero);
	precache_model(skin_temp);

	// Modelul CT
	get_pcvar_string(cvar_model_ct, skin_ct, charsmax(skin_ct));
	formatex(skin_temp, charsmax(skin_temp), "models/player/%s/%s.mdl", skin_ct, skin_ct);
	precache_model(skin_temp);
}

public plugin_init()
	RegisterHam(Ham_Spawn, "player", "fw_PlayerSpawn_Post", 1);

public fw_PlayerSpawn_Post(Player)
{
	if(!(1 <= Player <= get_maxplayers()) || !is_user_alive(Player))
		return;

	// Ne folosim de task pentru a nu da crash la server
	set_task(random_float(0.5, 0.7), "fw_PlayerModel_Change", Player);
}

public fw_PlayerModel_Change(Player)
{
	if(get_pcvar_num(cvar_only_admin) && !is_user_admin(Player))
		return;

	// Preluam numele modelelor
	new skin_tero[16], skin_ct[16];
	get_pcvar_string(cvar_model_tero, skin_tero, charsmax(skin_tero));
	get_pcvar_string(cvar_model_ct, skin_ct, charsmax(skin_ct));

	// Preluam echipa jucatorului
	if(cs_get_user_team(Player) == CS_TEAM_CT)
		cs_set_user_model(Player, skin_ct);
	if(cs_get_user_team(Player) == CS_TEAM_T)
		cs_set_user_model(Player, skin_tero);
}

Daca te-am ajutat nu uita sa apesi butonul "Multumesc" !